From 315f94518df5e89b0990f56d7200f52d67aeec51 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 5 Oct 2022 07:19:12 +0100
Subject: gentoo auto-resync : 05:10:2022 - 07:19:11

---
 gnome-base/gnome-control-center/Manifest           |   5 +
 .../gnome-control-center-43.0.ebuild               | 198 +++++++++++++++++++++
 2 files changed, 203 insertions(+)
 create mode 100644 gnome-base/gnome-control-center/gnome-control-center-43.0.ebuild

(limited to 'gnome-base/gnome-control-center')

diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index c0a9dc6b08e1..7d90ae202be7 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -1,4 +1,9 @@
 DIST gnome-control-center-42.0-patchset.tar.xz 5932 BLAKE2B 1c9311481be6a07dc2ff61fc9e65f190bc1668026fba2a1e4a8edf9a033e6b2b9019542d89aac4480323ee4802e00b765654008f5252e87040f013a990cb8048 SHA512 b76c1facd3566edcadfe33f81027966da35bb03909bfbae6faad72005b92447e291fa424611196bfae6e1dc5bf5982917f3ae14c36d87206f6bfb4af502bf1a4
 DIST gnome-control-center-42.3.tar.xz 6242028 BLAKE2B 8b757e3286acb2b40732ce601d63be4de0fe0f16fec652e3be83b6c7ed6718d89b6e15608d29ce3f295453510b8986ea410c0de96bb0d9dabb4f3b9c77c2fae5 SHA512 eb82f65b580637fa057196daed836b3ea24a223b9932a2063b2879357f8a62626a6939835dc165a6d3c5706d16b99192301d4de021e68faaabb8d2ecc2a317a3
+DIST gnome-control-center-43.0-patchset.tar.xz 5940 BLAKE2B 91f47272518175286943a160ef77338b0153aa700a75315708ec478627dda8353b21d257b2baed9961ba77700e43c5655be06591b447c442881f828dd7002622 SHA512 e4683e99f43d9c395238df02228a87df4798df53c936bc8d188e366653d9e75b5219b0b0d8eb66ad21141fc2f1a882b994b96cf523c26b8dc21edb854aa1f384
+DIST gnome-control-center-43.0.tar.xz 5693880 BLAKE2B 290e0fbdd9557954ac2fbd79fe1872653c44ddaef540dd220b049c08958e688ac42de056a659ddcd0a7c47af2fbbabc078e658640ca9771e863eec5c174b3f9e SHA512 3fbb9252fedf44ceed6b7d6f1fed5263a110adce432effe4966f793a1f1443e92e39ff11595a6a2b3179297cc17979c310a33e3e2ac9d23dae0087ee227375a7
+DIST gnome-control-center-gentoo-logo-dark.svg 14293 BLAKE2B 570e9326b8abe45849c31fd5cdb3fcfb1b2f18eac522f958928df5c3b747b0699f50a882f31cf7c0ae1f2138194f18596f738f42c942b57d340c53d46d82c551 SHA512 91227dafcf2091bb1568b0f9eec68b5e371ec64c9a6bc3605821f60d6bf2bd94dec0564f6a16a4a70d1db4d4df49fc25b6c910367bae3b85205cc609a9f2701b
+DIST gnome-control-center-gentoo-logo.svg 14288 BLAKE2B 371fc68b1015c8672db3e3858ae9077b1e3a9937e6add8690c39db36302ec031391c4d35e0c0b87094ca474a00c4187849e2d7111df34f43bc5bd7be52678527 SHA512 cf88933546de54ca15e2e830ac1086a78c4150f0ff59b8091e7e1cade5961c4e4cb83120a818a960b77841353ce3584ddc8f36b6edbde05543600283a143ad7b
 EBUILD gnome-control-center-42.3-r1.ebuild 6081 BLAKE2B 17ca211c256e92f930bcff19f08f6477825d0de21b03ee53a89d654aa2794c9510e057eb7d78b66bfd6224c8072776e8dc4f7ece54cc075dec2c1ada8d793bfe SHA512 1a6e584e539e8d70a0edd3a819f919b1a5b73850624a742c03a27d5821c9042092b7df38bb7b823f7a75d1605926fb898250d5465871c49f1bac5c2ae78236dc
+EBUILD gnome-control-center-43.0.ebuild 6671 BLAKE2B 17da36a0a7c0e0e2a1cc28460907e80599ac775e7acc95211cf36f939d139cb9e628baf9c677a911a98b4fdeb43583cc43d40ed0283fa2ca98a171d7efb6a01b SHA512 3eacd361451ea86ad5e128ec6576a3a81c3332fee7c1f4db9b3fd29f8b3794dd1fcfb950eb7f6a5631928c2df4360faf6b10a3647493367f3c821f1fc46aca38
 MISC metadata.xml 497 BLAKE2B 27aa6d9d725a3ce90d351442da83bdb5680f9931d78e5d6a653a1d2d392df118406e3eab36c77bbaeefc581be3a62c5df13fdfb611b2db27fc9c7440ba4ceae3 SHA512 c44903fa5a9462871c065bc776450c25bcca1dfe2f52d6bf676568f587bc308a0465bd5cb6e095fb0ecaefd0b8471df90df3b96164c7e7de76a86fbbe416a82b
diff --git a/gnome-base/gnome-control-center/gnome-control-center-43.0.ebuild b/gnome-base/gnome-control-center/gnome-control-center-43.0.ebuild
new file mode 100644
index 000000000000..08db5b66cad3
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-43.0.ebuild
@@ -0,0 +1,198 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-control-center"
+SRC_URI+=" https://dev.gentoo.org/~mattst88/distfiles/${PN}-43.0-patchset.tar.xz"
+SRC_URI+=" https://dev.gentoo.org/~mattst88/distfiles/${PN}-gentoo-logo.svg"
+SRC_URI+=" https://dev.gentoo.org/~mattst88/distfiles/${PN}-gentoo-logo-dark.svg"
+# Logo is CC-BY-SA-2.5
+LICENSE="GPL-2+ CC-BY-SA-2.5"
+SLOT="2"
+IUSE="+bluetooth +cups debug elogind +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager systemd test wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	^^ ( elogind systemd )
+" # Theoretically "?? ( elogind systemd )" is fine too, lacking some functionality at runtime, but needs testing if handled gracefully enough
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~x86"
+
+# meson.build depends on python unconditionally
+BDEPEND="${PYTHON_DEPS}"
+
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# display panel requires colord and gnome-settings-daemon[colord]
+# wacom panel requires gsd-enums.h from gsd at build time, probably also runtime support
+# printer panel requires cups and smbclient (the latter is not patched yet to be separately optional)
+# First block is toplevel meson.build deps in order of occurrence (plus deeper deps if in same conditional). Second block is dependency() from subdir meson.builds, sorted by directory name occurrence order
+DEPEND="
+	gnome-online-accounts? (
+		x11-libs/gtk+:3
+		>=net-libs/gnome-online-accounts-3.25.3:=
+	)
+	>=media-libs/libpulse-2.0[glib]
+	>=gui-libs/libadwaita-1.2.0:1
+	>=sys-apps/accountsservice-0.6.39
+	>=x11-misc/colord-0.1.34:0=
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=dev-libs/glib-2.70.0:2
+	gnome-base/gnome-desktop:4=
+	>=gnome-base/gnome-settings-daemon-41.0[colord,input_devices_wacom?]
+	>=gnome-base/gsettings-desktop-schemas-42_alpha
+	dev-libs/libxml2:2
+	>=sys-power/upower-0.99.8:=
+	>=dev-libs/libgudev-232
+	x11-libs/libX11
+	>=x11-libs/libXi-1.2
+	media-libs/libepoxy
+	app-crypt/gcr:0=
+	>=dev-libs/libpwquality-1.2.2
+	>=gui-libs/gtk-4.4:4[X,wayland=]
+	>=sys-auth/polkit-0.114
+	cups? (
+		>=net-print/cups-1.7[dbus]
+		>=net-fs/samba-4.0.0[client]
+	)
+	ibus? ( >=app-i18n/ibus-1.5.2 )
+	networkmanager? (
+		>=net-libs/libnma-1.8.36
+		>=net-misc/networkmanager-1.24.0[modemmanager]
+		>=net-misc/modemmanager-0.7.990:=
+	)
+	bluetooth? ( net-wireless/gnome-bluetooth:3= )
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27:= )
+	kerberos? ( app-crypt/mit-krb5 )
+
+	x11-libs/cairo[glib]
+	>=x11-libs/colord-gtk-0.3.0:=
+	media-libs/fontconfig
+	gnome-base/libgtop:2=
+	>=sys-fs/udisks-2.1.8:2
+	app-crypt/libsecret
+	net-libs/gnutls:=
+	media-libs/gsound
+
+	x11-libs/pango
+"
+# systemd/elogind USE flagged because package manager will potentially try to satisfy a
+# "|| ( systemd ( elogind openrc-settingsd)" via systemd if openrc-settingsd isn't already installed.
+# libgnomekbd needed only for gkbd-keyboard-display tool
+# gnome-color-manager needed for gcm-calibrate and gcm-viewer calls from color panel
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${DEPEND}
+	systemd? ( >=sys-apps/systemd-31 )
+	elogind? (
+		app-admin/openrc-settingsd
+		sys-auth/elogind
+	)
+	x11-themes/adwaita-icon-theme
+	>=gnome-extra/gnome-color-manager-3.1.2
+	cups? (
+		app-admin/system-config-printer
+		net-print/cups-pk-helper
+	)
+	>=gnome-base/libgnomekbd-3
+	wayland? ( dev-libs/libinput )
+	!wayland? (
+		>=x11-drivers/xf86-input-libinput-0.19.0
+		input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 )
+	)
+"
+# PDEPEND to avoid circular dependency; gnome-session-check-accelerated called by info panel
+# gnome-session-2.91.6-r1 also needed so that 10-user-dirs-update is run at login
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1
+	networkmanager? ( gnome-extra/nm-applet )" # networking panel can call into nm-connection-editor
+
+BDEPEND="
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	app-text/docbook-xml-dtd:4.2
+	x11-base/xorg-proto
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		')
+		x11-apps/setxkbmap
+	)
+"
+
+PATCHES=(
+	# Patches from gnome-43 branch
+	# Makes some panels and dependencies optional
+	# https://bugzilla.gnome.org/686840, 697478, 700145
+	# Fix some absolute paths to be appropriate for Gentoo
+	"${WORKDIR}"/patches/
+)
+
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	xdg_environment_reset
+	# Mark python tests with shebang executable, so that meson will launch them directly, instead
+	# of via its own python-single-r1 version, which might not match what we get from python_check_deps
+	chmod a+x tests/network/test-network-panel.py tests/datetime/test-datetime.py || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bluetooth)
+		-Dcups=$(usex cups enabled disabled)
+		-Ddocumentation=true # manpage
+		-Dgoa=$(usex gnome-online-accounts enabled disabled)
+		$(meson_use ibus)
+		-Dkerberos=$(usex kerberos enabled disabled)
+		$(meson_use networkmanager network_manager)
+		-Dprivileged_group=wheel
+		-Dsnap=false
+		$(meson_use test tests)
+		$(meson_use debug tracing)
+		$(meson_use input_devices_wacom wacom)
+		#$(meson_use wayland) # doesn't do anything in 3.34 and 3.36 due to unified gudev handling code
+		# bashcompletions installed to $datadir/bash-completion/completions by v3.28.2, which is the same as $(get_bashcompdir)
+		-Dmalcontent=false # unpackaged
+		-Ddistributor_logo=/usr/share/pixmaps/gnome-control-center-gentoo-logo.svg
+		-Ddark_mode_distributor_logo=/usr/share/pixmaps/gnome-control-center-gentoo-logo-dark.svg
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	insinto /usr/share/pixmaps
+	doins "${DISTDIR}"/gnome-control-center-gentoo-logo.svg
+	doins "${DISTDIR}"/gnome-control-center-gentoo-logo-dark.svg
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3