From 02930d1eb5af78d32b1597af6af24163895d9e0f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 11 May 2023 23:47:37 +0100
Subject: gentoo auto-resync : 11:05:2023 - 23:47:37

---
 sys-fabric/opensm/opensm-3.3.24-r1.ebuild | 63 +++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 sys-fabric/opensm/opensm-3.3.24-r1.ebuild

(limited to 'sys-fabric/opensm/opensm-3.3.24-r1.ebuild')

diff --git a/sys-fabric/opensm/opensm-3.3.24-r1.ebuild b/sys-fabric/opensm/opensm-3.3.24-r1.ebuild
new file mode 100644
index 000000000000..3f0563f02f42
--- /dev/null
+++ b/sys-fabric/opensm/opensm-3.3.24-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="OpenSM - InfiniBand Subnet Manager and Administration for OpenIB"
+HOMEPAGE="https://github.com/linux-rdma/opensm/"
+SRC_URI="https://github.com/linux-rdma/opensm/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 BSD-2 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+IUSE="selinux tools"
+
+DEPEND="sys-cluster/rdma-core"
+RDEPEND="${DEPEND}
+	selinux? ( sec-policy/selinux-opensm )
+	 tools? (
+		net-misc/iputils
+		virtual/openssh
+	)"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.3.17-sldd.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-perf-mgr \
+		--enable-default-event-plugin \
+		--with-osmv="openib"
+}
+
+src_install() {
+	default
+
+	newconfd "${FILESDIR}"/opensm.conf.d opensm
+	newinitd "${FILESDIR}"/opensm.init.d.2 opensm
+
+	insinto /etc/logrotate.d
+	newins scripts/opensm.logrotate opensm
+	# we dont need this int script
+	rm "${ED}"/etc/init.d/opensmd || die "Dropping of upstream initscript failed"
+
+	if use tools; then
+		dosbin scripts/sldd.sh
+		newconfd "${FILESDIR}"/sldd.conf.d sldd
+		newinitd "${FILESDIR}"/sldd.init.d sldd
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	einfo "To automatically configure the infiniband subnet manager on boot,"
+	einfo "edit /etc/opensm.conf and add opensm to your start-up scripts:"
+	einfo "\`rc-update add opensm default\`"
+}
-- 
cgit v1.2.3