From 6990d0600970cefe6aa2c17668f9028b08d23441 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 10 Apr 2023 23:37:47 +0100
Subject: gentoo auto-resync : 10:04:2023 - 23:37:47

---
 media-libs/grilo/Manifest               |  1 +
 media-libs/grilo/grilo-0.3.15-r1.ebuild | 77 +++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)
 create mode 100644 media-libs/grilo/grilo-0.3.15-r1.ebuild

(limited to 'media-libs/grilo')

diff --git a/media-libs/grilo/Manifest b/media-libs/grilo/Manifest
index c4f10b1f8899..1002488d08d5 100644
--- a/media-libs/grilo/Manifest
+++ b/media-libs/grilo/Manifest
@@ -1,3 +1,4 @@
 DIST grilo-0.3.15.tar.xz 241428 BLAKE2B 6b8841924c1b555abfcb852eddcaddaf0ea85dfe2922420e0e06b8fe2ea4fd4d8d5da47b011fd4c2f9c4edbe4fc08b36a3dd3c3779a92a0bd44abef3c3bffd9e SHA512 98616c1600bb7d7f5c92bbdc9b85d57da1e416f9207e60ad9b6c305c989f6d4ff6b21963f8f8c69f0daca68bf9d91b3397addfd0cea62f0553977fc0e69b2c31
+EBUILD grilo-0.3.15-r1.ebuild 2147 BLAKE2B 32ff659195256718f5862d03b84bd8221b47fd40233523a7474bb1d07a1151a89eb235c2b22d8b1dc40555eaee36ca17cf51a4b5b283806a3e2cf56d3c7a8380 SHA512 7649cbe3515987a5c44283e866117f4b8217ac106859df3f2f89033aaa92fc0ca930a9f95e09f4c8e528e7bc2e263e34cea17329c453ee00b874a8e72dcc6711
 EBUILD grilo-0.3.15.ebuild 2150 BLAKE2B 522219662d0ef98dbd24aad322973506f103d225e7f4eb5a288d17f999865d91e82065e1cf8f2b0f9679ca54dbc148067b765924b9f55d2fc7ed27a8881dea00 SHA512 89b7d4928c22662b2d2a736685e46cef7116880a14599faf4c3e1e1f0cc93639cf6bf3f6f03e8f7ec961d7b0fdc99fa49a56af82473d8ef3d1a85b328aa68cb3
 MISC metadata.xml 728 BLAKE2B bf26241647153b434cdf724108342a8415518d5d53487ef449ea382d2b3f3fe33bacf917ddeb65e90d11c7eeefabf3d58510c44b998cadbab3fc8b315bea6422 SHA512 9a871314e746f137125c7bb31f8b9a246fdbf2a9c92f017c1d134019b423d72639db1d5214bd8f06321f7ae4233085aff1d8a3cf7ad748b391ff81f92ff2255f
diff --git a/media-libs/grilo/grilo-0.3.15-r1.ebuild b/media-libs/grilo/grilo-0.3.15-r1.ebuild
new file mode 100644
index 000000000000..bbf0652fc20a
--- /dev/null
+++ b/media-libs/grilo/grilo-0.3.15-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit gnome.org meson python-any-r1 vala xdg
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3/0" # subslot is libgrilo-0.3 soname suffix
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gtk gtk-doc +introspection +playlist test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+# oauth could be optional if meson is patched - used for flickr oauth in grilo-test-ui tool
+RDEPEND="
+	>=dev-libs/glib-2.66:2
+	>=net-libs/libsoup-3:3.0[introspection?]
+	playlist? ( >=dev-libs/totem-pl-parser-3.4.1:= )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+
+	gtk? (
+		net-libs/liboauth
+		>=x11-libs/gtk+-3.14:3
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.10
+		app-text/docbook-xml-dtd:4.3
+	)
+	${PYTHON_DEPS}
+	test? ( sys-apps/dbus )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	sed -i -e "s:'GETTEXT_PACKAGE', meson.project_name():'GETTEXT_PACKAGE', 'grilo-${SLOT%/*}':" meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-${SLOT%/*}':" po/meson.build || die
+	sed -i -e "s:'grilo':'grilo-${SLOT%/*}':" doc/grilo/meson.build || die
+
+	# Drop explicit unversioned vapigen check
+	sed -i -e "/find_program.*vapigen/d" meson.build || die
+
+	# Don't build examples; they get embedded in gtk-doc, thus we don't install the sources with USE=examples either
+	sed -i -e "/subdir('examples')/d" meson.build || die
+
+	default
+	xdg_environment_reset
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable-grl-net=true # Fails to build
+		$(meson_use playlist enable-grl-pls)
+		$(meson_use gtk-doc enable-gtk-doc)
+		$(meson_use introspection enable-introspection)
+		$(meson_use gtk enable-test-ui)
+		$(meson_use vala enable-vala)
+		-Dsoup3=true
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
-- 
cgit v1.2.3