From 9ee6d97c2883d42f204a533a8bc1f4562df778fb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 16 Sep 2020 09:32:48 +0100
Subject: gentoo resync : 16.09.2020

---
 games-puzzle/gnurobbo/gnurobbo-0.68.ebuild | 47 ++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 games-puzzle/gnurobbo/gnurobbo-0.68.ebuild

(limited to 'games-puzzle/gnurobbo/gnurobbo-0.68.ebuild')

diff --git a/games-puzzle/gnurobbo/gnurobbo-0.68.ebuild b/games-puzzle/gnurobbo/gnurobbo-0.68.ebuild
new file mode 100644
index 000000000000..fded8903934c
--- /dev/null
+++ b/games-puzzle/gnurobbo/gnurobbo-0.68.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Robbo, a popular Atari XE/XL game ported to Linux"
+HOMEPAGE="http://gnurobbo.sourceforge.net/"
+SRC_URI="
+	mirror://sourceforge/gnurobbo/${P}-source.tar.gz
+	https://salsa.debian.org/games-team/gnurobbo/-/raw/debian/0.68+dfsg-5/debian/patches/single-variable-declarations.patch?inline=false -> ${P}-single-variable-declarations.patch
+"
+
+LICENSE="GPL-2 BitstreamVera"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+S="${WORKDIR}/${P}/${PN}"
+
+RDEPEND="
+	media-libs/libsdl[sound,video,joystick]
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer[vorbis]
+	media-libs/sdl-ttf
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-flags.patch"
+	"${DISTDIR}/${P}-single-variable-declarations.patch"
+)
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		PACKAGE_DATA_DIR="${EPREFIX}/usr/share/${PN}"
+}
+
+src_install() {
+	dobin gnurobbo
+	insinto "/usr/share/${PN}"
+	doins -r data/{levels,skins,locales,rob,sounds}
+	dodoc AUTHORS Bugs ChangeLog README TODO
+	newicon icon32.png ${PN}.png
+	make_desktop_entry ${PN} Gnurobbo
+}
-- 
cgit v1.2.3