From 3cf7c3ef441822c889356fd1812ebf2944a59851 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 25 Aug 2020 10:45:55 +0100
Subject: gentoo resync : 25.08.2020

---
 media-libs/aubio/aubio-0.4.7-r1.ebuild | 123 ---------------------------------
 1 file changed, 123 deletions(-)
 delete mode 100644 media-libs/aubio/aubio-0.4.7-r1.ebuild

(limited to 'media-libs/aubio/aubio-0.4.7-r1.ebuild')

diff --git a/media-libs/aubio/aubio-0.4.7-r1.ebuild b/media-libs/aubio/aubio-0.4.7-r1.ebuild
deleted file mode 100644
index 977ee51acd4e..000000000000
--- a/media-libs/aubio/aubio-0.4.7-r1.ebuild
+++ /dev/null
@@ -1,123 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-DISTUTILS_OPTIONAL=1
-PYTHON_COMPAT=( python2_7 )
-PYTHON_REQ_USE='threads(+)'
-inherit distutils-r1 waf-utils
-
-DESCRIPTION="Library for audio labelling"
-HOMEPAGE="https://aubio.org/"
-SRC_URI="https://aubio.org/pub/${P}.tar.bz2"
-
-LICENSE="GPL-3"
-SLOT="0/5"
-KEYWORDS="amd64 ~ppc ppc64 sparc x86"
-IUSE="doc double-precision examples ffmpeg fftw jack libsamplerate sndfile python test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	ffmpeg? ( >=media-video/ffmpeg-2.6:0= )
-	fftw? ( sci-libs/fftw:3.0= )
-	jack? ( virtual/jack )
-	libsamplerate? ( media-libs/libsamplerate )
-	python? (
-		${PYTHON_DEPS}
-		|| (
-			dev-python/numpy-python2[${PYTHON_USEDEP}]
-			dev-python/numpy[${PYTHON_USEDEP}]
-		)
-	)
-	sndfile? ( media-libs/libsndfile )
-"
-DEPEND="${RDEPEND}
-	${PYTHON_DEPS}
-	app-text/txt2man
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen )
-"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}
-	?? ( double-precision libsamplerate )
-"
-
-DOCS=( AUTHORS ChangeLog README.md )
-PYTHON_SRC_DIR="${S}"
-
-src_prepare() {
-	default
-	sed -e "s:doxygen:doxygen_disabled:" -i wscript || die
-
-	if ! use test; then
-		sed -e "/bld.*tests/d" -i wscript || die
-	fi
-}
-
-src_configure() {
-	python_setup
-	local mywafconfargs=(
-		--enable-complex
-		--docdir="${EPREFIX}"/usr/share/doc/${PF}
-		$(use_enable double-precision double)
-		$(use_enable fftw fftw3)
-		$(use_enable ffmpeg avcodec)
-		$(use_enable jack)
-		$(use_enable libsamplerate samplerate)
-		$(use_enable sndfile)
-	)
-	use double-precision || mywafconfargs+=( $(use_enable fftw fftw3f) )
-
-	waf-utils_src_configure "${mywafconfargs[@]}"
-
-	if use python ; then
-		cd "${PYTHON_SRC_DIR}" || die
-		distutils-r1_src_configure
-	fi
-}
-
-src_compile() {
-	waf-utils_src_compile --notests
-
-	if use doc; then
-		cd "${S}"/doc || die
-		emake dirhtml
-	fi
-
-	if use python ; then
-		cd "${PYTHON_SRC_DIR}" || die
-		distutils-r1_src_compile
-	fi
-}
-
-src_test() {
-	waf-utils_src_compile --alltests
-
-	if use python ; then
-		cd "${PYTHON_SRC_DIR}" || die
-		distutils-r1_src_test
-	fi
-}
-
-src_install() {
-	waf-utils_src_install
-
-	if use examples; then
-		# install dist_noinst_SCRIPTS from Makefile.am
-		dodoc -r examples
-	fi
-
-	if use python ; then
-		cd "${PYTHON_SRC_DIR}" || die
-		DOCS="" distutils-r1_src_install
-		newdoc python/README.md README.python
-	fi
-
-	if use doc; then
-		dodoc doc/*.txt
-		docinto html
-		dodoc -r doc/_build/dirhtml/.
-	fi
-
-	find "${ED}" -name "*.a" -delete || die
-}
-- 
cgit v1.2.3