From dbd6eaafcce6a59fa9b3323124c38fa17aa88e26 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 20 Mar 2024 19:00:10 +0000
Subject: gentoo auto-resync : 20:03:2024 - 19:00:10

---
 x11-misc/tabbed/tabbed-0.8-r1.ebuild | 53 ++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 x11-misc/tabbed/tabbed-0.8-r1.ebuild

(limited to 'x11-misc/tabbed/tabbed-0.8-r1.ebuild')

diff --git a/x11-misc/tabbed/tabbed-0.8-r1.ebuild b/x11-misc/tabbed/tabbed-0.8-r1.ebuild
new file mode 100644
index 000000000000..071f3ae506b4
--- /dev/null
+++ b/x11-misc/tabbed/tabbed-0.8-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="Simple generic tabbed fronted to xembed aware applications"
+HOMEPAGE="https://tools.suckless.org/tabbed/"
+SRC_URI="https://dl.suckless.org/tools/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXft
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	restore_config config.h
+}
+
+src_compile() {
+	tc-export CC PKG_CONFIG
+
+	local emakeargs=(
+		TABBED_CFLAGS="${CFLAGS} $("${PKG_CONFIG}" --cflags x11 xft)"
+		TABBED_LDFLAGS="${LDFLAGS} $("${PKG_CONFIG}" --libs x11 xft)"
+	)
+
+	emake "${emakeargs[@]}"
+}
+
+src_install() {
+	local emakeargs=(
+		DESTDIR="${D}"
+		PREFIX="${EPREFIX}/usr"
+		DOCPREFIX="${EPREFIX}/usr/share/doc/${PF}"
+	)
+	emake "${emakeargs[@]}" install
+
+	save_config config.h
+}
-- 
cgit v1.2.3