From 6990d0600970cefe6aa2c17668f9028b08d23441 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 10 Apr 2023 23:37:47 +0100
Subject: gentoo auto-resync : 10:04:2023 - 23:37:47

---
 net-misc/remmina/Manifest              |   2 +
 net-misc/remmina/remmina-1.4.30.ebuild | 110 +++++++++++++++++++++++++++++++++
 2 files changed, 112 insertions(+)
 create mode 100644 net-misc/remmina/remmina-1.4.30.ebuild

(limited to 'net-misc/remmina')

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index 68e2d26adbdd..d6e9f80557a2 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,3 +1,5 @@
 DIST Remmina-v1.4.29.tar.bz2 2014832 BLAKE2B a5e3a54d510c74fd8399116dfd1cc67aaafdf93e3217a20ad77a2c959597b7be51cf187ffb459eb5cabe0a30f985f649aa59dba1397d7a8b3a0c10ea997b3fdf SHA512 8fbe822d07ec800bb739579b373003ee56cbc661fd0b635e5a7af0369d2e5450e7116907a87c34e82704c2aab790ac501ee6331946751660321c917ffd9a183e
+DIST Remmina-v1.4.30.tar.bz2 2026559 BLAKE2B 96b4946e5d9480239f5089369cca6fee7bbe9129bb87f685d849df745cef7eca5b20cd8053ec3250378c1ca2be34e1b3c40d463a45c655aca65a73e9ac018593 SHA512 4e2beb4fd27bd9060a95735bd43ee80260d036bb59c406aa0d9ef63fcbd04c6e358384416b2308367d88a1f87d6e1af42299a21d59fd06dce785b9cfe1b67c84
 EBUILD remmina-1.4.29-r2.ebuild 2664 BLAKE2B 58e38dfd0d870f1e6b0fd2701c8ab09f9cb6af5c65ada4bfe5cf913f7fe306386df823b6b559384a9c7ee9e23fd08f16923a9c8583d141c11d9b8f6d45dde2b0 SHA512 a072a1499c8e1aa3a0c544fb2163ab7cc5609cefe982c6f2b81f59d8e9fbcaa33cda1978c493d8c8625b4a90efee4ecc1a06e9db1ee1958505144dee3100b232
+EBUILD remmina-1.4.30.ebuild 2666 BLAKE2B 9725d95b20ebe9fe0c1fa13ffe60a35a647161bc299533aa0aa253aac81be145ff4ce41be24fc2f0e0cd235e13ea88e3906e6bb17213c34c251f0adf08a3d809 SHA512 c346640010221b427ec7e3f02f0a479374a7305a5f02a41f60b8e8e4e2952e9cc3a917f79ef08c197dd154faf444a33261e9a6c5616e70c2f7f1c9f443cbcf40
 MISC metadata.xml 1123 BLAKE2B 658714c247c6fbec6118a88bc5493a67aca30e949249407d421592b956c15b439b6d96c682d2d6d7cc9f1eb2dfdcc902c4c463c6a208af4bb9196656723f220a SHA512 cbf00348e2da27acbe9890ac2d6b19d5731496cf1aab303d64f036700fb779587cb7fe81a95d3a25f9ec5dcb79e2e7e880e345fc1ac267acd25da89844ab6f21
diff --git a/net-misc/remmina/remmina-1.4.30.ebuild b/net-misc/remmina/remmina-1.4.30.ebuild
new file mode 100644
index 000000000000..790b0d0b43f2
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.30.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake optfeature python-single-r1 xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+appindicator crypt cups examples gnome-keyring gvnc kwallet nls python spice ssh rdp vnc wayland webkit zeroconf"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3[wayland?]
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	appindicator? ( dev-libs/libayatana-appindicator )
+	crypt? ( dev-libs/libgcrypt:0= )
+	gnome-keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet )
+	python? ( ${PYTHON_DEPS} )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4.1 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	spice? ( app-emulation/spice-protocol )
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DHAVE_LIBAPPINDICATOR=$(usex appindicator ON OFF)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=OFF
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_PYTHONLIBS=$(usex python ON OFF)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_X2GO=OFF
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+}
-- 
cgit v1.2.3