From 529abfa74a08ae5099db9780bcdf8250aa52ecb6 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 3 Dec 2022 14:59:59 +0000
Subject: gentoo auto-resync : 03:12:2022 - 14:59:58

---
 sys-libs/libnbd/Manifest             |  3 ++
 sys-libs/libnbd/libnbd-1.14.1.ebuild | 64 ++++++++++++++++++++++++++++++++++++
 sys-libs/libnbd/metadata.xml         | 24 ++++++++++++++
 3 files changed, 91 insertions(+)
 create mode 100644 sys-libs/libnbd/Manifest
 create mode 100644 sys-libs/libnbd/libnbd-1.14.1.ebuild
 create mode 100644 sys-libs/libnbd/metadata.xml

(limited to 'sys-libs/libnbd')

diff --git a/sys-libs/libnbd/Manifest b/sys-libs/libnbd/Manifest
new file mode 100644
index 000000000000..599c3492ca33
--- /dev/null
+++ b/sys-libs/libnbd/Manifest
@@ -0,0 +1,3 @@
+DIST libnbd-1.14.1.tar.gz 1257547 BLAKE2B 4c2fc02abc1d069b23fb8cc52b3359f10ebd23f2bc8cb359274a4fc2781413445d64ca1013b3123dff090d359a0e28076aa410220a05b155f95320238d1b99ee SHA512 9d95cf7a66926d00ec9aacfc6d04f2dc885ccfed07c78f1e6693190dd14132d30d6d1ff7d46e46007732a8a20a9fbf648775bc0b3371ad49eff4ce1e44e47209
+EBUILD libnbd-1.14.1.ebuild 1301 BLAKE2B 60e034f842aae6c74a521ed0d6def20d32a69bc19d5eba303ed81280caaf3903d5e243818cc84cf0cb4eab3017b635fdaf1b37bc7bad656fbb7a2f7f15a2c911 SHA512 65bb49bcdbebe59dec6cb4958f60af83ea58c75e23f2c7f2fbd63c0b995b37bc405ca3fe27cc14197dd0307fd4fa73abb3ec9133203eec76a6b8f55380c06d36
+MISC metadata.xml 731 BLAKE2B 902535457bff35c07d77a8256046d1ee800bf6396a60c11c433be2a764df77209a44b0b1711d433bcba666a693bfcf638d61b3bc1d272f5128ce8d93907c1247 SHA512 11b7a74e50a0e71e50e5d0ddb493268080d45b6894cfa0275110139b712768fd43cdef00d76500bca7d816a2dd2df664c6c9db6fea06770191137c1a984c7137
diff --git a/sys-libs/libnbd/libnbd-1.14.1.ebuild b/sys-libs/libnbd/libnbd-1.14.1.ebuild
new file mode 100644
index 000000000000..67aff2662660
--- /dev/null
+++ b/sys-libs/libnbd/libnbd-1.14.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1
+
+DESCRIPTION="NBD client library in userspace"
+HOMEPAGE="https://gitlab.com/nbdkit/libnbd"
+SRC_URI="https://download.libguestfs.org/libnbd/$(ver_cut 1-2)-stable/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="fuse gnutls uri-support test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	fuse? ( sys-fs/fuse:3 )
+	gnutls? ( net-libs/gnutls:= )
+	uri-support? ( dev-libs/libxml2 )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( sys-block/nbd[gnutls?] )
+"
+BDEPEND="dev-lang/perl"
+
+src_prepare() {
+	default
+
+	# Some tests require impossible to provide features, such as fuse.
+	# These are marked by requires_... in the functions.sh shell
+	# library.  Rather than listing these tests, let's list out the
+	# impossible to support features and make them skip.
+	cat <<-EOF >> tests/functions.sh.in || die
+		requires_fuse ()
+		{
+			requires false
+		}
+	EOF
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable fuse)
+		$(use_with gnutls)
+		$(use_with uri-support libxml2)
+		--disable-ocaml
+		--disable-python
+		--disable-golang
+	)
+
+	export bashcompdir="$(get_bashcompdir)"
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/sys-libs/libnbd/metadata.xml b/sys-libs/libnbd/metadata.xml
new file mode 100644
index 000000000000..9182ab0c520d
--- /dev/null
+++ b/sys-libs/libnbd/metadata.xml
@@ -0,0 +1,24 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>arsen@aarsen.me</email>
+		<name>Arsen Arsenović</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="gitlab">nbdkit/libnbd</remote-id>
+		<remote-id type="github">libguestfs/libnbd</remote-id>
+	</upstream>
+	<use>
+		<flag name="uri-support">
+			Enable nbd:// URI support via <pkg>dev-libs/libxml2</pkg>.
+		</flag>
+		<flag name="fuse">
+			Install the <pkg>sys-fs/fuse</pkg> powered nbdfuse.
+		</flag>
+	</use>
+</pkgmetadata>
-- 
cgit v1.2.3