From fc2f1018fc323ef2c6572734a9b130427cba76a6 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 3 Nov 2021 06:47:15 +0000
Subject: gentoo resync : 03.11.2021

---
 net-vpn/iodine/iodine-0.7.0-r3.ebuild | 50 +++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 net-vpn/iodine/iodine-0.7.0-r3.ebuild

(limited to 'net-vpn/iodine/iodine-0.7.0-r3.ebuild')

diff --git a/net-vpn/iodine/iodine-0.7.0-r3.ebuild b/net-vpn/iodine/iodine-0.7.0-r3.ebuild
new file mode 100644
index 000000000000..0c944c2eeea1
--- /dev/null
+++ b/net-vpn/iodine/iodine-0.7.0-r3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info toolchain-funcs
+
+DESCRIPTION="IP over DNS tunnel"
+HOMEPAGE="http://code.kryo.se/iodine/"
+SRC_URI="http://code.kryo.se/${PN}/${P}.tar.gz"
+
+CONFIG_CHECK="~TUN"
+
+LICENSE="ISC GPL-2" #GPL-2 for init script bug #426060
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-TestMessage.patch
+	"${FILESDIR}"/${P}-new-systemd.patch
+)
+
+src_prepare() {
+	default
+
+	sed -e '/^\s@echo \(CC\|LD\)/d' \
+		-e 's:^\(\s\)@:\1:' \
+		-i {,src/}Makefile || die
+
+	tc-export CC
+}
+
+src_install() {
+	# Don't re-run submake
+	sed -e '/^install:/s: all: :' \
+		-i Makefile || die
+	emake prefix="${EPREFIX}"/usr DESTDIR="${D}" install
+	einstalldocs
+
+	newinitd "${FILESDIR}"/iodined-1.init iodined
+	newconfd "${FILESDIR}"/iodined.conf iodined
+	keepdir /var/empty
+	fperms 600 /etc/conf.d/iodined
+}
-- 
cgit v1.2.3