From 95ea6b4d5731b3430396be650fdb3d4b21cebba1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 28 Sep 2023 23:35:57 +0100
Subject: gentoo auto-resync : 28:09:2023 - 23:35:56

---
 gui-libs/wlroots/wlroots-0.16.2-r2.ebuild | 91 +++++++++++++++++++++++++++++++
 1 file changed, 91 insertions(+)
 create mode 100644 gui-libs/wlroots/wlroots-0.16.2-r2.ebuild

(limited to 'gui-libs/wlroots/wlroots-0.16.2-r2.ebuild')

diff --git a/gui-libs/wlroots/wlroots-0.16.2-r2.ebuild b/gui-libs/wlroots/wlroots-0.16.2-r2.ebuild
new file mode 100644
index 000000000000..bb9f64c221f8
--- /dev/null
+++ b/gui-libs/wlroots/wlroots-0.16.2-r2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor"
+HOMEPAGE="https://gitlab.freedesktop.org/wlroots/wlroots"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/${PN}/${PN}.git"
+	inherit git-r3
+	SLOT="0/9999"
+else
+	SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/releases/${PV}/downloads/${P}.tar.gz -> ${P}.gl.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+	SLOT="0/$(ver_cut 2)"
+fi
+
+LICENSE="MIT"
+IUSE="+drm +libinput tinywl vulkan x11-backend xcb-errors X"
+REQUIRED_USE="
+	xcb-errors? ( || ( x11-backend X ) )
+"
+
+DEPEND="
+	>=dev-libs/wayland-1.21.0
+	media-libs/mesa[egl(+),gles2]
+	sys-auth/seatd:=
+	virtual/libudev
+	>=x11-libs/libdrm-2.4.114
+	x11-libs/libxkbcommon
+	>=x11-libs/pixman-0.42.0
+	drm? ( sys-apps/hwdata )
+	libinput? ( >=dev-libs/libinput-1.14.0:= )
+	vulkan? (
+		dev-util/glslang:=
+		dev-util/vulkan-headers
+		media-libs/vulkan-loader
+	)
+	xcb-errors? ( x11-libs/xcb-util-errors )
+	x11-backend? (
+		x11-libs/libxcb:=
+		x11-libs/xcb-util-renderutil
+	)
+	X? (
+		x11-base/xwayland
+		x11-libs/libxcb:=
+		x11-libs/xcb-util-wm
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.28
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local backends=(
+		$(usev drm)
+		$(usev libinput)
+		$(usev x11-backend 'x11')
+	)
+	local meson_backends=$(IFS=','; echo "${backends[*]}")
+	local emesonargs=(
+		$(meson_feature xcb-errors)
+		$(meson_use tinywl examples)
+		-Drenderers=$(usex vulkan 'gles2,vulkan' gles2)
+		$(meson_feature X xwayland)
+		-Dbackends=${meson_backends}
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use tinywl; then
+		dobin "${BUILD_DIR}"/tinywl/tinywl
+	fi
+}
+
+pkg_postinst() {
+	elog "You must be in the input group to allow your compositor"
+	elog "to access input devices via libinput."
+}
-- 
cgit v1.2.3