From c510d9ec7aca9b092e381a7a4ff213757c7a9709 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 8 Apr 2024 18:31:11 +0100
Subject: gentoo auto-resync : 08:04:2024 - 18:31:11

---
 .../cups-filters/cups-filters-2.0.0-r1.ebuild      | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 net-print/cups-filters/cups-filters-2.0.0-r1.ebuild

(limited to 'net-print/cups-filters/cups-filters-2.0.0-r1.ebuild')

diff --git a/net-print/cups-filters/cups-filters-2.0.0-r1.ebuild b/net-print/cups-filters/cups-filters-2.0.0-r1.ebuild
new file mode 100644
index 000000000000..462a52f62558
--- /dev/null
+++ b/net-print/cups-filters/cups-filters-2.0.0-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Cups filters"
+HOMEPAGE="https://wiki.linuxfoundation.org/openprinting/cups-filters"
+SRC_URI="https://github.com/OpenPrinting/cups-filters/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+foomatic"
+
+RDEPEND="
+	net-print/libcupsfilters
+	net-print/libppd
+	>=net-print/cups-1.7.3
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# The tests are composed of:
+# - built program
+# - test case itself: filter/test.sh
+#
+# The latter is not wired up, and it becomes immediately evident why.
+# Bow to this reality and don't claim we can run anything. As a side
+# effect, don't compile in src_test, that which we never use.
+RESTRICT="test"
+
+src_configure() {
+	local myeconfargs=(
+		--enable-imagefilters
+		--enable-driverless
+		--enable-poppler
+		--localstatedir="${EPREFIX}"/var
+		--with-fontdir="fonts/conf.avail"
+		# cups-browsed is split out and avahi is not needed for filters
+		# https://github.com/OpenPrinting/cups-filters/pull/558
+		--disable-avahi
+		# These are just probed for the path. Always enable them.
+		--with-gs-path="${EPREFIX}"/usr/bin/gs
+		--with-mutool-path="${EPREFIX}"/usr/bin/mutool
+
+		$(use_enable foomatic)
+	)
+
+	# bash for configure until https://github.com/OpenPrinting/cups-filters/pull/567 (bug #920346)
+	# lands in a release.
+	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
+}
-- 
cgit v1.2.3