From d934827bf44b7cfcf6711964418148fa60877668 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 25 Nov 2020 22:39:15 +0000
Subject: gentoo resync : 25.11.2020

---
 sys-libs/zlib/zlib-1.2.11-r3.ebuild | 132 ++++++++++++++++++++++++++++++++++++
 1 file changed, 132 insertions(+)
 create mode 100644 sys-libs/zlib/zlib-1.2.11-r3.ebuild

(limited to 'sys-libs/zlib/zlib-1.2.11-r3.ebuild')

diff --git a/sys-libs/zlib/zlib-1.2.11-r3.ebuild b/sys-libs/zlib/zlib-1.2.11-r3.ebuild
new file mode 100644
index 000000000000..b7ea3672a88c
--- /dev/null
+++ b/sys-libs/zlib/zlib-1.2.11-r3.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+AUTOTOOLS_AUTO_DEPEND="no"
+
+inherit autotools toolchain-funcs multilib multilib-minimal usr-ldscript
+
+DESCRIPTION="Standard (de)compression library"
+HOMEPAGE="https://zlib.net/"
+SRC_URI="https://zlib.net/${P}.tar.gz
+	http://www.gzip.org/zlib/${P}.tar.gz
+	http://www.zlib.net/current/beta/${P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0/1" # subslot = SONAME
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="minizip static-libs"
+
+BDEPEND="minizip? ( ${AUTOTOOLS_DEPEND} )"
+RDEPEND="!<dev-libs/libxml2-2.7.7" #309623
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.2.11-fix-deflateParams-usage.patch
+	"${FILESDIR}"/${PN}-1.2.11-minizip-drop-crypt-header.patch #658536
+)
+
+src_prepare() {
+	default
+
+	if use minizip ; then
+		cd contrib/minizip || die
+		eautoreconf
+	fi
+
+	case ${CHOST} in
+	*-mingw*|mingw*)
+		# uses preconfigured Makefile rather than configure script
+		multilib_copy_sources
+		;;
+	esac
+}
+
+echoit() { echo "$@"; "$@"; }
+
+multilib_src_configure() {
+	case ${CHOST} in
+	*-mingw*|mingw*)
+		;;
+	*)
+		local uname=$("${EPREFIX}"/usr/share/gnuconfig/config.sub "${CHOST}" | cut -d- -f3) #347167
+		local myconf=(
+			--shared
+			--prefix="${EPREFIX}/usr"
+			--libdir="${EPREFIX}/usr/$(get_libdir)"
+			${uname:+--uname=${uname}}
+		)
+		# not an autoconf script, so can't use econf
+		echoit "${S}"/configure "${myconf[@]}" || die
+		;;
+	esac
+
+	if use minizip ; then
+		local minizipdir="contrib/minizip"
+		mkdir -p "${BUILD_DIR}/${minizipdir}" || die
+		cd ${minizipdir} || die
+		ECONF_SOURCE="${S}/${minizipdir}" \
+		econf $(use_enable static-libs static)
+	fi
+}
+
+multilib_src_compile() {
+	case ${CHOST} in
+	*-mingw*|mingw*)
+		emake -f win32/Makefile.gcc STRIP=true PREFIX=${CHOST}-
+		sed \
+			-e 's|@prefix@|/usr|g' \
+			-e 's|@exec_prefix@|${prefix}|g' \
+			-e 's|@libdir@|${exec_prefix}/'$(get_libdir)'|g' \
+			-e 's|@sharedlibdir@|${exec_prefix}/'$(get_libdir)'|g' \
+			-e 's|@includedir@|${prefix}/include|g' \
+			-e 's|@VERSION@|'${PV}'|g' \
+			zlib.pc.in > zlib.pc || die
+		;;
+	*)
+		emake
+		;;
+	esac
+	use minizip && emake -C contrib/minizip
+}
+
+sed_macros() {
+	# clean up namespace a little #383179
+	# we do it here so we only have to tweak 2 files
+	sed -i -r 's:\<(O[FN])\>:_Z_\1:g' "$@" || die
+}
+
+multilib_src_install() {
+	case ${CHOST} in
+	*-mingw*|mingw*)
+		emake -f win32/Makefile.gcc install \
+			BINARY_PATH="${ED}/usr/bin" \
+			LIBRARY_PATH="${ED}/usr/$(get_libdir)" \
+			INCLUDE_PATH="${ED}/usr/include" \
+			SHARED_MODE=1
+		# overwrites zlib.pc created from win32/Makefile.gcc #620136
+		insinto /usr/$(get_libdir)/pkgconfig
+		doins zlib.pc
+		;;
+
+	*)
+		emake install DESTDIR="${D}" LDCONFIG=:
+		gen_usr_ldscript -a z
+		;;
+	esac
+	sed_macros "${ED}"/usr/include/*.h
+
+	if use minizip ; then
+		emake -C contrib/minizip install DESTDIR="${D}"
+		sed_macros "${ED}"/usr/include/minizip/*.h
+	fi
+
+	if ! use static-libs ; then
+		rm -f "${ED}"/usr/$(get_libdir)/lib{z,minizip}.{a,la} || die #419645
+	fi
+}
+
+multilib_src_install_all() {
+	dodoc FAQ README ChangeLog doc/*.txt
+	use minizip && dodoc contrib/minizip/*.txt
+}
-- 
cgit v1.2.3