From 7e2b5bc2c2e2e045de6095d46c24ee857453adf2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 11 Aug 2023 09:34:39 +0100
Subject: gentoo auto-resync : 11:08:2023 - 09:34:39

---
 net-fs/s3fs/s3fs-1.93.ebuild | 67 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 net-fs/s3fs/s3fs-1.93.ebuild

(limited to 'net-fs/s3fs/s3fs-1.93.ebuild')

diff --git a/net-fs/s3fs/s3fs-1.93.ebuild b/net-fs/s3fs/s3fs-1.93.ebuild
new file mode 100644
index 000000000000..f946efb66bc7
--- /dev/null
+++ b/net-fs/s3fs/s3fs-1.93.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+MY_PN=${PN}-fuse
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Amazon S3 mounting via fuse"
+HOMEPAGE="https://github.com/s3fs-fuse/s3fs-fuse/"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="gnutls nettle nss"
+REQUIRED_USE="nettle? ( gnutls !nss )"
+
+# Requires active internet connection and it tries to download some binaries for later execution
+RESTRICT="test"
+
+DEPEND="
+	dev-libs/libxml2:2
+	net-misc/curl
+	sys-fs/fuse:0
+	nss? ( dev-libs/nss )
+	!nss? (
+		gnutls? (
+			net-libs/gnutls:=
+			nettle? ( dev-libs/nettle:= )
+		)
+		!gnutls? ( dev-libs/openssl:0= )
+	)
+"
+
+RDEPEND="${DEPEND}
+	app-misc/mime-types
+"
+
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	sed -i 's/ -D_FORTIFY_SOURCE=3//' configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with nettle)
+	)
+	if use nss; then
+		myeconfargs+=( $(use_with nss) )
+	elif use gnutls; then
+		myeconfargs+=( $(use_with gnutls) )
+	else
+		myeconfargs+=( --with-openssl )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
-- 
cgit v1.2.3