# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
# As of 3.0.2, Upstream does NOT yet support newer than python3.8
PYTHON_COMPAT=(python3_{7..8})
PYTHON_REQ_USE="ipv6(+)?"

inherit autotools bash-completion-r1 python-single-r1 tmpfiles

MY_PV="${PV/_rc/~rc}"
MY_PV="${MY_PV/_beta/~beta}"
MY_P="${PN}-${MY_PV}"
SERIES="3.0"

if [[ ${PV} =~ [9]{4,} ]] ; then
	EGIT_REPO_URI="https://github.com/ganeti/ganeti"
	EGIT_BRANCH="stable-$SERIES"
	inherit git-r3
	PATCHES=()
else
	DEBIAN_PV="${PV}"
	#http://deb.debian.org/debian/pool/main/g/ganeti/ganeti_3.0.1-2.debian.tar.xz
	DEBIAN_PATCH=1
	SRC_URI="https://github.com/ganeti/ganeti/releases/download/v${PV}/${P}.tar.gz"
	[[ -n "${DEBIAN_PATCH}" ]] && SRC_URI+=" mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${DEBIAN_PV}-${DEBIAN_PATCH}.debian.tar.xz"
	KEYWORDS="~amd64 ~x86"
	PATCHES=(
		"${WORKDIR}"/debian/patches/0001-verify-warn-about-weak-certs.patch
		"${WORKDIR}"/debian/patches/0002-remove-hardcoded-libc-linux-constants.patch
	)
fi

DESCRIPTION="Ganeti is a virtual server management software tool"
HOMEPAGE="http://www.ganeti.org/"

LICENSE="GPL-2"
SLOT="0"
IUSE="drbd experimental ipv6 kvm lxc monitoring rbd syslog test xen restricted-commands"
RESTRICT="!test? ( test )"

REQUIRED_USE="|| ( kvm xen lxc )
	test? ( ipv6 )
	kvm? ( || ( amd64 x86 ) )
	${PYTHON_REQUIRED_USE}"

USER_PREFIX="${GANETI_USER_PREFIX:-"gnt-"}"
GROUP_PREFIX="${GANETI_GROUP_PREFIX:-"${USER_PREFIX}"}"

DEPEND="
	dev-libs/openssl:0
	$(python_gen_cond_dep '
		dev-python/paramiko[${PYTHON_USEDEP}]
		dev-python/pyopenssl[${PYTHON_USEDEP}]
		dev-python/simplejson[${PYTHON_USEDEP}]
		dev-python/pyparsing[${PYTHON_USEDEP}]
		dev-python/pyinotify[${PYTHON_USEDEP}]
		dev-python/pycurl[${PYTHON_USEDEP}]
		dev-python/ipaddr[${PYTHON_USEDEP}]
		dev-python/bitarray[${PYTHON_USEDEP}]
		dev-python/docutils[${PYTHON_USEDEP}]
		dev-python/fdsend[${PYTHON_USEDEP}]
	')
	|| (
		net-misc/iputils[arping]
		net-analyzer/arping
	)
	net-analyzer/fping
	net-misc/bridge-utils
	net-misc/curl[ssl]
	net-misc/openssh
	net-misc/socat
	sys-apps/iproute2
	sys-fs/lvm2
	>=sys-apps/baselayout-2.0
	>=dev-lang/ghc-8.0:0=
	<dev-lang/ghc-9:0=
	>=dev-haskell/cabal-3:0=
	dev-haskell/cabal-install:0=
	>=dev-haskell/mtl-2.1.1:0=
	>=dev-haskell/old-time-1.1.0.0:0=
	>=dev-haskell/random-1.0.1.1:0=
	>=dev-haskell/text-0.11.1.13:0=
	>=dev-haskell/transformers-0.3.0.0:0=

	>=dev-haskell/attoparsec-0.10.1.1:0=
	<dev-haskell/attoparsec-0.14:0
	>=dev-haskell/base64-bytestring-1.0.0.1:0=
	<dev-haskell/base64-bytestring-1.1:0=
	>=dev-haskell/cryptonite-0.23:0=
	>=dev-haskell/curl-1.3.7:0=
	<dev-haskell/curl-1.4:0=
	>=dev-haskell/hinotify-0.3.2:0=
	<dev-haskell/hinotify-0.5:0=
	>=dev-haskell/hslogger-1.1.4:0=
	<dev-haskell/hslogger-1.4:0=
	>=dev-haskell/json-0.5:0=
	<dev-haskell/json-1.0:0=
	>=dev-haskell/lens-3.10:0=
	<dev-haskell/lens-5.0:0=
	>=dev-haskell/lifted-base-0.2.0.3:0=
	<dev-haskell/lifted-base-0.3:0=
	>=dev-haskell/monad-control-0.3.1.3:0=
	<dev-haskell/monad-control-1.1:0=
	>=dev-haskell/parallel-3.2.0.2:3=
	<dev-haskell/parallel-3.3:3=
	>=dev-haskell/regex-pcre-0.94.2:0=
	<dev-haskell/regex-pcre-0.96:0=
	>=dev-haskell/temporary-1.1.2.3:0=
	<dev-haskell/temporary-1.4:0=
	>=dev-haskell/transformers-base-0.4.1:0=
	<dev-haskell/transformers-base-0.5:0=
	>=dev-haskell/utf8-string-0.3.7:0=
	>=dev-haskell/zlib-0.5.3.3:0=
	<dev-haskell/zlib-0.7:0=

	>=dev-haskell/network-2.9:0=
	<dev-haskell/network-3.2:0=
	>=dev-haskell/network-bsd-2.8:0=
	<dev-haskell/network-bsd-2.9:0=

	>=dev-haskell/psqueue-1.1:0=
	<dev-haskell/psqueue-1.2:0=
	>=dev-haskell/snap-core-1.0.0:0=
	>=dev-haskell/snap-server-1.0.0:0=
	>=dev-haskell/case-insensitive-0.4.0.1:0=
	<dev-haskell/case-insensitive-1.3:0=

	dev-haskell/vector:0=
	xen? ( >=app-emulation/xen-3.0 )
	kvm? (
		dev-python/psutil
		app-emulation/qemu
	)
	lxc? ( app-containers/lxc )
	drbd? ( sys-cluster/drbd-utils )
	rbd? ( sys-cluster/ceph )
	ipv6? ( net-misc/ndisc6 )
	${PYTHON_DEPS}"
RDEPEND="${DEPEND}"
DEPEND+="
	sys-devel/m4
	app-text/pandoc
	$(python_gen_cond_dep '
		dev-python/sphinx[${PYTHON_USEDEP}]
	')
	media-fonts/urw-fonts
	media-gfx/graphviz
	test? (
		dev-python/mock
		dev-python/pyyaml
		dev-haskell/haddock:0=
		>=dev-haskell/hunit-1.2.4.2:0=
		<dev-haskell/hunit-1.7:0=
		>=dev-haskell/quickcheck-2.8:2=
		<dev-haskell/quickcheck-2.14:2=
		>=dev-haskell/test-framework-0.6:0=
		<dev-haskell/test-framework-0.9:0=
		>=dev-haskell/test-framework-hunit-0.2.7:0=
		<dev-haskell/test-framework-hunit-0.4:0=
		>=dev-haskell/test-framework-quickcheck2-0.2.12.1:0=
		<dev-haskell/test-framework-quickcheck2-0.4:0=
		sys-apps/fakeroot
		>=net-misc/socat-1.7
		dev-util/shelltestrunner
	)"

PATCHES+=(
	#"${FILESDIR}/${PN}-2.12-start-stop-daemon-args.patch"
	#"${FILESDIR}/${PN}-2.11-add-pgrep.patch"
	#"${FILESDIR}/${PN}-2.15-daemon-util.patch"

	"${FILESDIR}/${PN}-2.9-disable-root-tests.patch"
	"${FILESDIR}/${PN}-2.9-skip-cli-test.patch"
	"${FILESDIR}/${PN}-2.10-rundir.patch"
	"${FILESDIR}/${PN}-2.12-qemu-enable-kvm.patch"
	"${FILESDIR}/${PN}-2.11-tests.patch"
	"${FILESDIR}/${PN}-lockdir.patch"
	"${FILESDIR}/${PN}-2.11-dont-nest-libdir.patch"
	"${FILESDIR}/${PN}-2.11-dont-print-man-help.patch"
	"${FILESDIR}/${PN}-2.11-daemon-util-tests.patch"
	#"${FILESDIR}/${PN}-2.13-process_unittest.patch"
	#"${FILESDIR}/${PN}-2.15-python-mock.patch"
	#"${FILESDIR}/${PN}-2.15.2-remove-sandbox-failing-tests.patch"
	"${FILESDIR}/${PN}-2.16-noded-must-run-as-root.patch"
	"${FILESDIR}/${PN}-2.16-kvmd-run-as-daemon-user.patch"
	"${FILESDIR}/${PN}-2.15-dont-invert-return-values-for-man-warnings.patch"
	#"${FILESDIR}/fix_ftbfs_with_sphinx_1.4"
	#"${FILESDIR}/${PN}-2.17-relax-deps.patch"
	##"${FILESDIR}"/${PN}-3.0.1-template_haskell.patch
	##"${FILESDIR}"/${PN}-3.0.1-docfixes.patch
	##"${FILESDIR}"/${PN}-3.0.1-sphinx.patch
	"${FILESDIR}"/${PN}-3.0.1-buildfix.patch
	"${FILESDIR}"/${PN}-3.0.1-gentoo-infra-hacks.patch
	"${FILESDIR}"/ganeti-3.0.2-less-sleep.patch
	"${FILESDIR}"/${PN}-3.0.2-gentoo-daemon-util-part2.patch
)

S="${WORKDIR}/${MY_P}"

QA_WX_LOAD="
	usr/lib*/${PN}/${SERIES}/usr/sbin/ganeti-*d
	usr/lib*/${PN}/${SERIES}/ganeti/mon-collector
	usr/lib*/${PN}/${SERIES}/usr/bin/htools
"

pkg_setup() {
	local user
	python-single-r1_pkg_setup

	# Unknown if this functionality was ever used. Maybe re-introduce if issues
	# reported.
	#if use multiple-users; then
	#	for user in gnt-{masterd,confd,luxid,rapi,daemons,admin}; do
	#		enewgroup ${user}
	#		enewuser ${user} -1 -1 -1 ${user}
	#	done
	#fi
}

# These flags get applied in src_prepare and src_configure
GNT_HASKELL_FLAGS="-optl -Wl,-z,relro -optl -Wl,--as-needed -Wno-unused-imports -Wno-deprecations -Wno-monomorphism-restriction"

src_prepare() {
	local testfile
	if has_version '>=dev-lang/ghc-8.10'; then
		# Breaks the build on 7.8
		PATCHES+=(
			#"${WORKDIR}"/debian/patches/ghc-7.10-compatibility.patch
		)
	fi
	if use experimental; then
		ewarn "Experimental patches have been applied! RPC between daemons with different patches applied may cause breakage!"
		PATCHES+=(
		)
	fi

	# Some debian patches have trailing whitespace, which trips upstream testing
	if test -d "${WORKDIR}"/debian/patches ; then
		sed -r -i -e 's,[[:space:]]+$,,g' "${WORKDIR}"/debian/patches/* || die "sed failed"
	fi

	eapply "${PATCHES[@]}"
	# Upstream commits:
	# 4c3c2ca2a97a69c0287a3d23e064bc17978105eb
	# 24618882737fd7c189adf99f4acc767d48f572c3
	sed -i \
		-e '/QuickCheck/s,< 2.8,< 2.8.3,g' \
		cabal/ganeti.template.cabal
	# Neuter -Werror
	sed -i \
		-e '/^if DEVELOPER_MODE/,/^endif/s/-Werror//' \
		Makefile.am

	# not sure why these tests are failing
	# should remove this on next version bump if possible
	for testfile in test/py/import-export_unittest.bash; do
		printf '#!/bin/bash\ntrue\n' > "${testfile}"
	done

	# take the sledgehammer approach to bug #526270
	grep -lr '/bin/sh' "${S}" | xargs -r -- sed -i 's:/bin/sh:/bin/bash:g'

	eapply_user

	[[ ${PV} =~ [9]{4,} ]] && ./autogen.sh
	rm autotools/missing
	eautoreconf
	# Disable warnings to make it easier to see failure
	sed -i -e "/^GHC_BYVERSION_FLAGS = @GHC_BYVERSION_FLAGS@/s/$/ ${GNT_HASKELL_FLAGS}/g" "${S}"/Makefile.in
}

src_compile() {
	export TMPDIR="${T}/tmp"
	mkdir -p "${TMPDIR}"
	default
}

src_configure() {
	# this is kind of a hack to work around the removal of the qemu-kvm wrapper
	local kvm_arch

	if use amd64; then
		kvm_arch=x86_64
	elif use x86; then
		kvm_arch=i386
	elif use kvm; then
		die "Could not determine qemu system to use for kvm"
	fi

	econf_opt=(
		--localstatedir=/var
		--sharedstatedir=/var
		--disable-symlinks
		--with-sshd-restart-command='/etc/init.d/sshd restart'
		#--with-export-dir=/var/lib/ganeti-storage/export # Old gentoo
		--with-export-dir=/srv/ganeti/export # Upstream recommended

		#--with-extstorage-search-path=/var/lib/ganeti-storage/ # Old Gentoo
		--with-extstorage-search-path=/srv/ganeti/extstorage,/var/lib/ganeti-storage/ext # Upstream + Gentoo

		--with-os-search-path=/srv/ganeti/os,/usr/share/${PN}/os # Upstream + Gentoo

		--disable-manpages-in-doc
		--enable-metadata
		$(use_enable restricted-commands)
		$(use_enable test haskell-tests)
		#$(usex multiple-users "--with-default-user=" "" "gnt-daemons" "")
		#$(usex multiple-users "--with-user-prefix=" "" "${USER_PREFIX}" "")
		#$(usex multiple-users "--with-default-group=" "" "gnt-daemons" "")
		#$(usex multiple-users "--with-group-prefix=" "" "${GROUP_PREFIX}" "")
		$(use_enable syslog)
		$(use_enable monitoring)
		$(usex kvm '--with-kvm-path=' '' "/usr/bin/qemu-system-${kvm_arch}" '')
		--with-haskell-flags="${GNT_HASKELL_FLAGS}"
		--enable-socat-escape
		--enable-socat-compress
		--disable-maintainer-mode
		# Upstream ships some weird defaults for filenames
		--with-xen-kernel=/boot/kernel
		--with-kvm-kernel=/boot/kernel
		--with-xen-initrd=/boot/initramfs
		--with-kvm-initrd=/boot/initramfs

		# Force this split haskell module
		ENABLE_NETWORK_BSD=1
	)
	econf "${econf_opt[@]}"
}

src_compile() {
	emake ENABLE_MANPAGES="" MAN_HAS_WARNINGS=""
}

src_install() {
	emake V=1 DESTDIR="${D}" ENABLE_MANPAGES="" MAN_HAS_WARNINGS="" install

	newinitd "${FILESDIR}"/ganeti.initd-r6 ${PN}
	newconfd "${FILESDIR}"/ganeti.confd-r5 ${PN}

	if use kvm; then
		newinitd "${FILESDIR}"/ganeti-kvm-poweroff.initd ganeti-kvm-poweroff
		newconfd "${FILESDIR}"/ganeti-kvm-poweroff.confd ganeti-kvm-poweroff
	fi

	# ganeti installs it's own docs in a generic location
	rm -rf "${D}"/{usr/share/doc/${PN},run}

	sed -i "s:/usr/$(get_libdir)/${PN}/tools/burnin:burnin:" doc/examples/bash_completion
	newbashcomp doc/examples/bash_completion gnt-instance
	bashcomp_alias gnt-instance burnin ganeti-{cleaner,confd} \
		h{space,check,scan,info,ail,arep,roller,squeeze,bal} \
		gnt-{os,job,filter,debug,storage,group,node,network,backup,cluster}

	use monitoring && bashcomp_alias gnt-instance mon-collector

	dodoc INSTALL UPGRADE NEWS README doc/*.rst

	docinto html
	dodoc -r doc/html/*

	docinto examples
	dodoc doc/examples/{ganeti.cron,gnt-config-backup} doc/examples/*.ocf

	docinto examples/hooks
	dodoc doc/examples/hooks/{ipsec,ethers}

	insinto /etc/cron.d
	newins doc/examples/ganeti.cron ${PN}

	insinto /etc/logrotate.d
	newins doc/examples/ganeti.logrotate ${PN}

	newtmpfiles "${FILESDIR}"/ganeti-tmpfilesd ${PN}.conf

	keepdir /var/log/${PN}/
	keepdir /usr/share/${PN}/${SERIES}/os/
	# These are the older Gentoo paths
	keepdir /var/lib/ganeti-storage/{export,file,shared}/

	# This is handled by tmpfiles. You cannot use keepdir here as Ganeti refuses to have other files in it!
	rmdir "${D}"/var/lib/ganeti || true

	dosym ${SERIES} "/usr/share/${PN}/default"
	dosym ${SERIES} "/usr/$(get_libdir)/${PN}/default"

	python_fix_shebang "${ED}" "${D}"/usr/"$(get_libdir)"/${PN}/${SERIES}

	# Be opinionated, this is the paths that upstream suggests and uses as defaults in configure.
	# ganeti-tmpfilesd will ensure they are created
	touch "${D}"/etc/ganeti/file-storage-paths
	echo /srv/ganeti/file-storage >>"${D}"/etc/ganeti/file-storage-paths
	echo /srv/ganeti/shared-file-storage >>"${D}"/etc/ganeti/file-storage-paths
}

pkg_postinst() {
	if use multiple-users; then
		elog "You have enable multiple user support, the users for this must"
		elog "be created. You can use the provided tool for this, which is"
		elog "located at:"
		elog "    /usr/$(get_libdir)/${PN}/tools/users-setup"
	fi
}

src_test() {
	# locale is used in some of the doc checks
	export LC_ALL=C
	PATH="${S}/scripts:${S}/src:${PATH}" \
	TMPDIR="/tmp" \
	LC_ALL=C \
	GANETI_MASTER="$(hostname -f)" \
	emake check
}