From 948d557b4a61dc14722668b6b11a4cf3cee07b01 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 13 Sep 2019 17:56:30 +0100
Subject: gentoo resync : 13.09.2019

---
 media-libs/libvisio/Manifest              |  4 +-
 media-libs/libvisio/libvisio-0.1.7.ebuild | 62 +++++++++++++++++++++++++++++++
 media-libs/libvisio/libvisio-9999.ebuild  | 36 ++++++++++--------
 3 files changed, 86 insertions(+), 16 deletions(-)
 create mode 100644 media-libs/libvisio/libvisio-0.1.7.ebuild

(limited to 'media-libs/libvisio')

diff --git a/media-libs/libvisio/Manifest b/media-libs/libvisio/Manifest
index d7ed21296511..40cf0f6622f2 100644
--- a/media-libs/libvisio/Manifest
+++ b/media-libs/libvisio/Manifest
@@ -1,4 +1,6 @@
 DIST libvisio-0.1.6.tar.xz 676396 BLAKE2B dbd96b64a3789e275a47fe59cd939620787937e31ee11b7af7977575c183ade233afdb952d4c2e362312ae400d23726cbd01e3ccb644c9a413abc84ddbe0f161 SHA512 58cee8cfe4205b2cad2f11dbe17882e57ebf0d10500116ca9d8d120e138f8eb0c65a5fea3bd7d2746bf8140377ee9deb34258597e028f9fdc8d21f270606cce1
+DIST libvisio-0.1.7.tar.xz 854296 BLAKE2B db5dd96d769c237bc2926d52a43c2496adca50b74133ea3c81df7ba5a61824891623eb33b4801b463b27f5c03946ea7ffcf827b98c95139c9659b0a1b0f7b604 SHA512 c26f67a09fa6a6d0bf6f3fff5590d5cf16983630d4f7cfcf86d9461baec58dbdf7989fd934be6db0639ca043c160aac2d008275afb9e047766bc878ac579a9ea
 EBUILD libvisio-0.1.6.ebuild 1210 BLAKE2B d2ea49d29ab3c84b415849c7434fd249e2d2d133c6e68db5f01b6bdb561aec6197ebbe3798a7112ca0c41a307fe3f08ba6e176b0f2ac6a43f7c8984f2a54c136 SHA512 b64ee3644f2eb32d2d9cf7eee267f04e4f60b49015ea7014b341d1643b7a3757d45ee93c6a8eb1ba580991ae5becfeeceefc0cef382a0d63c0239bff229f5530
-EBUILD libvisio-9999.ebuild 1211 BLAKE2B 50fe1bbacc7ac8885aa556a5a1123267567e5cc7b3db06ba5b3341b9511bd254c8899135c6a64bd053908d31a4634b35e26a6f87229fd972a1725d69b1d2df3a SHA512 50653377d8d8e6b326ac79e4de255b793db97f0d4fc12520117174a7d96746c435af694e2f7c8fb367abb7522ee3a3145ff6387dee0cdf85ec14d2d15042b9fa
+EBUILD libvisio-0.1.7.ebuild 1251 BLAKE2B 2bc8acf7656e4a83c5de89d5a33d0bbc39d50865786eb10c3966ec2ec306e7ba00cfb93717aba30aaea9cdaff6b56fd9265bb606c21cb891b37f9ba9ec2b9a5e SHA512 4857277b54992988cf485cc82bbaefbe05504a73e87817dca51e79bb1b1f51b79fac81f0b6775b3552e5f60d4f4b1a31d6449f25ae66bc66babf5d7c184d4471
+EBUILD libvisio-9999.ebuild 1251 BLAKE2B 2bc8acf7656e4a83c5de89d5a33d0bbc39d50865786eb10c3966ec2ec306e7ba00cfb93717aba30aaea9cdaff6b56fd9265bb606c21cb891b37f9ba9ec2b9a5e SHA512 4857277b54992988cf485cc82bbaefbe05504a73e87817dca51e79bb1b1f51b79fac81f0b6775b3552e5f60d4f4b1a31d6449f25ae66bc66babf5d7c184d4471
 MISC metadata.xml 321 BLAKE2B 845e098f8136b178e62b70bb06d8ce26ed7e2b9aec93358180d36cc8de5d4436501fa13521dcc7b4a7f8e311603b25c9d30d23db216008d3d96af5e462611a9a SHA512 a9d2208bf93a05e3406aee66412b46e731ce5a858e3e5e4a6668568b3ccba863d540f3e6224bc7e5ed8c6ad22d330fc0e30ecc90df2f8a866280bb138040fc12
diff --git a/media-libs/libvisio/libvisio-0.1.7.ebuild b/media-libs/libvisio/libvisio-0.1.7.ebuild
new file mode 100644
index 000000000000..e4147a14c125
--- /dev/null
+++ b/media-libs/libvisio/libvisio-0.1.7.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libvisio.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://dev-www.libreoffice.org/src/libvisio/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+DESCRIPTION="Library parsing the file format of MS Visio documents"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libvisio"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+IUSE="doc static-libs test tools"
+
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/librevenge
+	dev-libs/libxml2
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-util/gperf
+	sys-devel/libtool
+	test? ( dev-util/cppunit )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	# bug 619688
+	append-cxxflags -std=c++14
+
+	local myeconfargs=(
+		$(use_with doc docs)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/media-libs/libvisio/libvisio-9999.ebuild b/media-libs/libvisio/libvisio-9999.ebuild
index 1f7cc355b43d..e4147a14c125 100644
--- a/media-libs/libvisio/libvisio-9999.ebuild
+++ b/media-libs/libvisio/libvisio-9999.ebuild
@@ -1,35 +1,39 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 inherit flag-o-matic
 
-EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libvisio.git"
-[[ ${PV} == 9999 ]] && inherit autotools git-r3
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libvisio.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://dev-www.libreoffice.org/src/libvisio/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
 
-DESCRIPTION="Library parsing the visio documents"
+DESCRIPTION="Library parsing the file format of MS Visio documents"
 HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libvisio"
-[[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libvisio/${P}.tar.xz"
 
 LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
 SLOT="0"
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
 IUSE="doc static-libs test tools"
 
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
 RDEPEND="
 	dev-libs/icu:=
 	dev-libs/librevenge
 	dev-libs/libxml2
 "
 DEPEND="${RDEPEND}
-	dev-lang/perl
 	dev-libs/boost
 	dev-util/gperf
 	sys-devel/libtool
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen )
 	test? ( dev-util/cppunit )
 "
 
@@ -43,11 +47,13 @@ src_configure() {
 	# bug 619688
 	append-cxxflags -std=c++14
 
-	econf \
-		$(use_with doc docs) \
-		$(use_enable static-libs static) \
-		$(use_enable test tests) \
+	local myeconfargs=(
+		$(use_with doc docs)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
 		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
 }
 
 src_install() {
-- 
cgit v1.2.3