blob: 7d9c41cd930858729a7ca43a5fb55498b24e5f35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
MK_VER=20210330
DESCRIPTION="NetBSD's portable make"
HOMEPAGE="http://www.crufty.net/help/sjg/bmake.html"
SRC_URI="
http://void.crufty.net/ftp/pub/sjg/${P}.tar.gz
http://void.crufty.net/ftp/pub/sjg/mk-${MK_VER}.tar.gz"
S="${WORKDIR}/${PN}"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
# Skip failing test (sandbox and csh)
PATCHES=( "${FILESDIR}"/${PN}-20210206-tests.patch )
src_prepare() {
default
cd "${WORKDIR}" || die
eapply "${FILESDIR}"/${PN}-20210314-mk-fixes.patch
}
src_configure() {
econf \
--with-mksrc=../mk \
--with-default-sys-path="${EPREFIX}"/usr/share/mk/${PN} \
--with-machine_arch=${ARCH}
}
src_compile() {
sh make-bootstrap.sh || die "bootstrap failed"
}
src_test() {
cd unit-tests || die
# the 'ternary' test uses ${A} internally, which
# conflicts with Gentoo's ${A}, hence unset it for
# the tests temporarily.
env -u A MAKEFLAGS= \
"${S}"/bmake -r -m / TEST_MAKE="${S}"/bmake test || die "tests compilation failed"
}
src_install() {
dobin ${PN}
doman ${PN}.1
FORCE_BSD_MK=1 SYS_MK_DIR=. \
sh ../mk/install-mk -v -m 644 "${ED}"/usr/share/mk/${PN} \
|| die "failed to install mk files"
}
|