From 066d27181e9a797ad9f8fc43b49fc9a10ff2f707 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 3 Mar 2019 13:42:34 +0000
Subject: gentoo resync : 03.03.2019

---
 sci-libs/dlib/Manifest          |   2 +
 sci-libs/dlib/dlib-19.16.ebuild | 108 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 110 insertions(+)
 create mode 100644 sci-libs/dlib/dlib-19.16.ebuild

(limited to 'sci-libs/dlib')

diff --git a/sci-libs/dlib/Manifest b/sci-libs/dlib/Manifest
index 3673a79a3621..3d790a1878d1 100644
--- a/sci-libs/dlib/Manifest
+++ b/sci-libs/dlib/Manifest
@@ -1,6 +1,8 @@
+DIST dlib-19.16.tar.gz 10411975 BLAKE2B 93047590a4d8f4685970d3db6841cbf9cc90ca8a5e50f0929a106d887e5db1b4fd96bbe14380537a3e28369a8db6d9d8c067e7768000ac3c7d0f225b46369326 SHA512 4e040ef88acff05e1a48e499b813c876b22ad3f989d076bdf19969d01036b62e51a0dff30b70046910ba31dfa1b1c2450a7fad41ae3142b7285ed74b8d584887
 DIST dlib-19.4.tar.gz 7226923 BLAKE2B 2d72936fc46d559a80288e7f88a64c372fb5f8dcfc69b57abee8a27519f3084fa0cf4193261dd9758f9eb718e755d46a17655e38cb74aaa0046855f11676e157 SHA512 23bf80353f9b6ce07b6a3a7df05016705645c18bcf2b3ead567935008ea12c9f6dc0722d9bbacc009bd26f78eb43c1cbecf776bfed5a3445c1f2e8e208f201e2
 DIST dlib-19.7.tar.gz 7670615 BLAKE2B 13343f3b99bf5dd7a9c032de09eff47f1675bbc978a93edfbd952196b2347e4a887a8eed805f22985477b10ecfa1df85fc568e32f1a00b17b0292a0a51db9764 SHA512 a3877066e04a411d96e910f4229c60a86971a9290e840aa4a5b2f0b102e9b8c37bfede259b80b71ba066d21eb0aa2565808e51d0eab6397ff5fd2bac60dcedd5
 DIST dlib-19.9.tar.gz 8892457 BLAKE2B d18548e09f8169bbc9d7f339599bd58b940410839b259a8d7be9cb999f82e634ad5cd0539adb45239dab821ea1029493d24ae9990ca32c75c744e2c5d9e218f6 SHA512 1e2123c22e1b13cc84108fa627bfa92eadc9dee63f93a9f45676bbf2b752c8728117d915ac327f5223b0cdbce87dd3bef2f4d8d5ed3f8f5a314ffa9e8962a246
+EBUILD dlib-19.16.ebuild 2952 BLAKE2B b026843271edc33b088d0bea4e61591579f44bf6c8a6115fb71002d857d20feabb3d18310cadedb8e21da47cdcec46ef77535444d4fc80e7b37d9f4fe46d5ce2 SHA512 3c4e77716a6de00a12fbe68b3823b15ad623f71c81d7a83d18442f7c725aa255ffe5eab6828458f24aad91db16bcf46096b39ccfb50b0a8342b6a726c37cf743
 EBUILD dlib-19.4.ebuild 1797 BLAKE2B 45fd4d3b434852fa3a8d1571e30fee6ffbdb254ed471433fac534c26854ab69352b981dae4ad45b404cc6ff8525a92bb22915bd058c18e0f00d4c3cce9157164 SHA512 ef2172c18b446cf98c79e9b6a4dcf622ca62d05cc353d82d35385a16a334a94d5689af5117f9fee26e9e32346da57227beb83ca35b4b216135ad15b214042328
 EBUILD dlib-19.7.ebuild 1795 BLAKE2B beb38d516fb6c854f7958c6d63d83d5612acfdd384986df8ef7cfc58bca1a2c323078d96711882f4a2adeef775520fdef9e08caee550667d2493eead4fa7e9c8 SHA512 e3b82055fc6e093d2cbd7850b91354cf3e5b62cbf0d614b1c62316cdcf7aed0082808400161ea072d21a4296f901d5edeebc039ff5db73aaa0a921b6cba106ee
 EBUILD dlib-19.9.ebuild 1998 BLAKE2B 57bcf753826ddf3366f0c6001ca4e98292173ff6834419eb7b99db9df53b6b939d81a4788cbf63463c1fa4bf289060262085f2c9709cdd5fd7c1600e138ac94e SHA512 15e4a3d3d024e11c9554d0d2c6b163fa612f3f39fb9e291bb78bdf9e2c898b4b22e04181e26b6eed5a34ecd6bac8036a8b31052c9c32f32f0ab46d80d2bd474d
diff --git a/sci-libs/dlib/dlib-19.16.ebuild b/sci-libs/dlib/dlib-19.16.ebuild
new file mode 100644
index 000000000000..bdcf3929b23b
--- /dev/null
+++ b/sci-libs/dlib/dlib-19.16.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+DISTUTILS_OPTIONAL=1
+inherit cmake-utils cuda distutils-r1
+
+DESCRIPTION="Numerical and networking C++ library"
+HOMEPAGE="http://dlib.net/"
+SRC_URI="https://github.com/davisking/dlib/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Boost-1.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cblas cuda debug examples gif jpeg lapack mkl png python sqlite static-libs test X cpu_flags_x86_avx cpu_flags_x86_sse2 cpu_flags_x86_sse4_1"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# doc needs a bunch of deps not in portage
+
+RDEPEND="
+	cblas? ( virtual/cblas:= )
+	cuda? ( dev-libs/cudnn:= )
+	gif? ( media-libs/giflib:= )
+	jpeg? ( virtual/jpeg:0= )
+	lapack? ( virtual/lapack:= )
+	mkl? ( sci-libs/mkl:= )
+	png? ( media-libs/libpng:0= )
+	python? ( ${PYTHON_DEPS} )
+	sqlite? ( dev-db/sqlite:3= )
+	X? ( x11-libs/libX11:= )"
+DEPEND="${RDEPEND}
+	python? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+	)"
+
+DOCS=( docs/README.txt )
+
+src_prepare() {
+	use cuda && cuda_src_prepare
+	cmake-utils_src_prepare
+	use python && distutils-r1_src_prepare
+}
+
+python_configure_all() {
+	mydistutilsargs=(
+		--"$(usex gif)" DLIB_GIF_SUPPORT
+		--"$(usex jpeg)" DLIB_JPEG_SUPPORT
+		--"$(usex png)" DLIB_PNG_SUPPORT
+		--"$(usex X no yes)" DLIB_NO_GUI_SUPPORT
+		--"$(usex cblas)" DLIB_USE_BLAS
+		--"$(usex cuda)" DLIB_USE_CUDA
+		--"$(usex lapack)" DLIB_USE_LAPACK
+		--"$(usex cpu_flags_x86_avx)" USE_AVX_INSTRUCTIONS
+		--"$(usex cpu_flags_x86_sse2)" USE_SSE2_INSTRUCTIONS
+		--"$(usex cpu_flags_x86_sse4_1)" USE_SSE4_INSTRUCTIONS
+	)
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDLIB_ENABLE_ASSERTS="$(usex debug)"
+		-DDLIB_ENABLE_STACK_TRACE="$(usex debug)"
+		-DDLIB_GIF_SUPPORT="$(usex gif)"
+		-DDLIB_JPEG_SUPPORT="$(usex jpeg)"
+		-DDLIB_PNG_SUPPORT="$(usex png)"
+		-DDLIB_LINK_WITH_SQLITE3="$(usex sqlite)"
+		-DDLIB_NO_GUI_SUPPORT="$(usex X OFF ON)"
+		-DDLIB_USE_BLAS="$(usex cblas)"
+		-DDLIB_USE_CUDA="$(usex cuda)"
+		-DDLIB_USE_LAPACK="$(usex lapack)"
+		-DUSE_AVX_INSTRUCTIONS="$(usex cpu_flags_x86_avx)"
+		-DUSE_SSE2_INSTRUCTIONS="$(usex cpu_flags_x86_sse2)"
+		-DUSE_SSE4_INSTRUCTIONS="$(usex cpu_flags_x86_sse4_1)"
+	)
+	cmake-utils_src_configure
+	use python && distutils-r1_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	use python && distutils-r1_src_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+src_test() {
+	mkdir "${BUILD_DIR}"/dlib/test || die
+	pushd "${BUILD_DIR}"/dlib/test > /dev/null || die
+	cmake "${S}"/dlib/test && emake
+	./dtest --runall || die
+	popd > /dev/null || die
+	use python && distutils-r1_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+	use python && distutils-r1_src_install
+	use static-libs || rm -f "${ED}"/usr/$(get_libdir)/*.a
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}
+	fi
+}
-- 
cgit v1.2.3