From 8c8f1cfd2aa9e839aad7dad6fd43b370cfbc0a1e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 10 Jan 2024 13:02:42 +0000
Subject: gentoo auto-resync : 10:01:2024 - 13:02:42

---
 media-libs/mlt/Manifest             |   1 +
 media-libs/mlt/mlt-7.22.0-r1.ebuild | 172 ++++++++++++++++++++++++++++++++++++
 2 files changed, 173 insertions(+)
 create mode 100644 media-libs/mlt/mlt-7.22.0-r1.ebuild

(limited to 'media-libs/mlt')

diff --git a/media-libs/mlt/Manifest b/media-libs/mlt/Manifest
index 9dcb1c987232..e2ad3d7b5026 100644
--- a/media-libs/mlt/Manifest
+++ b/media-libs/mlt/Manifest
@@ -2,5 +2,6 @@ AUX mlt-6.10.0-swig-underlinking.patch 596 BLAKE2B b51670d051ae2bd016da65f560ed8
 AUX mlt-6.22.1-no_lua_bdepend.patch 153 BLAKE2B 3ea31c570e7bef81bda0905549baedee8b9eed2bc14c535abff02985d573e4606f4f8f42213bcbc86fa68af905ba6c39dddcbf63efa20172c608659153d79073 SHA512 b382ee68f2815b4aa62ce7708a7452536f2bc0287dc4d59f557c08fbf51d6bef7607f63e11e991b4f52eb7e06afbde06d53aac3d42b4a0c96f59332ec17d48cd
 AUX mlt-7.0.1-cmake-symlink.patch 569 BLAKE2B 06f7c8e7ec78206bb1344bab98f1d9ec816b16c458300964fe31ff30f8f2cc64d8f25a795773fd64db7249b031a164c350b55b6326c4d07d73ffd27f8786a911 SHA512 6deb458c3a89f800b4770460330c1e545c22d3a7304f0713b7ae214145d1413a3061c7c026ab2f6fc44801d1d7505352f03c0da7034e817b684e0ebb25d9a94f
 DIST mlt-7.22.0.tar.gz 1659954 BLAKE2B ab3dff26446a048e79d5f11942b05fa557ec91a813b14bd46492fe66c46a2e6685f3835ff647b69e6b6ebe137a345fc7eb17c8e88bdfd3bdb81e41eeca910aaa SHA512 84763e1cb8495be9476637d2474aa492906b904990905f9283faffff75829553cf87b097166fe6d382acc043422e6da45014ca4ba281c7fc68f10ebe3cec4fee
+EBUILD mlt-7.22.0-r1.ebuild 3913 BLAKE2B 4c5d489d65fc918447b6106183c290edfd0563bae5b74fb28c15804c36016ac5a622cefbec7b40e66435220f0e45478b30c6521baf4e58863e5bb5064aafb83d SHA512 2236f38f4ae9e73868064dc22768a8d86ba16742e01381d888ac88c6257fdff6fe9dcfe6d4d5f521122eff5a286ff7f37328ba7078b5fb376d521c7bb5c1aedc
 EBUILD mlt-7.22.0.ebuild 3716 BLAKE2B cd2bd2aa613ab8a90bbf2ce83d303f513fde781cb9f49a31030e719f8aecb5b42ad7eeb0fbe20ad2d01d63cad6f171b522187db6cb754c546755bb6d446b2fbe SHA512 a573659972260e7b7d515d16b027c71cbbb79967f5336d1eb1205d29596a9e44b8d30f0a5704938697569b10e15cbf3eb7f93dd014f8cbade24522a8120b7e73
 MISC metadata.xml 1412 BLAKE2B 8d4eed394f1d1e95e5559466ef1840978966e8f1f7b89fdfd2549b2a35b6ce8f114c9373374fdaefe320cc34a4dc8cbd9f6c4433740d1ae9680de54484b5e3d1 SHA512 b19c711dc3798f952e0223dc0628b25aa3c9a296d66ee2f2b7f46a55b82e71c0c583ee64517be88dcc55eb1e9c31aa782b9043eb7630a853077afb1bf8b4dedd
diff --git a/media-libs/mlt/mlt-7.22.0-r1.ebuild b/media-libs/mlt/mlt-7.22.0-r1.ebuild
new file mode 100644
index 000000000000..586827098f4a
--- /dev/null
+++ b/media-libs/mlt/mlt-7.22.0-r1.ebuild
@@ -0,0 +1,172 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+inherit python-single-r1 cmake
+
+DESCRIPTION="Open source multimedia framework for television broadcasting"
+HOMEPAGE="https://www.mltframework.org/"
+SRC_URI="https://github.com/mltframework/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/7"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug ffmpeg frei0r gtk jack libsamplerate opencv opengl python qt5 qt6 rtaudio rubberband sdl test vdpau vidstab xine xml"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# Needs unpackaged 'kwalify'
+RESTRICT="test"
+
+# rtaudio will use OSS on non linux OSes
+# Qt already needs FFTW/PLUS so let's just always have it on to ensure
+# MLT is useful: bug #603168.
+DEPEND="
+	>=media-libs/libebur128-1.2.2:=
+	sci-libs/fftw:3.0=
+	ffmpeg? ( media-video/ffmpeg:0=[vdpau?] )
+	frei0r? ( media-plugins/frei0r-plugins )
+	gtk? (
+		media-libs/libexif
+		x11-libs/pango
+	)
+	jack? (
+		>=dev-libs/libxml2-2.5
+		media-libs/ladspa-sdk
+		virtual/jack
+	)
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
+	opencv? ( >=media-libs/opencv-4.5.1:=[contrib] )
+	opengl? (
+		media-libs/libglvnd
+		media-video/movit
+	)
+	python? ( ${PYTHON_DEPS} )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+		media-libs/libexif
+		x11-libs/libX11
+	)
+	qt6? (
+		dev-qt/qt5compat:6
+		dev-qt/qtbase:6[gui,network,widgets,xml]
+		dev-qt/qtsvg:6
+		media-libs/libexif
+		x11-libs/libX11
+	)
+	rtaudio? (
+		>=media-libs/rtaudio-4.1.2
+		kernel_linux? ( media-libs/alsa-lib )
+	)
+	rubberband? ( media-libs/rubberband )
+	sdl? (
+		media-libs/libsdl2[X,opengl,video]
+		media-libs/sdl2-image
+	)
+	vidstab? ( media-libs/vidstab )
+	xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
+	xml? ( >=dev-libs/libxml2-2.5 )
+"
+#	java? ( >=virtual/jre-1.8:* )
+#	perl? ( dev-lang/perl )
+#	php? ( dev-lang/php )
+#	ruby? ( ${RUBY_DEPS} )
+#	sox? ( media-sound/sox )
+#	tcl? ( dev-lang/tcl:0= )
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	python? ( >=dev-lang/swig-2.0 )
+"
+
+DOCS=( AUTHORS NEWS README.md )
+
+PATCHES=(
+	# downstream
+	"${FILESDIR}"/${PN}-6.10.0-swig-underlinking.patch
+	"${FILESDIR}"/${PN}-6.22.1-no_lua_bdepend.patch
+	"${FILESDIR}"/${PN}-7.0.1-cmake-symlink.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Respect CFLAGS LDFLAGS when building shared libraries. Bug #308873
+	if use python; then
+		sed -i "/mlt.so/s/ -lmlt++ /& ${CFLAGS} ${LDFLAGS} /" src/swig/python/build || die
+		python_fix_shebang src/swig/python
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DCLANG_FORMAT=OFF
+		-DGPL=ON
+		-DGPL3=ON
+		-DBUILD_TESTING=$(usex test)
+		-DMOD_KDENLIVE=ON
+		-DMOD_SDL1=OFF
+		-DMOD_SDL2=$(usex sdl)
+		-DMOD_AVFORMAT=$(usex ffmpeg)
+		-DMOD_PLUS=ON
+		-DMOD_FREI0R=$(usex frei0r)
+		-DMOD_GDK=$(usex gtk)
+		-DMOD_JACKRACK=$(usex jack)
+		-DMOD_RESAMPLE=$(usex libsamplerate)
+		-DMOD_OPENCV=$(usex opencv)
+		-DMOD_MOVIT=$(usex opengl)
+		-DMOD_QT=$(usex qt5)
+		-DMOD_GLAXNIMATE=$(usex qt5)
+		-DMOD_QT6=$(usex qt6)
+		-DMOD_GLAXNIMATE_QT6=$(usex qt6)
+		-DMOD_RTAUDIO=$(usex rtaudio)
+		-DMOD_RUBBERBAND=$(usex rubberband)
+		-DMOD_VIDSTAB=$(usex vidstab)
+		-DMOD_XINE=$(usex xine)
+		-DMOD_XML=$(usex xml)
+		-DMOD_SOX=OFF
+	)
+
+	# TODO: rework upstream CMake to allow controlling MMX/SSE/SSE2
+	# TODO: add swig language bindings?
+	# see also https://www.mltframework.org/twiki/bin/view/MLT/ExtremeMakeover
+
+	if use python; then
+		mycmakeargs+=(
+			-DSWIG_PYTHON=ON
+			-DPython3_EXECUTABLE="${PYTHON}"
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	insinto /usr/share/${PN}
+	doins -r demo
+
+	#
+	# Install SWIG bindings
+	#
+
+	docinto swig
+
+	if use python; then
+		dodoc "${S}"/src/swig/python/play.py
+		python_optimize
+	fi
+}
-- 
cgit v1.2.3