From d934827bf44b7cfcf6711964418148fa60877668 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 25 Nov 2020 22:39:15 +0000
Subject: gentoo resync : 25.11.2020

---
 dev-vcs/gitstats/gitstats-0_pre20201124.ebuild | 48 ++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-vcs/gitstats/gitstats-0_pre20201124.ebuild

(limited to 'dev-vcs/gitstats/gitstats-0_pre20201124.ebuild')

diff --git a/dev-vcs/gitstats/gitstats-0_pre20201124.ebuild b/dev-vcs/gitstats/gitstats-0_pre20201124.ebuild
new file mode 100644
index 000000000000..0fa1ffbc9f80
--- /dev/null
+++ b/dev-vcs/gitstats/gitstats-0_pre20201124.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit python-r1
+
+DESCRIPTION="Statistics generator for git"
+HOMEPAGE="http://gitstats.sourceforge.net/"
+SRC_URI="https://github.com/gktrk/gitstats/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 GPL-3 ) MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	sci-visualization/gnuplot[gd]
+	dev-vcs/git"
+DEPEND="
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	dev-lang/perl:*
+"
+
+DOCS=( doc/{AUTHOR,README,TODO.txt} )
+
+src_prepare() {
+	sed \
+		-e "s:basedirs = \[binarypath, secondarypath, '/usr/share/gitstats'\]:basedirs = \['${EPREFIX}/usr/share/gitstats'\]:g" \
+	-i gitstats || die "failed to fix static files path"
+	default
+}
+
+src_compile() {
+	emake VERSION="${PV}" man
+}
+
+src_install() {
+	emake PREFIX="${ED}"/usr VERSION="${PV}" install
+	doman doc/${PN}.1
+	einstalldocs
+	python_replicate_script "${ED}"/usr/bin/${PN}
+}
-- 
cgit v1.2.3