From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 media-libs/alure/alure-1.2-r1.ebuild | 48 ++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 media-libs/alure/alure-1.2-r1.ebuild

(limited to 'media-libs/alure/alure-1.2-r1.ebuild')

diff --git a/media-libs/alure/alure-1.2-r1.ebuild b/media-libs/alure/alure-1.2-r1.ebuild
new file mode 100644
index 000000000000..2aefcc7885f3
--- /dev/null
+++ b/media-libs/alure/alure-1.2-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils eutils
+
+DESCRIPTION="The OpenAL Utility Toolkit"
+HOMEPAGE="http://kcat.strangesoft.net/alure.html"
+SRC_URI="http://kcat.strangesoft.net/alure-releases/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~ppc64 x86"
+IUSE="dumb examples flac fluidsynth mp3 sndfile static-libs vorbis"
+
+RDEPEND=">=media-libs/openal-1.1
+	dumb? ( media-libs/dumb )
+	flac? ( media-libs/flac )
+	fluidsynth? ( >=media-sound/fluidsynth-1.1.1 )
+	mp3? ( media-sound/mpg123 )
+	sndfile? ( media-libs/libsndfile )
+	vorbis? ( media-libs/libvorbis )"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}/${P}-include-unistd.patch" )
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -i -e "/DESTINATION/s:doc/alure:doc/${PF}:" CMakeLists.txt || die
+}
+
+src_configure() {
+	# FIXME: libmodplug/sndfile.h from libmodplug conflict with sndfile.h from libsndfile
+	local mycmakeargs=(
+		-DMODPLUG=OFF
+		-DDUMB=$(usex dumb)
+		-DBUILD_EXAMPLES=$(usex examples)
+		-DFLAC=$(usex flac)
+		-DFLUIDSYNTH=$(usex fluidsynth)
+		-DMPG123=$(usex mp3)
+		-DSNDFILE=$(usex sndfile)
+		-DBUILD_STATIC=$(usex static-libs)
+		-DVORBIS=$(usex vorbis)
+	)
+
+	cmake-utils_src_configure
+}
-- 
cgit v1.2.3