From fcc5224904648a8e6eb528d7603154160a20022f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 2 Feb 2022 01:39:05 +0000
Subject: gentoo resync : 02.02.2022

---
 dev-vcs/git-lfs/git-lfs-2.13.3-r1.ebuild | 70 ++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 dev-vcs/git-lfs/git-lfs-2.13.3-r1.ebuild

(limited to 'dev-vcs/git-lfs/git-lfs-2.13.3-r1.ebuild')

diff --git a/dev-vcs/git-lfs/git-lfs-2.13.3-r1.ebuild b/dev-vcs/git-lfs/git-lfs-2.13.3-r1.ebuild
new file mode 100644
index 000000000000..2cf565a6aba2
--- /dev/null
+++ b/dev-vcs/git-lfs/git-lfs-2.13.3-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+EGO_PN=github.com/git-lfs/git-lfs
+inherit go-module
+
+DESCRIPTION="Command line extension and specification for managing large files with git"
+HOMEPAGE="https://git-lfs.github.com/"
+
+if [[ "${PV}" = 9999* ]]; then
+	EGIT_REPO_URI="https://${EGO_PN}"
+	inherit git-r3
+else
+	SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="Apache-2.0 BSD BSD-2 BSD-4 ISC MIT"
+SLOT="0"
+IUSE="doc test"
+
+BDEPEND="doc? ( || ( app-text/ronn-ng app-text/ronn ) )"
+RDEPEND="dev-vcs/git"
+
+RESTRICT+=" !test? ( test )"
+
+DOCS=(
+	CHANGELOG.md
+	CODE-OF-CONDUCT.md
+	CONTRIBUTING.md
+	README.md
+	SECURITY.md
+)
+
+src_compile() {
+	# Flags -w, -s: Omit debugging information to reduce binary size,
+	# see https://golang.org/cmd/link/.
+	local mygobuildargs=(
+		-ldflags="-X ${EGO_PN}/config.GitCommit=${GIT_COMMIT} -s -w"
+		-mod vendor -v -work -x
+	)
+	go build "${mygobuildargs[@]}" -o git-lfs git-lfs.go || die
+
+	if use doc; then
+		ronn docs/man/*.ronn || die "man building failed"
+	fi
+}
+
+src_install() {
+	dobin git-lfs
+	einstalldocs
+	use doc && doman docs/man/*.1
+}
+
+src_test() {
+	local mygotestargs=(
+		-ldflags="-X ${EGO_PN}/config.GitCommit=${GIT_COMMIT}"
+		-mod vendor
+	)
+	go test "${mygotestargs[@]}" ./... || die
+}
+
+pkg_postinst () {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog ""
+		elog "Run \'git lfs install\' once for each user account manually."
+		elog "For more details see https://bugs.gentoo.org/show_bug.cgi?id=733372."
+	fi
+}
-- 
cgit v1.2.3