From c3bc61051d7f12b4c682efa7a5460bbc8815649e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 7 Jan 2022 22:48:01 +0000
Subject: gentoo resync : 07.01.2022

---
 net-misc/seafile/seafile-8.0.5.ebuild | 58 +++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 net-misc/seafile/seafile-8.0.5.ebuild

(limited to 'net-misc/seafile/seafile-8.0.5.ebuild')

diff --git a/net-misc/seafile/seafile-8.0.5.ebuild b/net-misc/seafile/seafile-8.0.5.ebuild
new file mode 100644
index 000000000000..ef6a84798688
--- /dev/null
+++ b/net-misc/seafile/seafile-8.0.5.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+RELEASE_COMMIT="28ede40ebeca4f046c1d6625ac69fd4949e66042"
+
+inherit autotools python-single-r1 vala
+
+DESCRIPTION="File syncing and sharing software with file encryption and group sharing"
+HOMEPAGE="https://www.seafile.com/ https://github.com/haiwen/seafile/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/${RELEASE_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/future[${PYTHON_USEDEP}]
+	')
+	dev-libs/openssl:=
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/jansson:=
+	dev-libs/libevent:=
+	net-libs/libsearpc[${PYTHON_SINGLE_USEDEP}]
+	net-misc/curl
+	sys-apps/util-linux
+	sys-libs/zlib"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}
+	$(vala_depend)"
+
+S="${WORKDIR}/${PN}-${RELEASE_COMMIT}"
+
+src_prepare() {
+	default
+	eautoreconf
+	vala_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	# Remove unnecessary .la files
+	find "${ED}" -name '*.la' -delete || die
+	python_fix_shebang "${ED}"/usr/bin/seaf-cli
+}
-- 
cgit v1.2.3