From ceeeb463cc1eef97fd62eaee8bf2196ba04bc384 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 29 Feb 2020 18:01:47 +0000
Subject: gentoo (leap year) resync : 29.02.2020

---
 sys-boot/woeusb/woeusb-3.3.1.ebuild | 59 +++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 sys-boot/woeusb/woeusb-3.3.1.ebuild

(limited to 'sys-boot/woeusb/woeusb-3.3.1.ebuild')

diff --git a/sys-boot/woeusb/woeusb-3.3.1.ebuild b/sys-boot/woeusb/woeusb-3.3.1.ebuild
new file mode 100644
index 000000000000..2828715f8b07
--- /dev/null
+++ b/sys-boot/woeusb/woeusb-3.3.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+WX_GTK_VER="3.0-gtk3"
+
+inherit autotools wxwidgets
+
+DESCRIPTION="Creates windows installer on usb media from an iso image"
+HOMEPAGE="https://github.com/slacka/WoeUSB"
+SRC_URI="https://github.com/slacka/WoeUSB/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="minimal"
+
+RDEPEND="
+	sys-apps/util-linux
+	sys-block/parted
+	sys-fs/dosfstools
+	sys-fs/ntfs3g
+	sys-boot/grub:2[grub_platforms_pc]
+	!minimal? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND=""
+
+S="${WORKDIR}/WoeUSB-${PV}"
+
+src_prepare() {
+	default
+	find . -type f -print0 | xargs -0 sed -i "s/@@WOEUSB_VERSION@@/${PV}/" || die
+	if ! use minimal; then
+		setup-wxwidgets
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	! use minimal && default
+}
+
+src_compile() {
+	! use minimal && default
+}
+
+src_test() {
+	! use minimal && default
+}
+
+src_install() {
+	if use minimal; then
+		dosbin src/woeusb
+		einstalldocs
+	else
+		default
+	fi
+}
-- 
cgit v1.2.3