From 623ee73d661e5ed8475cb264511f683407d87365 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 12 Apr 2020 03:41:30 +0100
Subject: gentoo Easter resync : 12.04.2020

---
 media-gfx/inkscape/Manifest                  |   3 +-
 media-gfx/inkscape/inkscape-0.92.4-r3.ebuild | 165 +++++++++++++++++++++++++++
 media-gfx/inkscape/metadata.xml              |  11 +-
 3 files changed, 173 insertions(+), 6 deletions(-)
 create mode 100644 media-gfx/inkscape/inkscape-0.92.4-r3.ebuild

(limited to 'media-gfx/inkscape')

diff --git a/media-gfx/inkscape/Manifest b/media-gfx/inkscape/Manifest
index 09bdd6f4b577..bd270bc8fcb0 100644
--- a/media-gfx/inkscape/Manifest
+++ b/media-gfx/inkscape/Manifest
@@ -12,6 +12,7 @@ AUX inkscape-1.0_beta1-do-not-compress-man.patch 454 BLAKE2B d680993be80d9069c79
 DIST inkscape-0.92.4.tar.bz2 31929728 BLAKE2B 892bf4ed913019b27a9b8897e3ae32c44152163ded0eb345d59915ffdc9818d29f210de3294ef1b05601141185b5e3b10779778551b860f31e7df5c659492c77 SHA512 b9034605a79cd8aea808edf42e284819951ae1ea67778f0922f4c10224e94aca6c844acbc2294625773f0a7047d4e32ccdada876238a792a2c17db172c88e120
 DIST inkscape-1.0beta2_2019-12-03_2b71d25d45.tar.xz 39508392 BLAKE2B fd48f22439d1182aff1db5afd74870a6c1d291afb310fc9fa5036fa3c2547ead8c17f6cd67f77a56f655c56af8ffaa7a349b17166c7b18ef3ddf234aa6e57805 SHA512 029508d4867ac0890b2c9c4d274408f849a17e8a7978853df38543d94e7c08d33546a8a40fbcd940da1ba847f11e37ff2bafa285174b65d45ee5de59e907e78f
 EBUILD inkscape-0.92.4-r2.ebuild 3836 BLAKE2B 39efa33d21c2ae8054827c76cfe451a60fbca48b12a4eeb106bd0b03895ecf02102df8fd2c28626d7daf4a720eaeb67d4e3642f214d9f4ad68b3c183826a4e47 SHA512 8c2304ac76e116472f726b952ebc3a47478ca78d50686c1594ea55555b7e39d1f1003118ec6572244735f871a18f55ec49391fbde3d327b204d518cf84978f03
+EBUILD inkscape-0.92.4-r3.ebuild 3871 BLAKE2B d0653e907e2586a9f2f2d348b62840a7a64856c1a250ffe61b867252ff01f971b756c2adba7b2f608a7a5de615efb582853f224105067de41f4363b45eeb8a3b SHA512 25d2f80dce93f59073e9b81c74a6c62aacbd335366e22a5d7ca9c63113e0bdd987bcfc11e050ed5a53066583f48bba283b50d0f41d09e6b21866abe85f1b7e55
 EBUILD inkscape-1.0_beta2-r1.ebuild 4160 BLAKE2B ff8fe48e09e96ce2ff5b1a9eca34c4fc249ae22a1b057cdf7ef714fbb43878e9bed4e2811a260eb5cb03920b4fd2eeda988fb27f290714fa3e1b6bd2947427e2 SHA512 2363a42f4053c03ab8d02beed5f51054f517d0814780d93f3b68315bc594f1a0d4906af7ab8cf68de965edc12104da726ebb0d70613b9aba988ce4fb22159d59
 EBUILD inkscape-9999.ebuild 4056 BLAKE2B a24e811d39011b09d28b5e4d44db85f4d225219d14b80c7b8527dad38fc46e4365471616ae582eb261a518d48827f57cf0e25cb1c3f534ff540162e7a9d95472 SHA512 cdccb07f6f0f6c7c6b6448f1fb1662a9cacc58f52bbbdb1ea9ca2fde52b5170e7ea5640c56ee0909312b8e9a09eec071b9192096bfda46d76baa17fcd51d8e3c
-MISC metadata.xml 951 BLAKE2B 5610cce03a912f378f4bbb997bb9acc028f2f02c1ec40034ed523b7f7cee2cc980f1f24fb8fbd26b40d494a514769b722ca64e93078c82ad75c9db94a9f19ca4 SHA512 f62078fa96c501f4d8e01d4e539b74b91cbf90997392e903e30db9c3a117c2ccc7f2d3e1c2e62c85362cd0a2d504dd565cfd70f92e5b947d416f8a3f2cd88f8e
+MISC metadata.xml 1075 BLAKE2B 86f17c0732921e450d6215ff22e8140006ebfd1f570943086680fa85cb7fffc5d1d4a8876ad26b03d65e2841b70b0337b7fa75ea5fc7cee5a1bb3242363a5d43 SHA512 094db7f9e4bed29b308a95488d849c44a02c1fcd870ffcabb75e6fb08ec3eb028d1adf980a13e3501e2ec043dfed8dda18038e5bd09274d5090317526623165e
diff --git a/media-gfx/inkscape/inkscape-0.92.4-r3.ebuild b/media-gfx/inkscape/inkscape-0.92.4-r3.ebuild
new file mode 100644
index 000000000000..912e7bba247d
--- /dev/null
+++ b/media-gfx/inkscape/inkscape-0.92.4-r3.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="xml"
+inherit autotools flag-o-matic gnome2-utils xdg toolchain-funcs python-single-r1
+
+MY_P="${P/_/}"
+
+DESCRIPTION="SVG based generic vector-drawing program"
+HOMEPAGE="https://inkscape.org/"
+SRC_URI="https://inkscape.global.ssl.fastly.net/media/resources/file/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="cdr dia dbus exif gnome imagemagick openmp postscript inkjar jpeg latex"
+IUSE+=" lcms nls spell static-libs visio wpg uniconvertor"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-text/poppler-0.26.0:=[cairo]
+	>=dev-cpp/glibmm-2.54.1
+	>=dev-cpp/gtkmm-2.18.0:2.4
+	>=dev-cpp/cairomm-1.9.8
+	>=dev-libs/boehm-gc-7.1:=
+	>=dev-libs/glib-2.28
+	>=dev-libs/libsigc++-2.0.12
+	>=dev-libs/libxml2-2.6.20
+	>=dev-libs/libxslt-1.0.15
+	dev-libs/popt
+	media-gfx/potrace
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/libpng:0=
+	sci-libs/gsl:=
+	x11-libs/libX11
+	>=x11-libs/gtk+-2.10.7:2
+	>=x11-libs/pango-1.24
+	cdr? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libcdr
+	)
+	dbus? ( dev-libs/dbus-glib )
+	exif? ( media-libs/libexif )
+	gnome? ( >=gnome-base/gnome-vfs-2.0 )
+	imagemagick? ( <media-gfx/imagemagick-7:=[cxx] )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	spell? (
+		app-text/aspell
+		app-text/gtkspell:2
+	)
+	visio? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libvisio
+	)
+	wpg? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+	)
+"
+# These only use executables provided by these packages
+# See share/extensions for more details. inkscape can tell you to
+# install these so we could of course just not depend on those and rely
+# on that.
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		|| (
+			dev-python/numpy-python2[${PYTHON_MULTI_USEDEP}]
+			dev-python/numpy[${PYTHON_MULTI_USEDEP}]
+		)
+	')
+	uniconvertor? ( media-gfx/uniconvertor )
+	dia? ( app-office/dia )
+	latex? (
+		media-gfx/pstoedit[plotutils]
+		app-text/dvipsk
+		app-text/texlive-core
+	)
+	postscript? ( app-text/ghostscript-gpl )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.36
+	dev-util/glib-utils
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.92.1-automagic.patch"
+	"${FILESDIR}/${PN}-0.91_pre3-cppflags.patch"
+	"${FILESDIR}/${PN}-0.92.1-desktop.patch"
+	"${FILESDIR}/${PN}-0.91_pre3-exif.patch"
+	"${FILESDIR}/${PN}-0.91_pre3-sk-man.patch"
+	"${FILESDIR}/${PN}-0.48.4-epython.patch"
+	"${FILESDIR}/${PN}-0.92.4-poppler-0.76.0.patch" #684246
+	"${FILESDIR}/${PN}-0.92.4-poppler-0.82.0.patch"
+	"${FILESDIR}/${PN}-0.92.4-poppler-0.83.0.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+RESTRICT="test"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed -i "s#@EPYTHON@#${EPYTHON}#" \
+		src/extension/implementation/script.cpp || die
+
+	eautoreconf
+
+	# bug 421111
+	python_fix_shebang share/extensions
+}
+
+src_configure() {
+	# aliasing unsafe wrt #310393
+	append-flags -fno-strict-aliasing
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable nls)
+		$(use_enable openmp)
+		$(use_enable exif)
+		$(use_enable jpeg)
+		$(use_enable lcms)
+		--enable-poppler-cairo
+		$(use_enable wpg)
+		$(use_enable visio)
+		$(use_enable cdr)
+		$(use_enable dbus dbusapi)
+		$(use_enable imagemagick magick)
+		$(use_with gnome gnome-vfs)
+		$(use_with inkjar)
+		$(use_with spell gtkspell)
+		$(use_with spell aspell)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake -C src helper/sp-marshal.h #686304
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name "*.la" -delete || die
+	python_optimize "${ED%/}"/usr/share/${PN}/extensions
+}
diff --git a/media-gfx/inkscape/metadata.xml b/media-gfx/inkscape/metadata.xml
index 49c45680f5fe..8bfffeae53d1 100644
--- a/media-gfx/inkscape/metadata.xml
+++ b/media-gfx/inkscape/metadata.xml
@@ -6,13 +6,14 @@
 		<name>Gentoo Graphics Project</name>
 	</maintainer>
 	<use>
-		<flag name="cdr">Enable support for CorelDRAW Diagrams via <pkg>media-libs/libcdr</pkg></flag>
-		<flag name="dia">pull in <pkg>app-office/dia</pkg> for dia import extension</flag>
+		<flag name="cdr">Enable support for CorelDRAW files via <pkg>media-libs/libcdr</pkg></flag>
+		<flag name="dia">Enable DIA flow chart import via <pkg>app-office/dia</pkg></flag>
 		<flag name="inkjar">Enable support for OpenOffice.org SVG jar files</flag>
-		<flag name="latex">pull in dependencies for LaTeX formulas</flag>
+		<flag name="latex">Enable rendering of LaTeX formulas</flag>
 		<flag name="svg2">Enable support for new SVG2 features</flag>
-		<flag name="visio">Enable support for Microsoft Visio Diagrams via <pkg>media-libs/libvisio</pkg></flag>
-		<flag name="wpg">Enable support for WordPerfect Graphics via <pkg>app-text/libwpg</pkg></flag>
+		<flag name="visio">Enable support for Microsoft Visio diagrams via <pkg>media-libs/libvisio</pkg></flag>
+		<flag name="wpg">Enable support for WordPerfect graphics via <pkg>app-text/libwpg</pkg></flag>
+		<flag name="uniconvertor">Enable conversion of vector graphic files via <pkg>media-gfx/uniconvertor</pkg> (needs Python 2)</flag>
 	</use>
 	<upstream>
 		<remote-id type="gitlab">inkscape/inkscape</remote-id>
-- 
cgit v1.2.3