From 590c04803f88a968b4a750c0f420eb314e1fe968 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 19 Sep 2023 17:09:22 +0100
Subject: gentoo auto-resync : 19:09:2023 - 17:09:22

---
 net-misc/zsync/zsync-0.6.2-r3.ebuild | 49 ++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 net-misc/zsync/zsync-0.6.2-r3.ebuild

(limited to 'net-misc/zsync/zsync-0.6.2-r3.ebuild')

diff --git a/net-misc/zsync/zsync-0.6.2-r3.ebuild b/net-misc/zsync/zsync-0.6.2-r3.ebuild
new file mode 100644
index 000000000000..08e57393fa50
--- /dev/null
+++ b/net-misc/zsync/zsync-0.6.2-r3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+ZLIB_PV=1.2.3
+ZLIB_P="zlib-${ZLIB_PV}"
+
+DESCRIPTION="Partial/differential file download client over HTTP using the rsync algorithm"
+HOMEPAGE="http://zsync.moria.org.uk/"
+SRC_URI="
+	http://zsync.moria.org.uk/download/${P}.tar.bz2
+	http://www.gzip.org/zlib/${ZLIB_P}.tar.bz2
+	http://www.zlib.net/${ZLIB_P}.tar.bz2"
+ZLIB_S="${WORKDIR}/${ZLIB_P}"
+
+LICENSE="Artistic-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.6.2-musl-off_t-fix.patch
+)
+
+src_prepare() {
+	default
+	# Move old zlib-1.2.11 out the way
+	mv "${S}"/zlib zlib-1.2.11-modified || die
+
+	cd "${ZLIB_S}" || die
+	# I am not sure how many other zlib patches we will need to port as well
+	# This covers the security vuln in 1.2.11
+	eapply "${FILESDIR}"/${P}-${ZLIB_P}-support.patch
+	rm Makefile || die
+
+	cd "${S}" || die
+	cp -a "${ZLIB_S}" "${ZLIB_P}-modified" || die
+	ln -s "${ZLIB_P}-modified" zlib || die
+
+	eautoreconf
+}
+
+src_install() {
+	dobin zsync zsyncmake
+	dodoc NEWS README
+	doman doc/zsync.1 doc/zsyncmake.1
+}
-- 
cgit v1.2.3