From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 net-libs/libwebsockets/Manifest                   |  2 +
 net-libs/libwebsockets/libwebsockets-4.3.2.ebuild | 81 +++++++++++++++++++++++
 2 files changed, 83 insertions(+)
 create mode 100644 net-libs/libwebsockets/libwebsockets-4.3.2.ebuild

(limited to 'net-libs/libwebsockets')

diff --git a/net-libs/libwebsockets/Manifest b/net-libs/libwebsockets/Manifest
index aae1f51a997c..c56b0e17d884 100644
--- a/net-libs/libwebsockets/Manifest
+++ b/net-libs/libwebsockets/Manifest
@@ -1,3 +1,5 @@
 DIST libwebsockets-4.3.1.tar.gz 15607585 BLAKE2B 420343dd358e4ca45d0cadde7f0a6398dbd5043c4cd2c1a70f32dc9b5ef4cb222239971c4ce758ee156deac4d06bd18289a8e975a7f41508abfdcb05870994f6 SHA512 3cc2daadd7d2587ce946209a31741662d98367f0f9f77a1555497bef6fc6acc6cb97f5196d6ecef2d13828bb5613c60cccada03d9a01a5c970a9cfd25baeb0ae
+DIST libwebsockets-4.3.2.tar.gz 15616264 BLAKE2B 3b8657b79828102cbfba71ea789acd3b7aec7faaa6317974d182b3cb4b5091d8efcf1f184278f71674624a0f1968450ab056e1d91f9faf2c35c67c6c6f4cb695 SHA512 68d18574dea0563fa4f080c5d0d1cfe21a115bffdb17c6190f6741998f1e5db0739e252ef344ffe6fa4bd6781372456b240539471dd2aa900e43759e0f2d42ad
 EBUILD libwebsockets-4.3.1.ebuild 2302 BLAKE2B 57120058a60d6cf22d821e0527a17f443d82b98ab98708b6958327860a9f151bf33699712cafb97dee1a02620e66b62665abb5c78e872bb433e3fb3025d3f020 SHA512 6409af3d8398bd8032f5bf6ccc110ecf71c202ef4e9d6b9663bf441758da06e7a40977c922d1d9ed64fa2b6883ab23bb568129d4bf9aead8ae1249f52cb14999
+EBUILD libwebsockets-4.3.2.ebuild 2302 BLAKE2B 76dc737c442788280cb2c8f8ab87658cc9dd004fa1ef1832967f26ae1adb17a768ea1d5b862074a237b4ba218adcca5144867c6b40acc8b1ad40c9b2a02ec241 SHA512 cf34a2c3f050e1a6ac1c3d9ce71091bdf137038759f64ed907d38b152fe1c7266ca36b4bc74c9f06d95650d221dc26f58b99b9b0791a7ad9522f2e33d1319c9f
 MISC metadata.xml 1703 BLAKE2B 7ebe447535ebfd38c9df8e0bb865a7e3302fe5c820d768433c33f714c28e2b24ccd6b54d9b8f82e3d1296c50f655d6595c2e0cf41da456b4132b9fbdd0ea5769 SHA512 f1f62216dcc707501003f1da3386235fe53a6df6c14339b8c2371170224a11159c75ad88a6d3cf6abf848c6d73d4970982d2f1ec49aa6a2db5ebccdad44ef574
diff --git a/net-libs/libwebsockets/libwebsockets-4.3.2.ebuild b/net-libs/libwebsockets/libwebsockets-4.3.2.ebuild
new file mode 100644
index 000000000000..aa4726c64784
--- /dev/null
+++ b/net-libs/libwebsockets/libwebsockets-4.3.2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="A flexible pure-C library for implementing network protocols"
+HOMEPAGE="https://libwebsockets.org/"
+SRC_URI="https://github.com/warmcat/libwebsockets/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/19" # libwebsockets.so.19
+KEYWORDS="amd64 arm arm64 ppc ~ppc64 x86"
+IUSE="access-log caps cgi client dbus generic-sessions http-proxy http2 ipv6
+	+lejp libev libevent libuv mbedtls peer-limits server-status smtp socks5
+	sqlite3 ssl threads zip"
+
+REQUIRED_USE="
+	access-log? ( http2 )
+	generic-sessions? ( smtp sqlite3 )
+	http-proxy? ( client )
+	mbedtls? ( ssl )
+	smtp? ( libuv )
+	socks5? ( client http-proxy )
+	?? ( libev libevent )"
+
+RDEPEND="
+	sys-libs/zlib
+	caps? ( sys-libs/libcap )
+	dbus? ( sys-apps/dbus )
+	http-proxy? ( net-libs/libhubbub )
+	libev? ( dev-libs/libev )
+	libevent? ( dev-libs/libevent:= )
+	libuv? ( dev-libs/libuv:= )
+	sqlite3? ( dev-db/sqlite:= )
+	ssl? (
+		!mbedtls? ( dev-libs/openssl:0= )
+		mbedtls? ( net-libs/mbedtls:= )
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Git=ON
+		-DDISABLE_WERROR=ON
+		-DLWS_BUILD_HASH="unknown"
+		-DLWS_HAVE_LIBCAP=$(usex caps)
+		-DLWS_IPV6=$(usex ipv6)
+		-DLWS_ROLE_DBUS=$(usex dbus)
+		-DLWS_WITHOUT_CLIENT=$(usex !client)
+		-DLWS_WITHOUT_TEST_CLIENT=$(usex !client)
+		-DLWS_WITH_ACCESS_LOG=$(usex access-log)
+		-DLWS_WITH_CGI=$(usex cgi)
+		-DLWS_WITH_GENERIC_SESSIONS=$(usex generic-sessions)
+		-DLWS_WITH_HTTP2=$(usex http2)
+		-DLWS_WITH_HTTP_PROXY=$(usex http-proxy)
+		-DLWS_WITH_HUBBUB=$(usex http-proxy)
+		-DLWS_WITH_LEJP=$(usex lejp)
+		-DLWS_WITH_LIBEV=$(usex libev)
+		-DLWS_WITH_LIBEVENT=$(usex libevent)
+		-DLWS_WITH_LIBUV=$(usex libuv)
+		-DLWS_WITH_MBEDTLS=$(usex mbedtls)
+		-DLWS_WITH_PEER_LIMITS=$(usex peer-limits)
+		-DLWS_WITH_SERVER_STATUS=$(usex server-status)
+		-DLWS_WITH_SMTP=$(usex smtp)
+		-DLWS_WITH_SOCKS5=$(usex socks5)
+		-DLWS_WITH_SQLITE3=$(usex sqlite3)
+		-DLWS_WITH_SSL=$(usex ssl)
+		-DLWS_WITH_STATIC=OFF
+		-DLWS_WITH_STRUCT_JSON=$(usex lejp)
+		-DLWS_WITH_THREADPOOL=$(usex threads)
+		-DLWS_WITH_ZIP_FOPS=$(usex zip)
+		-DLWS_WITHOUT_TESTAPPS=ON
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3