From 93a93e9a3b53c1a73142a305ea1f8136846942ee Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 22 Dec 2021 14:08:05 +0000
Subject: gentoo resync : 22.12.2021

---
 .../libtorrent-rasterbar-2.0.5.ebuild              | 78 ++++++++++++++++++++++
 1 file changed, 78 insertions(+)
 create mode 100644 net-libs/libtorrent-rasterbar/libtorrent-rasterbar-2.0.5.ebuild

(limited to 'net-libs/libtorrent-rasterbar/libtorrent-rasterbar-2.0.5.ebuild')

diff --git a/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-2.0.5.ebuild b/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-2.0.5.ebuild
new file mode 100644
index 000000000000..7df4947a91b8
--- /dev/null
+++ b/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-2.0.5.ebuild
@@ -0,0 +1,78 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
+HOMEPAGE="https://libtorrent.org/ https://github.com/arvidn/libtorrent"
+SRC_URI="https://github.com/arvidn/libtorrent/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/2.0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="+dht debug gnutls python ssl test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/boost:=[threads(+)]
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-libs/boost[python,${PYTHON_USEDEP}]
+		')
+	)
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? ( dev-libs/openssl:= )
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="python? (
+		$(python_gen_cond_dep '
+			dev-python/setuptools[${PYTHON_USEDEP}]
+		')
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${P}-boost-1.78.patch"
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_CXX_STANDARD=17
+		-DBUILD_SHARED_LIBS=ON
+		-Dbuild_examples=OFF
+		-Ddht=$(usex dht ON OFF)
+		-Dencryption=$(usex ssl ON OFF)
+		-Dgnutls=$(usex gnutls ON OFF)
+		-Dlogging=$(usex debug ON OFF)
+		-Dpython-bindings=$(usex python ON OFF)
+		-Dbuild_tests=$(usex test ON OFF)
+	)
+
+	# We need to drop the . from the Python version to satisfy Boost's
+	# FindBoost.cmake module, bug #793038.
+	use python && mycmakeargs+=( -Dboost-python-module-name="${EPYTHON/./}" )
+
+	cmake_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# Needs running UPnP server
+		-E "test_upnp"
+	)
+
+	# Checked out Fedora's test workarounds for inspiration
+	# https://src.fedoraproject.org/rpms/rb_libtorrent/blob/rawhide/f/rb_libtorrent.spec#_120
+	LD_LIBRARY_PATH="${BUILD_DIR}:${LD_LIBRARY_PATH}" cmake_src_test
+}
-- 
cgit v1.2.3