From aa3411e241a201d53a2689766fe419f2756819f3 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 24 Mar 2019 17:22:19 +0000
Subject: gentoo resync : 24.03.2019

---
 media-sound/kid3/kid3-3.7.1.ebuild | 90 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 media-sound/kid3/kid3-3.7.1.ebuild

(limited to 'media-sound/kid3/kid3-3.7.1.ebuild')

diff --git a/media-sound/kid3/kid3-3.7.1.ebuild b/media-sound/kid3/kid3-3.7.1.ebuild
new file mode 100644
index 000000000000..6ae8aae43403
--- /dev/null
+++ b/media-sound/kid3/kid3-3.7.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_KDEINSTALLDIRS="false"
+KDE_HANDBOOK="false" # buildsystem applies broken python hacks, bug #614950
+inherit kde5
+
+DESCRIPTION="Simple tag editor based on Qt"
+HOMEPAGE="https://kid3.sourceforge.io/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE="acoustid flac kde mp3 mp4 +taglib vorbis"
+
+REQUIRED_USE="flac? ( vorbis )"
+
+COMMON_DEPEND="
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtmultimedia)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	sys-libs/readline:0=
+	acoustid? (
+		media-libs/chromaprint
+		virtual/ffmpeg
+	)
+	flac? (
+		media-libs/flac[cxx]
+		media-libs/libvorbis
+	)
+	kde? (
+		$(add_frameworks_dep kconfig)
+		$(add_frameworks_dep kconfigwidgets)
+		$(add_frameworks_dep kcoreaddons)
+		$(add_frameworks_dep kwidgetsaddons)
+		$(add_frameworks_dep kxmlgui)
+	)
+	mp3? ( media-libs/id3lib )
+	mp4? ( media-libs/libmp4v2:0 )
+	taglib? ( >=media-libs/taglib-1.9.1 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	!media-sound/kid3:4
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	$(add_qt_dep linguist-tools)
+"
+
+src_prepare() {
+	# overengineered upstream build system
+	# kde5 eclass src_prepare leads to compile failure
+
+	# only enable handbook when required
+	if ! use_if_iuse handbook ; then
+		cmake_comment_add_subdirectory ${KDE_DOC_DIR}
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_CHROMAPRINT=$(usex acoustid)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_ID3LIB=$(usex mp3)
+		-DWITH_MP4V2=$(usex mp4)
+		-DWITH_TAGLIB=$(usex taglib)
+		-DWITH_VORBIS=$(usex vorbis)
+	)
+
+	if use kde ; then
+		mycmakeargs+=( "-DWITH_APPS=KDE;CLI" )
+	else
+		mycmakeargs+=( "-DWITH_APPS=Qt;CLI" )
+	fi
+
+	kde5_src_configure
+}
-- 
cgit v1.2.3