From 40aaaa64e86ba6710bbeb31c4615a6ce80e75e11 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 28 Apr 2021 20:21:43 +0100
Subject: gentoo resync : 28.04.2021

---
 net-dialup/minicom/minicom-2.8.ebuild | 60 +++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 net-dialup/minicom/minicom-2.8.ebuild

(limited to 'net-dialup/minicom/minicom-2.8.ebuild')

diff --git a/net-dialup/minicom/minicom-2.8.ebuild b/net-dialup/minicom/minicom-2.8.ebuild
new file mode 100644
index 000000000000..dad212bacba1
--- /dev/null
+++ b/net-dialup/minicom/minicom-2.8.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Serial Communication Program"
+HOMEPAGE="https://salsa.debian.org/minicom-team/minicom"
+SRC_URI="https://salsa.debian.org/${PN}-team/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="nls"
+
+DEPEND="sys-libs/ncurses:="
+
+RDEPEND="
+	${DEPEND}
+	net-dialup/lrzsz
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.8-gentoo-runscript.patch
+	"${FILESDIR}"/${PN}-2.8-lockdir.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Lockdir must exist if not manually specified.
+	# '/var/lock' is created by OpenRC.
+	local myeconfargs=(
+		--disable-rpath
+		--enable-lock-dir="/var/lock"
+		$(use_enable nls)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	insinto /etc/minicom
+	doins "${FILESDIR}"/minirc.dfl
+}
+
+pkg_preinst() {
+	[[ -s "${EROOT}"/etc/minicom/minirc.dfl ]] && rm -f "${ED}"/etc/minicom/minirc.dfl
+}
-- 
cgit v1.2.3