From eccb70a7f91b2d22582587f26d1a28bb31408b45 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 18 May 2019 00:10:51 +0100
Subject: gentoo resync : 18.05.2019

---
 x11-misc/vym/vym-2.7.1.ebuild | 74 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 x11-misc/vym/vym-2.7.1.ebuild

(limited to 'x11-misc/vym/vym-2.7.1.ebuild')

diff --git a/x11-misc/vym/vym-2.7.1.ebuild b/x11-misc/vym/vym-2.7.1.ebuild
new file mode 100644
index 000000000000..7dd60221c778
--- /dev/null
+++ b/x11-misc/vym/vym-2.7.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PLOCALES="cs_CZ de_DE el es fr hr_HR ia it ja pt_BR ru sv zh_CN zh_TW"
+inherit desktop l10n qmake-utils
+
+DESCRIPTION="View Your Mind, a mindmap tool"
+HOMEPAGE="https://www.insilmaril.de/vym/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dbus"
+
+RDEPEND="
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtxml:5
+	dbus? ( dev-qt/qtdbus:5 )
+"
+DEPEND="
+	${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+DOCS=( README.md doc/vym.pdf )
+
+src_prepare() {
+	default
+
+	if has es ${LINGUAS-es} ; then
+		DOCS+=( doc/vym_es.pdf )
+	fi
+	if has fr ${LINGUAS-fr} ; then
+		DOCS+=( doc/vym_fr.pdf )
+	fi
+
+	remove_locale() {
+		sed -i \
+			-e "/TRANSLATIONS += lang\/vym.${1}.ts/d" \
+			vym.pro || die
+	}
+
+	gunzip doc/vym.1.gz || die
+
+	#remove dead en translation
+	rm lang/vym.en.ts || die
+	remove_locale en
+
+	l10n_find_plocales_changes lang ${PN}. .ts
+	l10n_for_each_disabled_locale_do remove_locale
+
+	"$(qt5_get_bindir)"/lrelease vym.pro || die
+}
+
+src_configure() {
+	eqmake5 vym.pro \
+		PREFIX="${EPREFIX}"/usr \
+		DATADIR="${EPREFIX}"/usr/share \
+		$(usex dbus "" NO_DBUS=1 )
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+
+	doman doc/vym.1
+
+	make_desktop_entry vym vym /usr/share/vym/icons/vym.png Education
+}
-- 
cgit v1.2.3