From d7ed2b01311f15ba54fe8ea872aab7d59ab2b193 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 29 Jan 2021 18:03:51 +0000
Subject: gentoo resync : 29.01.2021

---
 x11-libs/xapps/Manifest           |  2 +
 x11-libs/xapps/xapps-2.0.6.ebuild | 90 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)
 create mode 100644 x11-libs/xapps/xapps-2.0.6.ebuild

(limited to 'x11-libs/xapps')

diff --git a/x11-libs/xapps/Manifest b/x11-libs/xapps/Manifest
index 059bf311e8b9..1f867e97f4ec 100644
--- a/x11-libs/xapps/Manifest
+++ b/x11-libs/xapps/Manifest
@@ -1,3 +1,5 @@
 DIST xapps-1.8.9.tar.gz 187789 BLAKE2B 37b2d2677cb6483533d79853a83d77b30033313c06db89e93491076bb017122f77cd97b30d5ba64ce53fb41a37736791e97da785f516953b76b1d979d341e2fc SHA512 95dd1cbf84b59adf6682d9025e0cfa7a414c24d4f584cde87d0cc6ea82c06338de2c320dad8d997e105980782ec5cb23f0def6f6d60ea84be7d74c90d7cd692c
+DIST xapps-2.0.6.tar.gz 231023 BLAKE2B bc3907966c132c683e75769f8f45839d45229c77933ef861f58b03a21cca15a4f3dd610acb6a19fc16d35ddb189340cdef80704e78c89a3e49659a2f82be121e SHA512 bac6e105e2b1e237958fb610a9bd697a023c10a45131da7dee984532986022895414d81849f53bc0007c319c2139c6d39474e2e7fd9ce4e53365517f4ba4f012
 EBUILD xapps-1.8.9.ebuild 2106 BLAKE2B 43f5d9666856ebc891b8362032f6e18217147632b403ae3be201b5b09bc982ddaec49f85d7ad6b153e3826d2c445a08ef7a6a8de547eb5099056422d65b24069 SHA512 65547197cce19ac7f23eb502cdf6227979d45c9d7acf56e0ef0a91b46bd4c9d402a530091386891f54a4823d751c61e7a7009503058d04a8988166ab8ca7c413
+EBUILD xapps-2.0.6.ebuild 2097 BLAKE2B 6ceb5acdc7f639222d179e3aa7941c48c83136a3729df1bd4a2262a63d970e41419b0ac6dd934ebf99da529e61740f954b38f4a33997584ea584584fa7a20b58 SHA512 41e50d0993575743cdc24ef82aec4e7442652c1af9672723a04d4f91f2df4e1eb09a4fa08472143e3bc8038c7f8035944ec9b793067b18082403c2023d1f3439
 MISC metadata.xml 577 BLAKE2B ed5786f6e30619e209d841a04547b52f7a9a09eeb5a64f0fcbe9f33031e936610aaef4b80cd29f45d662ac23295448ba336786c31a2b5f302332750497d0f545 SHA512 3af23ee720d2691213fccfbcdde69b5af42259fb0acee32e499c51e13dc8a5414fed038372b2a485db65548b38163886911d4b44ebaaca8ff0e0274c4c40d48b
diff --git a/x11-libs/xapps/xapps-2.0.6.ebuild b/x11-libs/xapps/xapps-2.0.6.ebuild
new file mode 100644
index 000000000000..c46c8304e806
--- /dev/null
+++ b/x11-libs/xapps/xapps-2.0.6.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2-utils vala meson python-r1 xdg-utils
+
+DESCRIPTION="Cross-desktop libraries and common resources"
+HOMEPAGE="https://github.com/linuxmint/xapp/"
+LICENSE="GPL-3"
+
+SRC_URI="https://github.com/linuxmint/xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/xapp-${PV}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+SLOT="0"
+IUSE="gtk-doc introspection static-libs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.44.0:2
+	dev-libs/gobject-introspection:0=
+	dev-libs/libdbusmenu[gtk3]
+	gnome-base/libgnomekbd
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.22.0:2[introspection?]
+	>=x11-libs/gtk+-3.16.0:3[introspection?]
+	x11-libs/libxkbfile
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.40.6
+	sys-devel/gettext
+
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	xdg_environment_reset
+	vala_src_prepare
+	default
+
+	# don't install distro specific tools
+	sed -i "/subdir('scripts')/d" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dpy-overrides-dir="/pygobject"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# copy pygobject files to each active python target
+	# work-around for "py-overrides-dir" only supporting a single target
+	install_pygobject_override() {
+		PYTHON_GI_OVERRIDESDIR=$("${EPYTHON}" -c 'import gi;print(gi._overridesdir)' || die)
+		einfo "gobject overrides directory: ${PYTHON_GI_OVERRIDESDIR}"
+		mkdir -p "${ED}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		cp -r "${D}"/pygobject/* "${ED}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		python_optimize "${ED}/${PYTHON_GI_OVERRIDESDIR}/"
+	}
+	python_foreach_impl install_pygobject_override
+	rm -r "${D}/pygobject" || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3