dev-python/grpcio{,-tools} : update PYTHON_COMPAT

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/grpcio/grpcio-1.59.0-r1.ebuild b/dev-python/grpcio/grpcio-1.59.0-r1.ebuild
new file mode 100644
index 00000000..68d55056
--- /dev/null
+++ b/dev-python/grpcio/grpcio-1.59.0-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 multiprocessing prefix pypi
+
+DESCRIPTION="High-performance RPC framework (python libraries)"
+HOMEPAGE="https://grpc.io"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ~ppc64 ~riscv x86"
+
+RDEPEND="
+	>=dev-libs/openssl-1.1.1:0=[-bindist(-)]
+	>=dev-libs/re2-0.2021.11.01:=
+	>=dev-python/cython-0.29.36[${PYTHON_USEDEP}]
+	<dev-python/protobuf-python-5[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-4.21.3[${PYTHON_USEDEP}]
+	net-dns/c-ares:=
+	sys-libs/zlib:=
+"
+
+DEPEND="${RDEPEND}"
+
+python_prepare_all() {
+	if has_version ">=dev-python/cython-3.0.0[${PYTHON_USEDEP}]"; then
+		PATCHES=( "${FILESDIR}/1.59.0-cython3.patch" )
+	fi
+	distutils-r1_python_prepare_all
+	hprefixify setup.py
+}
+
+python_configure_all() {
+	# os.environ.get('GRPC_BUILD_WITH_BORING_SSL_ASM', True)
+	export GRPC_BUILD_WITH_BORING_SSL_ASM=
+	export GRPC_PYTHON_DISABLE_LIBC_COMPATIBILITY=1
+	export GRPC_PYTHON_BUILD_SYSTEM_CARES=1
+	export GRPC_PYTHON_BUILD_SYSTEM_OPENSSL=1
+	export GRPC_PYTHON_BUILD_WITH_SYSTEM_RE2=1
+	export GRPC_PYTHON_BUILD_SYSTEM_ZLIB=1
+	export GRPC_PYTHON_BUILD_WITH_CYTHON=1
+	export GRPC_PYTHON_BUILD_EXT_COMPILER_JOBS="$(makeopts_jobs)"
+}