From fb7c221776ce0bda5eb40ef32cb74daa98aed0d7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 9 Apr 2024 18:31:35 +0100
Subject: gentoo auto-resync : 09:04:2024 - 18:31:35

---
 .../prowlarr-bin/prowlarr-bin-1.16.0.4401.ebuild   | 77 ++++++++++++++++++++++
 1 file changed, 77 insertions(+)
 create mode 100644 www-apps/prowlarr-bin/prowlarr-bin-1.16.0.4401.ebuild

(limited to 'www-apps/prowlarr-bin/prowlarr-bin-1.16.0.4401.ebuild')

diff --git a/www-apps/prowlarr-bin/prowlarr-bin-1.16.0.4401.ebuild b/www-apps/prowlarr-bin/prowlarr-bin-1.16.0.4401.ebuild
new file mode 100644
index 000000000000..6b55e3a00dbf
--- /dev/null
+++ b/www-apps/prowlarr-bin/prowlarr-bin-1.16.0.4401.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+DESCRIPTION="An indexer manager/proxy to integrate with your various PVR apps"
+HOMEPAGE="https://wiki.servarr.com/prowlarr/
+	https://github.com/Prowlarr/Prowlarr/"
+
+SRC_URI="
+	amd64? (
+		elibc_glibc? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-core-x64.tar.gz
+		)
+		elibc_musl? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-musl-core-x64.tar.gz
+		)
+	)
+	arm? (
+		elibc_glibc? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-core-arm.tar.gz
+		)
+		elibc_musl? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-musl-core-arm.tar.gz
+		)
+	)
+	arm64? (
+		elibc_glibc? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-core-arm64.tar.gz
+		)
+		elibc_musl? (
+			https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-musl-core-arm64.tar.gz
+		)
+	)
+"
+S="${WORKDIR}/Prowlarr"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm ~arm64"
+RESTRICT="bindist strip test"
+
+RDEPEND="
+	acct-group/prowlarr
+	acct-user/prowlarr
+	dev-libs/icu
+	dev-util/lttng-ust:0
+	dev-db/sqlite
+"
+
+QA_PREBUILT="*"
+
+src_prepare() {
+	default
+
+	# https://github.com/dotnet/runtime/issues/57784
+	rm libcoreclrtraceptprovider.so Prowlarr.Update/libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	newinitd "${FILESDIR}/prowlarr.init" prowlarr
+
+	keepdir /var/lib/prowlarr
+	fowners -R prowlarr:prowlarr /var/lib/prowlarr
+
+	insinto /etc/logrotate.d
+	insopts -m0644 -o root -g root
+	newins "${FILESDIR}/prowlarr.logrotate" prowlarr
+
+	dodir  "/opt/prowlarr"
+	cp -R "${S}/." "${D}/opt/prowlarr" || die "Install failed!"
+
+	systemd_dounit "${FILESDIR}/prowlarr.service"
+	systemd_newunit "${FILESDIR}/prowlarr.service" "prowlarr@.service"
+}
-- 
cgit v1.2.3