From 4c2ed878d2353b3decc88b86f66017cdee3ceeeb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 30 Aug 2023 04:07:22 +0100
Subject: gentoo auto-resync : 30:08:2023 - 04:07:22

---
 net-libs/libssh2/libssh2-1.11.0-r2.ebuild | 66 +++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 net-libs/libssh2/libssh2-1.11.0-r2.ebuild

(limited to 'net-libs/libssh2/libssh2-1.11.0-r2.ebuild')

diff --git a/net-libs/libssh2/libssh2-1.11.0-r2.ebuild b/net-libs/libssh2/libssh2-1.11.0-r2.ebuild
new file mode 100644
index 000000000000..2afaa2f4cbe9
--- /dev/null
+++ b/net-libs/libssh2/libssh2-1.11.0-r2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib
+
+DESCRIPTION="Library implementing the SSH2 protocol"
+HOMEPAGE="https://www.libssh2.org"
+SRC_URI="https://www.libssh2.org/download/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ~ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="gcrypt mbedtls test zlib"
+REQUIRED_USE="?? ( gcrypt mbedtls )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
+	!gcrypt? (
+		mbedtls? ( net-libs/mbedtls:0=[${MULTILIB_USEDEP}] )
+		!mbedtls? (
+			>=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}]
+		)
+	)
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.11.0-mansyntax_sh.patch
+	"${FILESDIR}"/${PN}-1.11.0-size_t.patch
+)
+
+multilib_src_configure() {
+	local crypto_backend=OpenSSL
+	if use gcrypt; then
+		crypto_backend=Libgcrypt
+	elif use mbedtls; then
+		crypto_backend=mbedTLS
+	fi
+
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_TESTING=$(usex test)
+		-DCRYPTO_BACKEND=${crypto_backend}
+		-DENABLE_ZLIB_COMPRESSION=$(usex zlib)
+	)
+
+	if use test ; then
+		# Pass separately to avoid unused var warnings w/ USE=-test
+		mycmakeargs+=(
+			-DRUN_SSHD_TESTS=OFF
+			-DRUN_DOCKER_TESTS=OFF
+		)
+	fi
+
+	cmake_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+}
-- 
cgit v1.2.3