dev-qt/qdbusviewer : import from gentoo tree, make it use our eclass, increase revision to beat gentoo

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-qt/qdbusviewer/qdbusviewer-5.9.5-r1000.ebuild b/dev-qt/qdbusviewer/qdbusviewer-5.9.5-r1000.ebuild
new file mode 100644
index 00000000..2441ab8f
--- /dev/null
+++ b/dev-qt/qdbusviewer/qdbusviewer-5.9.5-r1000.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit desktop gnome2-utils qt5-build-r10000
+
+DESCRIPTION="Graphical tool that lets you introspect D-Bus objects and messages"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="amd64"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdbus-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtwidgets-${PV}
+	~dev-qt/qtxml-${PV}
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/qdbus/qdbusviewer
+)
+
+src_install() {
+	qt5-build-r10000_src_install
+
+	doicon -s 32 src/qdbus/qdbusviewer/images/qdbusviewer.png
+	newicon -s 128 src/qdbus/qdbusviewer/images/qdbusviewer-128.png qdbusviewer.png
+	make_desktop_entry "${QT5_BINDIR}"/qdbusviewer 'Qt 5 QDBusViewer' qdbusviewer 'Qt;Development'
+}
+
+pkg_postinst() {
+	qt5-build-r10000_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	qt5-build-r10000_pkg_postrm
+	gnome2_icon_cache_update
+}