From bc4457d8e0e53a2e43c4254d08053ba9708663e1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 20 Jun 2023 01:14:49 +0100
Subject: gentoo auto-resync : 20:06:2023 - 01:14:49

---
 media-libs/sdl2-gfx/sdl2-gfx-1.0.4-r1.ebuild | 55 ++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 media-libs/sdl2-gfx/sdl2-gfx-1.0.4-r1.ebuild

(limited to 'media-libs/sdl2-gfx/sdl2-gfx-1.0.4-r1.ebuild')

diff --git a/media-libs/sdl2-gfx/sdl2-gfx-1.0.4-r1.ebuild b/media-libs/sdl2-gfx/sdl2-gfx-1.0.4-r1.ebuild
new file mode 100644
index 000000000000..28cd3309e9d6
--- /dev/null
+++ b/media-libs/sdl2-gfx/sdl2-gfx-1.0.4-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+MY_P="${P/sdl2-/SDL2_}"
+DESCRIPTION="Graphics drawing primitives library for SDL2"
+HOMEPAGE="https://www.ferzkopp.net/joomla/content/view/19/14/"
+SRC_URI="https://www.ferzkopp.net/Software/SDL2_gfx/${MY_P}.tar.gz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="doc cpu_flags_x86_mmx"
+
+DEPEND=">=media-libs/libsdl2-2.0.1-r1[video,${MULTILIB_USEDEP}]"
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS ChangeLog README )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.0.4-slibtool.patch
+)
+
+src_prepare() {
+	default
+	mv configure.in configure.ac || die
+	sed -i \
+		-e 's/ -O / /' \
+		configure.ac || die
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable cpu_flags_x86_mmx mmx)
+		--disable-static
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use doc ; then
+		docinto html
+		dodoc -r Docs/html/*
+	fi
+
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}
-- 
cgit v1.2.3