From d934827bf44b7cfcf6711964418148fa60877668 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 25 Nov 2020 22:39:15 +0000
Subject: gentoo resync : 25.11.2020

---
 lxqt-base/lxqt-panel/Manifest                 |   2 +
 lxqt-base/lxqt-panel/lxqt-panel-0.16.1.ebuild | 116 ++++++++++++++++++++++++++
 2 files changed, 118 insertions(+)
 create mode 100644 lxqt-base/lxqt-panel/lxqt-panel-0.16.1.ebuild

(limited to 'lxqt-base/lxqt-panel')

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
index 4306554fba57..eb2d942c6980 100644
--- a/lxqt-base/lxqt-panel/Manifest
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -1,3 +1,5 @@
 DIST lxqt-panel-0.15.1.tar.xz 473356 BLAKE2B 297e704c51b3c950551fd09012c0aa533fdecf3d46d0f988428ce4100b7936970c5b400c6dc77103e26c07a05d10611fcd921354063cc55252b0a9cb93b0ebe6 SHA512 8eb9856faa2ce56c56df7514772d3ae6d31339a10d16e1ed659be0a2affc57fd16e01e05cb67c4205dfb773234ca9b8a69f414f742ccc30495bf4e2acfa0513f
+DIST lxqt-panel-0.16.1.tar.xz 473632 BLAKE2B aee19df3cef9dd25b20ae44cdbeb0c017fefc1e7e7f1d350e07820aa2d873a03dfd69a990e99abed95a9c633a6c496bff356fbbcfcc3cebacc50dde52dc79780 SHA512 2db8c4b5d8ddf42b72ffd5863242774277b4bf2fd1ec4393908851ce3224c970de5f12ae61be3dd7008407ea5df7b0b59990b03982e2725ee9a0ce2e3cce48f5
 EBUILD lxqt-panel-0.15.1.ebuild 2903 BLAKE2B bcb9e2065c5a552533828d69811baaf685c3ea288c3d1d2c33fb77f44b4167bc38859db512850bb8f5fed416530b5e428c80dab79a473312fd3087980ddee6fb SHA512 e9b2e20b6bb86cf970d260c667e75a1ece43f2f30f221fb13c85a43c4442421c6ef52d0c73ca737b1ac7ffb961ed0a457efc6842bcd1837e485b377d7c90cebc
+EBUILD lxqt-panel-0.16.1.ebuild 2905 BLAKE2B 6babb5e23d910a168048f5554a38f967ed6d2d5434959f25087e501e9391d51450ae864ac133fdd09f13e1941359031b54eceb180c02fdaee4044b67b7a1c16e SHA512 cd5a2a7a1eb3c9d2f1db7364bcd63f1257d22cf36fd72b0a432f995198bac086f4a01542405f5a3290f1f9f8483fa56aa4d8111fd112c814beabdf68ab864cf7
 MISC metadata.xml 1319 BLAKE2B 3bfa4db473764d962cab5c005d97a1a1449a799546d1d7d20cbd7da095b25ed6dd40aa47046d561bc9041255cfca62af9f08e16f69a14557325b12a81911fb1b SHA512 26b2c71f50db3c8efe9df6dcd4a497ffbd9d281549a1e7bc12faa22be9aef28bf51d89a172b7ba6c17e9c3cce926b837c4f5d6598567e8359545b166eae19d3a
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-0.16.1.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-0.16.1.ebuild
new file mode 100644
index 000000000000..bbc5bb32a74b
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-0.16.1.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="https://lxqt.github.io/"
+
+MY_PV="$(ver_cut 1-2)*"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+IUSE="+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator
++mainmenu +mount networkmonitor pulseaudio +quicklaunch lm-sensors +showdesktop
++spacer statusnotifier sysstat +taskbar +tray +volume +worldclock"
+
+# Work around a missing header issue: https://bugs.gentoo.org/666278
+REQUIRED_USE="
+	|| ( desktopswitch mainmenu showdesktop taskbar )
+	volume? ( || ( alsa pulseaudio ) )
+"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=dev-util/lxqt-build-tools-0.8.0
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5[X]
+	>=lxde-base/lxmenu-data-0.1.5
+	>=lxde-base/menu-cache-1.1.0
+	=lxqt-base/liblxqt-${MY_PV}
+	=lxqt-base/lxqt-globalkeys-${MY_PV}
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	lm-sensors? ( sys-apps/lm-sensors )
+	mount? ( kde-frameworks/solid:5 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	statusnotifier? ( dev-libs/libdbusmenu-qt[qt5(+)] )
+	sysstat? ( >=lxqt-base/libsysstat-0.4.1 )
+	tray? (
+		x11-libs/libxcb:=
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender
+		x11-libs/xcb-util
+	)
+	volume? (
+		alsa? ( media-libs/alsa-lib )
+		pulseaudio? (
+			media-sound/pavucontrol-qt
+			media-sound/pulseaudio
+		)
+	)
+"
+RDEPEND="${DEPEND}
+	!lxqt-base/lxqt-l10n
+"
+
+src_configure() {
+	local mycmakeargs=(
+		# Plugins
+		-DCOLORPICKER_PLUGIN=$(usex colorpicker)
+		-DCPULOAD_PLUGIN=$(usex cpuload)
+		-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
+		-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
+		-DDOM_PLUGIN=$(usex dom)
+		-DKBINDICATOR_PLUGIN=$(usex kbindicator)
+		-DMAINMENU_PLUGIN=$(usex mainmenu)
+		-DMOUNT_PLUGIN=$(usex mount)
+		-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
+		-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
+		-DSENSORS_PLUGIN=$(usex lm-sensors)
+		-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
+		-DSPACER_PLUGIN=$(usex spacer)
+		-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
+		-DSYSSTAT_PLUGIN=$(usex sysstat)
+		-DTASKBAR_PLUGIN=$(usex taskbar)
+		-DTRAY_PLUGIN=$(usex tray)
+		-DVOLUME_PLUGIN=$(usex volume)
+		-DWORLDCLOCK_PLUGIN=$(usex worldclock)
+	)
+
+	if use volume; then
+		mycmakeargs+=(
+			-DVOLUME_USE_ALSA=$(usex alsa)
+			-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman panel/man/*.1
+}
-- 
cgit v1.2.3