From 50c71de793c37c19d34a68b3af53ba5e7ca51d22 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 25 Mar 2024 07:01:01 +0000
Subject: gentoo auto-resync : 25:03:2024 - 07:01:01

---
 net-misc/gallery-dl/gallery-dl-1.26.9.ebuild | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 net-misc/gallery-dl/gallery-dl-1.26.9.ebuild

(limited to 'net-misc/gallery-dl/gallery-dl-1.26.9.ebuild')

diff --git a/net-misc/gallery-dl/gallery-dl-1.26.9.ebuild b/net-misc/gallery-dl/gallery-dl-1.26.9.ebuild
new file mode 100644
index 000000000000..1e6696f28666
--- /dev/null
+++ b/net-misc/gallery-dl/gallery-dl-1.26.9.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite,ssl,xml(+)"
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Download image galleries and collections from several image hosting sites"
+HOMEPAGE="https://github.com/mikf/gallery-dl/"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/mikf/${PN}.git"
+else
+	SRC_URI="https://github.com/mikf/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/requests-2.11.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Tests against real servers, some tests always fail and some are subject to change.
+	rm test/test_results.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile_all() {
+	emake PYTHON="${EPYTHON}" data/completion/{,_}gallery-dl man
+}
+
+pkg_postinst() {
+	optfeature "Pixiv Ugoira to WebM conversion" media-video/ffmpeg
+	optfeature "video downloads" net-misc/yt-dlp
+}
-- 
cgit v1.2.3