From 590b9b7b03bf4651e099949e318755af7cfa81b8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 1 Aug 2021 22:03:23 +0100
Subject: gentoo resync : 01.08.2021

---
 sys-devel/lld/Manifest               |  1 +
 sys-devel/lld/lld-14.0.0.9999.ebuild | 68 ++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)
 create mode 100644 sys-devel/lld/lld-14.0.0.9999.ebuild

(limited to 'sys-devel/lld')

diff --git a/sys-devel/lld/Manifest b/sys-devel/lld/Manifest
index e59790d874ee..a2ae630b37e7 100644
--- a/sys-devel/lld/Manifest
+++ b/sys-devel/lld/Manifest
@@ -9,4 +9,5 @@ EBUILD lld-11.1.0.ebuild 1399 BLAKE2B bfa3538e4bd9492e94547f4ed304d75ff5da1e58c1
 EBUILD lld-12.0.0.ebuild 1666 BLAKE2B 6fe783db711fd7a68603e02271eb8dcdd71bee6729e2b940fdbfbe318514bf87312252ad290f059d0c547ab9c5efa4877f6c93c201e5b2e10e31d3f31466980c SHA512 85a2c9f6105acc9ab00a241e7dace1c933fad82f878e7d0df7706e57b6c54df9a94932a1c3b66d5bf0a551eb1187e4964fc7e370648f2243765bdacb6e2f2040
 EBUILD lld-12.0.1.ebuild 1671 BLAKE2B 8f04ffcf0837a8000f5de80d36034b33b83458918f76dbd7ecfc5640d07cf2c9fce3b6b8e49138cc97e9d2a05051a4e5cb9d68b1a77db5060c861d018699ea28 SHA512 e054b3d29377f6b396366370026b54e362de3ba20e4b5ef971b32610a1b7de57ec24eec94d4586b7c453653249840260eb16aca795a36c2a29a3039fa37f8d8f
 EBUILD lld-13.0.0.9999.ebuild 1629 BLAKE2B 6bbe1d8e730c8ab5719492f03791754bcba4b18839bed1031afa617cff7e88f6b16cad038fa96eccf64e817fe017844fe466b754fbecebea32bb7bc48c5a0339 SHA512 f4239a40bd9cbdde38f837643290214d230f79243f21b22503af0c0c2ebc28683d913db3b0a72ac9582c95c236b63f1134cdac41a18118a98915c606e4d62285
+EBUILD lld-14.0.0.9999.ebuild 1629 BLAKE2B 6bbe1d8e730c8ab5719492f03791754bcba4b18839bed1031afa617cff7e88f6b16cad038fa96eccf64e817fe017844fe466b754fbecebea32bb7bc48c5a0339 SHA512 f4239a40bd9cbdde38f837643290214d230f79243f21b22503af0c0c2ebc28683d913db3b0a72ac9582c95c236b63f1134cdac41a18118a98915c606e4d62285
 MISC metadata.xml 216 BLAKE2B fe5e49887842aa513fbf1f2e09bed09a884d531fd21bdaeb2d389e8bf590b6c0e7063f0af98f66e2db129308ab0f0804ba327c3c752bbb4c900c59ac109d99aa SHA512 3485598147c953e72e1785693a489a7e7d73d59620b76054db9c0ce95d8bfa0e8ffec29da7f7a9d73a32e5b77eac07ca3306c56a972dc57fd89d477edaebf3d5
diff --git a/sys-devel/lld/lld-14.0.0.9999.ebuild b/sys-devel/lld/lld-14.0.0.9999.ebuild
new file mode 100644
index 000000000000..68762b0a03cc
--- /dev/null
+++ b/sys-devel/lld/lld-14.0.0.9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake llvm llvm.org python-any-r1
+
+DESCRIPTION="The LLVM linker (link editor)"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="~sys-devel/llvm-${PV}"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		>=dev-util/cmake-3.16
+		$(python_gen_any_dep "~dev-python/lit-${PV}[\${PYTHON_USEDEP}]")
+	)"
+
+LLVM_COMPONENTS=( lld libunwind/include/mach-o )
+LLVM_TEST_COMPONENTS=( llvm/utils/{lit,unittest} )
+llvm.org_set_globals
+
+python_check_deps() {
+	has_version -b "dev-python/lit[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
+	use test && python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	llvm.org_src_unpack
+
+	# Directory ${WORKDIR}/llvm does not exist with USE="-test",
+	# but LLVM_MAIN_SRC_DIR="${WORKDIR}/llvm" is set below,
+	# and ${LLVM_MAIN_SRC_DIR}/../libunwind/include is used by build system
+	# (lld/MachO/CMakeLists.txt) and is expected to be resolvable
+	# to existent directory ${WORKDIR}/libunwind/include.
+	mkdir -p "${WORKDIR}/llvm" || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DLLVM_INCLUDE_TESTS=$(usex test)
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_BUILD_TESTS=ON
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="$(get_lit_flags)"
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake_build check-lld
+}
-- 
cgit v1.2.3