From 21616d4521c47fc859035ab3939842cddd56e374 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 9 Aug 2022 08:15:38 +0100
Subject: gentoo auto-resync : 09:08:2022 - 08:15:37

---
 net-misc/yt-dlp/yt-dlp-2022.8.8.ebuild | 64 ++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 net-misc/yt-dlp/yt-dlp-2022.8.8.ebuild

(limited to 'net-misc/yt-dlp/yt-dlp-2022.8.8.ebuild')

diff --git a/net-misc/yt-dlp/yt-dlp-2022.8.8.ebuild b/net-misc/yt-dlp/yt-dlp-2022.8.8.ebuild
new file mode 100644
index 000000000000..775abf17078d
--- /dev/null
+++ b/net-misc/yt-dlp/yt-dlp-2022.8.8.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+inherit bash-completion-r1 distutils-r1 optfeature wrapper
+
+DESCRIPTION="youtube-dl fork with additional features and fixes"
+HOMEPAGE="https://github.com/yt-dlp/yt-dlp/"
+SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86 ~x64-macos"
+
+RDEPEND="
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	!net-misc/youtube-dl[-yt-dlp(-)]"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# adjust requires for pycryptodome and optional dependencies (bug #828466)
+	sed -ri requirements.txt \
+		-e "s/^(pycryptodome)x/\1/" \
+		-e "/^(brotli.*|certifi|mutagen|websockets)/d" || die
+}
+
+python_test() {
+	epytest -m 'not download'
+}
+
+python_install_all() {
+	dodoc README.md Changelog.md supportedsites.md
+	doman yt-dlp.1
+
+	dobashcomp completions/bash/yt-dlp
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins completions/fish/yt-dlp.fish
+
+	insinto /usr/share/zsh/site-functions
+	doins completions/zsh/_yt-dlp
+
+	rm -r "${ED}"/usr/share/doc/yt_dlp || die
+
+	make_wrapper youtube-dl "yt-dlp --compat-options youtube-dl"
+}
+
+pkg_postinst() {
+	optfeature "various features (merging tracks, streamed content)" media-video/ffmpeg
+	has_version media-video/atomicparsley || # allow fallback but don't advertise
+		optfeature "embedding metadata thumbnails in MP4/M4A files" media-libs/mutagen
+
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		elog 'A wrapper using "yt-dlp --compat-options youtube-dl" was installed'
+		elog 'as "youtube-dl". This is strictly for compatibility and it is'
+		elog 'recommended to use "yt-dlp" directly, it may be removed in the future.'
+	fi
+}
-- 
cgit v1.2.3