From a98588cfddf3d6e88a5f17d7f399b695163c7a85 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 3 May 2024 00:00:22 +0100
Subject: gentoo auto-resync : 03:05:2024 - 00:00:22

---
 media-libs/tiff/Manifest             |  1 +
 media-libs/tiff/tiff-4.6.0-r1.ebuild | 82 ++++++++++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)
 create mode 100644 media-libs/tiff/tiff-4.6.0-r1.ebuild

(limited to 'media-libs/tiff')

diff --git a/media-libs/tiff/Manifest b/media-libs/tiff/Manifest
index 6686f9ecddbb..f32c1cd04359 100644
--- a/media-libs/tiff/Manifest
+++ b/media-libs/tiff/Manifest
@@ -10,5 +10,6 @@ DIST tiff-4.6.0.tar.xz 2124388 BLAKE2B 3b508b02b0a536c5bc8e67fe4c1b09ae9c8302527
 DIST tiff-4.6.0.tar.xz.sig 310 BLAKE2B 9f159a5839dd41bda34eceeed6e451455fbcfec5d51ebb097038e3977a391a751e91a9f683375593f45af0f9c8f0dbe55a0cc437fe4512537b30d513adfdb2c0 SHA512 da87b4294e17d49cf60e81ec5285f503291532423330552e41dddfb672c0636e95b8a80d603c3095abbee469cb7dce63c2df0c22b751a3bf8541550f97f78b49
 EBUILD tiff-4.5.0-r2.ebuild 2864 BLAKE2B 86c265644953029f369ef4ea8a75ac463f2e7792c129b05d71eb7711e58ec14323bbde65500b123119cde3241eccb30a226d39c7ce188af0f005ea6fecda4ace SHA512 f841c9e5df12cac12a3b6c594317cee5eac92631c1df434f7ddfe33bbf7666b05a1cc20b725c87e52677f1729ceabe9078b9abf7cf8b4ee0a63b4aa6b5f7edad
 EBUILD tiff-4.5.1.ebuild 2481 BLAKE2B 1de6d42ea0adb8b49571c2c77cebd651fbd733cdf11e06d63dac12ca2c3f325249bb74bbb238192ed5e6453c3e96dd02cd326e1a7e12eecaa090d531c9a1411c SHA512 8040959ab28166f077d3f5e45cd42c749cc957e249891e139dcbee1e6b0e08e319df27f84ada066f717c7cff53e077b993c37eb52f7e6941d6ee5747ea26701e
+EBUILD tiff-4.6.0-r1.ebuild 2472 BLAKE2B 7b6261cd5f2bcbc58624d93c92a6d349e7931bbb6f831819e849b1d144dd084e8a51f45a2fc0ad4a1bfc750dca28d11914b17261e7559a75a8d27679515b79f3 SHA512 4dfdf84236273fba1887994c27c5839dd40bf85db43f9c7872c66691eff4a677466d2a9cbab70c103ab1c31f5639bf142e40034fbbb54d3df61430b849b2b25a
 EBUILD tiff-4.6.0.ebuild 2428 BLAKE2B 10a13725ebfbc229d00d16caa09a9823cce3fe72c166ad9526b5e4544e6bba20555d401884d41d49f8aa817e41092650482750c832176497665e3ac4e8e623e6 SHA512 b3311c692e9cca01195722190ede7b2b95b256ca193e48ea7f6e24f7d6c38bfadcf1933cfc7e90d20862378afb00d9ab1901beaff6718e27fe47b324ab87b2c6
 MISC metadata.xml 615 BLAKE2B b76f8c2714111fe539c2d15b56361bc3b2bc7469b3cd74cf933a9dad4ac8577b7bb1a2bc010ceb3623640778d1dbc912433988e938db7df8f8fca67c51003c2c SHA512 81b22e0e2763fbcd573d2c1fee362785c15c7c33cc00d0f7ce89eb9f95f55e64aee78eefc51de6d7270aa966102b744f070620828becbbb03012cc22e3e99469
diff --git a/media-libs/tiff/tiff-4.6.0-r1.ebuild b/media-libs/tiff/tiff-4.6.0-r1.ebuild
new file mode 100644
index 000000000000..d42050f0cb22
--- /dev/null
+++ b/media-libs/tiff/tiff-4.6.0-r1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Release signer can vary per version but not clear if others will be doing
+# them in future, so gone with Even Rouault for now as he does other geosci
+# stuff too like PROJ, GDAL. Previous release manager of TIFF was
+# GraphicsMagick maintainer Bob Friesenhahn. Please be careful when verifying
+# who made releases.
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/rouault.asc
+inherit libtool multilib-minimal verify-sig flag-o-matic
+
+MY_P="${P/_rc/rc}"
+DESCRIPTION="Tag Image File Format (TIFF) library"
+HOMEPAGE="http://libtiff.maptools.org"
+SRC_URI="https://download.osgeo.org/libtiff/${MY_P}.tar.xz"
+SRC_URI+=" verify-sig? ( https://download.osgeo.org/libtiff/${MY_P}.tar.xz.sig )"
+S="${WORKDIR}/${PN}-$(ver_cut 1-3)"
+
+LICENSE="libtiff"
+SLOT="0/6"
+if [[ ${PV} != *_rc* ]] ; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+IUSE="+cxx jbig jpeg lzma static-libs test webp zlib zstd"
+RESTRICT="!test? ( test )"
+
+# bug #483132
+REQUIRED_USE="test? ( jpeg )"
+
+RDEPEND="
+	jbig? ( >=media-libs/jbigkit-2.1:=[${MULTILIB_USEDEP}] )
+	jpeg? ( media-libs/libjpeg-turbo:=[${MULTILIB_USEDEP}] )
+	lzma? ( >=app-arch/xz-utils-5.0.5-r1[${MULTILIB_USEDEP}] )
+	webp? ( media-libs/libwebp:=[${MULTILIB_USEDEP}] )
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
+	zstd? ( >=app-arch/zstd-1.3.7-r1:=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-evenrouault )"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/tiffconf.h
+)
+
+src_prepare() {
+	default
+
+	# Added to fix cross-compilation
+	elibtoolize
+}
+
+multilib_src_configure() {
+	append-lfs-flags
+
+	local myeconfargs=(
+		--disable-sphinx
+		--with-docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable cxx)
+		$(use_enable jbig)
+		$(use_enable jpeg)
+		$(use_enable lzma)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+		$(use_enable webp)
+		$(use_enable zlib)
+		$(use_enable zstd)
+		--disable-libdeflate #bug #930111
+
+		$(multilib_native_enable docs)
+		$(multilib_native_enable contrib)
+		$(multilib_native_enable tools)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	find "${ED}" -type f -name '*.la' -delete || die
+	rm "${ED}"/usr/share/doc/${PF}/{README*,RELEASE-DATE,TODO,VERSION} || die
+}
-- 
cgit v1.2.3