From 34dea8e38f88007799629d0a56b12dec480b1d21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 20 Jun 2021 14:45:01 +0100
Subject: gentoo resync : 20.06.2021

---
 media-radio/ibp/Manifest           |  2 +-
 media-radio/ibp/ibp-0.21-r1.ebuild | 53 -------------------------------------
 media-radio/ibp/ibp-0.21-r2.ebuild | 54 ++++++++++++++++++++++++++++++++++++++
 3 files changed, 55 insertions(+), 54 deletions(-)
 delete mode 100644 media-radio/ibp/ibp-0.21-r1.ebuild
 create mode 100644 media-radio/ibp/ibp-0.21-r2.ebuild

(limited to 'media-radio/ibp')

diff --git a/media-radio/ibp/Manifest b/media-radio/ibp/Manifest
index 792d9a17acd9..d9d117928159 100644
--- a/media-radio/ibp/Manifest
+++ b/media-radio/ibp/Manifest
@@ -1,3 +1,3 @@
 DIST ibp-0.21.tgz 33536 BLAKE2B 0fee17215d6e6fc99dba6d216f4e2b79bf0be89f6edd68fe5b0c0f4ca6fee794274a9ec0c08b73f502fd57dd0208d1d0fcf362d0a8671d94d4a6a613f578e443 SHA512 784bdcae61ce41dff7d88eb2068171dafa607012660393188326e94e323fdf5badebf3d8a24016c83c96c770b6d0935fc35aef5aca6bbfd665b7f2ccf39118ca
-EBUILD ibp-0.21-r1.ebuild 1167 BLAKE2B cebd1220a37cb8105b7f5e4a4b8ef3e0f19e2d82476cb5cdeed9e08ccfc16f3eb2be488a77980de1097ab85c94091c7076b925ca9859ede6e03cfdaad2b64f6b SHA512 e3991259438d90d4cfd8183b1d962dd9f3fa660759b46c713df31e30db5cc30c6eed72d31a0e42a8ddc654151d0ce12ad946e6fb6f38e6ff6e45fa580709b360
+EBUILD ibp-0.21-r2.ebuild 1164 BLAKE2B 568e345c87dd5815bda07f04efd23cdfe029991677805a17c02307e297aabd2f0a330b3d22e8549765052b9714f4ab471d264c7154e919b0645de3e632a01e1e SHA512 890f366cf23fc30cfb9bbfe1a1ea93d05e5a320d79afe7899822c844d75ce10e5ffcabcea249c1f039059ef512d4d064e70e0e4b985ae141e54fe2592bfc98ed
 MISC metadata.xml 249 BLAKE2B d6fa8a349066f9684c68c3086f53e41ebf30b6e313e8e8e752a953c0eaa0853448fe17e5ed46836bc5e149a282a33c7408c675d3b39eb3d59ddc1c1ad86bf716 SHA512 965ae00fa198dd8f5869c4c14ff3e28c7d76be7182be6ba4bedbb68d7138da5be3c8bb993689db2c73ac328456015ebdf018ee1b308d6988067810d1156bd179
diff --git a/media-radio/ibp/ibp-0.21-r1.ebuild b/media-radio/ibp/ibp-0.21-r1.ebuild
deleted file mode 100644
index a02af617b34f..000000000000
--- a/media-radio/ibp/ibp-0.21-r1.ebuild
+++ /dev/null
@@ -1,53 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="6"
-inherit toolchain-funcs
-
-DESCRIPTION="Shows currently transmitting beacons of the International Beacon Project (IBP)"
-HOMEPAGE="http://wwwhome.cs.utwente.nl/~ptdeboer/ham/ibp.html"
-SRC_URI="http://wwwhome.cs.utwente.nl/~ptdeboer/ham/${P}.tgz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="X"
-
-RDEPEND="sys-libs/ncurses:0
-	X? ( x11-libs/libX11  )"
-DEPEND="${RDEPEND}
-	X? ( >=x11-misc/imake-1.0.8-r1 )"
-
-src_prepare() {
-	# respect CFLAGS if built without USE=X
-	sed -i -e "s/= -D/+= -D/" Makefile || die
-	# fix compile if ncurses is built with separate libtinfo
-	if has_version "sys-libs/ncurses:0[tinfo]" ;then
-		sed -i -e "s/-lcurses/-lcurses -ltinfo/" Imakefile Makefile || die
-	fi
-
-	eapply_user
-}
-
-src_configure() {
-	if use X ;then
-		CC="$(tc-getBUILD_CC)" LD="$(tc-getLD)" \
-			IMAKECPP="${IMAKECPP:-$(tc-getCPP)}" xmkmf || die
-	fi
-}
-
-src_compile() {
-	if use X ; then
-		emake \
-			CC="$(tc-getCC)" \
-			LOCAL_LDFLAGS="${LDFLAGS}" \
-			CDEBUGFLAGS="${CFLAGS}"
-	else
-		emake CC="$(tc-getCC)"
-	fi
-}
-
-src_install() {
-	dobin ${PN}
-	doman ${PN}.1
-}
diff --git a/media-radio/ibp/ibp-0.21-r2.ebuild b/media-radio/ibp/ibp-0.21-r2.ebuild
new file mode 100644
index 000000000000..08a4b2b5fa4a
--- /dev/null
+++ b/media-radio/ibp/ibp-0.21-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Shows currently transmitting beacons of the International Beacon Project (IBP)"
+HOMEPAGE="http://wwwhome.cs.utwente.nl/~ptdeboer/ham/ibp.html"
+SRC_URI="http://wwwhome.cs.utwente.nl/~ptdeboer/ham/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="X"
+
+RDEPEND="sys-libs/ncurses:0=
+	X? ( x11-libs/libX11  )"
+DEPEND="${RDEPEND}
+	X? ( >=x11-misc/imake-1.0.8-r1 )"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	# Respect CFLAGS if built without USE=X
+	sed -i -e "s/= -D/+= -D/" Makefile || die
+
+	# Fix compile if ncurses is built with separate libtinfo
+	sed -i -e "s:-lcurses:$($(tc-getPKG_CONFIG) --libs ncurses):" Imakefile Makefile || die
+
+	eapply_user
+}
+
+src_configure() {
+	if use X ;then
+		CC="$(tc-getBUILD_CC)" LD="$(tc-getLD)" \
+			IMAKECPP="${IMAKECPP:-$(tc-getCPP)}" xmkmf || die
+	fi
+}
+
+src_compile() {
+	if use X ; then
+		emake \
+			CC="$(tc-getCC)" \
+			LOCAL_LDFLAGS="${LDFLAGS}" \
+			CDEBUGFLAGS="${CFLAGS}"
+	else
+		emake CC="$(tc-getCC)"
+	fi
+}
+
+src_install() {
+	dobin ${PN}
+	doman ${PN}.1
+}
-- 
cgit v1.2.3