From 623ee73d661e5ed8475cb264511f683407d87365 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 12 Apr 2020 03:41:30 +0100
Subject: gentoo Easter resync : 12.04.2020

---
 media-sound/fmit/fmit-1.0.15-r3.ebuild | 58 ++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 media-sound/fmit/fmit-1.0.15-r3.ebuild

(limited to 'media-sound/fmit/fmit-1.0.15-r3.ebuild')

diff --git a/media-sound/fmit/fmit-1.0.15-r3.ebuild b/media-sound/fmit/fmit-1.0.15-r3.ebuild
new file mode 100644
index 000000000000..1d322a86d482
--- /dev/null
+++ b/media-sound/fmit/fmit-1.0.15-r3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils
+
+DESCRIPTION="Free Music Instrument Tuner"
+HOMEPAGE="https://gillesdegottex.github.io/fmit"
+SRC_URI="https://github.com/gillesdegottex/fmit/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa jack oss portaudio"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5[-gles2-only]
+	dev-qt/qtmultimedia:5
+	dev-qt/qtopengl:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	>=sci-libs/fftw-3.3.4:3.0=
+	virtual/opengl
+	alsa? ( media-libs/alsa-lib )
+	jack? ( virtual/jack )
+	portaudio? ( media-libs/portaudio )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+src_prepare() {
+	# Fix the path to readme file to prevent errors on start up
+	sed -i "/QFile readmefile/c\QFile readmefile \
+		(\"/usr/share/doc/${PF}/README.txt\");" \
+		src/main.cpp || die "README sed failed"
+	# Fix the PREFIX location, insert real path.
+	sed -i "/QString fmitprefix/c\QString fmitprefix(STR(/usr));" \
+		src/main.cpp || die "PREFIX fix sed failed"
+	# Fix the PREFIX location, insert real path.
+	sed -i "/QString fmitprefix/c\QString fmitprefix(STR(/usr));" \
+		src/modules/MicrotonalView.cpp || die "PREFIX fix sed failed"
+	default
+}
+
+src_configure() {
+	local config flag
+	for flag in alsa jack portaudio oss; do
+		use ${flag} && config+=" acs_${flag}"
+	done
+
+	"$(qt5_get_bindir)"/lrelease fmit.pro || die "Running lrelease failed"
+
+	eqmake5 CONFIG+="${config}" fmit.pro PREFIX="${D}"/usr \
+		PREFIXSHORTCUT="${D}"/usr DISTDIR=/usr
+}
-- 
cgit v1.2.3