From 5043a584ce7a3eb644e68694a3266c1a5d2ccba5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 3 Jun 2023 21:32:31 +0100
Subject: gentoo auto-resync : 03:06:2023 - 21:32:31

---
 dev-util/ostree/Manifest             |   2 +
 dev-util/ostree/ostree-2023.3.ebuild | 118 +++++++++++++++++++++++++++++++++++
 2 files changed, 120 insertions(+)
 create mode 100644 dev-util/ostree/ostree-2023.3.ebuild

(limited to 'dev-util/ostree')

diff --git a/dev-util/ostree/Manifest b/dev-util/ostree/Manifest
index abe263e0758f..3e9145a47f7a 100644
--- a/dev-util/ostree/Manifest
+++ b/dev-util/ostree/Manifest
@@ -1,6 +1,8 @@
 AUX ostree-2022.6-musl-allperms.patch 478 BLAKE2B 95191befc9281591480f3a80717817e262798b7d6fc3abf35cb5c0462267822092a102de446f5334e3807816418e7b2b5b4dd59cd66796734b85131873e2dc9a SHA512 275e4fd6c1547c852ec9d2a8649c45c5bec6fdc2351e9333adfc3ed31b0cbedefaca6db95ba97ec8a65fa16bd550827909f7172b46a6b64a184840272578b7cc
 DIST ostree-2023.1.tar.xz 2079904 BLAKE2B 993570624cb43684d81fff9f3789a9cee3b998f945a78bc6eb99330eed45739d1e6fb66589cefba10eea608c5cd389cc121a890c27efa773a405a5d8b1f117d9 SHA512 a6a6e47d6cb9ec6826d48a50a2abac69e4a040f2b5830d39e8a006c738a163fb15fde8630bf271d92cec9470601281669cd4bf942e4b7c4d42441bd5d1730572
 DIST ostree-2023.2.tar.xz 2081320 BLAKE2B f773bf979b4bc97b9b8f96dc4385745bc386c29952a36c07cdd33a7db7802876ce154b5ac1f3669605ab3949a539aa8e2b3a3d94608557eb65249b5188f9d012 SHA512 549a2bdf8cef93d421aaf990e2d1c534063f0314b5933db7ce123bdd138229e24cc171d541296e45a7546a91d35149c1c8f29ea90949876200c574e7ec297b98
+DIST ostree-2023.3.tar.xz 2075168 BLAKE2B 6e699420a89b36520e60a5682a421fd8f10eb20702abe6af97be9ee78a04be98e8d164157d29726de9e63b869051f7e60f199776ea3d959d4f0ad4165ff780c6 SHA512 af3b80d55e15b515e860ab0ee5f061f1a4d649b21441d5cde66e71ff4349ef480565cb795838ebce2f42784d53e349c2443159d9ee452277001d930ba814fe40
 EBUILD ostree-2023.1.ebuild 2824 BLAKE2B 144f93d943f0879e9104d78996600c50c7e6f936a578baf15b13f65191f8299ef45805008111443d00ac6dc85d270c48403d1bcf8bfbb090be8ce899e49f32aa SHA512 7b44a33dfbd808708009cb3c7e6f4b92bdf9d6a6c7f657bc86033451435ad5907f7e1dbeca45a7eaab24e394159ef0e96a3a9f691bfc7b093c92f5158d3a58e9
 EBUILD ostree-2023.2.ebuild 2651 BLAKE2B 1c2e921eabf6ba07731654af72e28c6e4d58aa7571b39edfcc253df2eab833430e19365a0e0db11c1b5a51e71438f4e8d2692f0802672b9fe9821d7c1ff22202 SHA512 f4919163f99fa1de99ee307ec5c03eff49cf684fea5a727b2a8cbac88e4b6dc2a8368b5d5fe8b1b5501148a475a3d83759a818be56495065538120fb22b34faa
+EBUILD ostree-2023.3.ebuild 2651 BLAKE2B 1c2e921eabf6ba07731654af72e28c6e4d58aa7571b39edfcc253df2eab833430e19365a0e0db11c1b5a51e71438f4e8d2692f0802672b9fe9821d7c1ff22202 SHA512 f4919163f99fa1de99ee307ec5c03eff49cf684fea5a727b2a8cbac88e4b6dc2a8368b5d5fe8b1b5501148a475a3d83759a818be56495065538120fb22b34faa
 MISC metadata.xml 1990 BLAKE2B 1c3e6400d24f0701211c0b8dcfba8d31c06b7c493cbe6eb2c5432ea818d0a0fbe863f8f1661eb386d179bb186cb7c970f7d7a3f8c9c42ea4b03b3d4ea0472a57 SHA512 04e37ddcd7348d43d475e04c996ee8b2e94c64143325dcfb21c5738b75f71ecd2c2ec64c8f91fbd06f5a6228671e90fdf10a939d4457abe4d0f88492435b4601
diff --git a/dev-util/ostree/ostree-2023.3.ebuild b/dev-util/ostree/ostree-2023.3.ebuild
new file mode 100644
index 000000000000..32ce2d1f9766
--- /dev/null
+++ b/dev-util/ostree/ostree-2023.3.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools systemd tmpfiles
+
+DESCRIPTION="Operating system and container binary deployment and upgrades"
+HOMEPAGE="https://ostreedev.github.io/ostree/"
+SRC_URI="
+	https://github.com/ostreedev/ostree/releases/download/v${PV}/lib${P}.tar.xz
+		-> ${P}.tar.xz
+"
+S="${WORKDIR}/lib${P}"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+LICENSE="LGPL-2+"
+SLOT="0"
+
+IUSE="archive +curl doc dracut gnutls +gpg grub +http2 httpd introspection libmount selinux sodium ssl +soup systemd zeroconf"
+RESTRICT="test"
+REQUIRED_USE="
+	dracut? ( systemd )
+	http2? ( curl )
+	httpd? ( || ( curl soup ) )
+"
+
+RDEPEND="
+	app-arch/xz-utils
+	dev-libs/libassuan
+	dev-libs/glib:2
+	sys-fs/fuse:3
+	sys-libs/zlib
+	archive? ( app-arch/libarchive:= )
+	curl? ( net-misc/curl )
+	dracut? ( sys-kernel/dracut )
+	gpg? (
+		app-crypt/gpgme:=
+		dev-libs/libgpg-error
+	)
+	grub? ( sys-boot/grub:2= )
+	introspection? ( dev-libs/gobject-introspection )
+	libmount? ( sys-apps/util-linux )
+	selinux? ( sys-libs/libselinux )
+	sodium? ( >=dev-libs/libsodium-1.0.14:= )
+	soup? ( net-libs/libsoup:2.4 )
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? (
+			dev-libs/openssl:0=
+		)
+	)
+	systemd? ( sys-apps/systemd:0= )
+	zeroconf? ( net-dns/avahi[dbus] )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	doc? ( dev-util/gtk-doc )
+"
+BDEPEND="
+	dev-util/glib-utils
+	sys-devel/flex
+	sys-devel/bison
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/ostree-2022.6-musl-allperms.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Needs Bison (bug #884289)
+	unset YACC
+
+	local econfargs=(
+		--enable-man
+		--enable-shared
+		--with-grub2-mkconfig-path=grub-mkconfig
+		--with-modern-grub
+		$(use_with archive libarchive)
+		$(use_with curl)
+		$(use_with dracut dracut yesbutnoconf) #816867
+		$(use_enable doc gtk-doc)
+		$(usex introspection --enable-introspection={,} yes no)
+		$(use_with gpg gpgme)
+		$(use_enable http2)
+		$(use_enable httpd trivial-httpd-cmdline)
+		$(use_with selinux )
+		$(use_with soup)
+		$(use_with libmount)
+		$(use ssl && { use gnutls && echo --with-crypto=gnutls || echo --with-crypto=openssl; })
+		$(use_with sodium ed25519-libsodium)
+		$(use_with systemd libsystemd)
+		$(use_with zeroconf avahi)
+	)
+
+	if use systemd; then
+		econfargs+=( --with-systemdsystemunitdir="$(systemd_get_systemunitdir)" )
+	fi
+
+	unset ${!XDG_*} #657346 g-ir-scanner sandbox violation
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	tmpfiles_process ostree-tmpfiles.conf
+}
-- 
cgit v1.2.3