dev-qt : bump to 5.9.5

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.9.5-r1000.ebuild b/dev-qt/qtdeclarative/qtdeclarative-5.9.5-r1000.ebuild
new file mode 100644
index 00000000..8186bb3b
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.9.5-r1000.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+inherit python-any-r1 qt5-build-r10000
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="amd64"
+fi
+
+IUSE="gles2 +jit localstorage +widgets xml"
+
+# qtgui[gles2=] is needed because of bug 504322
+COMMON_DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=]
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qttest-${PV}
+	localstorage? ( ~dev-qt/qtsql-${PV} )
+	widgets? ( ~dev-qt/qtwidgets-${PV}[gles2=] )
+	xml? (
+		~dev-qt/qtnetwork-${PV}
+		~dev-qt/qtxmlpatterns-${PV}
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+"
+RDEPEND="${COMMON_DEPEND}
+	!<dev-qt/qtquickcontrols-5.7:5
+"
+
+PATCHES=( "${FILESDIR}/${P}-texture-memleak.patch" )
+
+src_prepare() {
+	use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
+
+	qt_use_disable_mod localstorage sql \
+		src/imports/imports.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/qmltest/qmltest.pro \
+		tests/auto/auto.pro \
+		tools/tools.pro \
+		tools/qmlscene/qmlscene.pro \
+		tools/qml/qml.pro
+
+	qt_use_disable_mod xml xmlpatterns \
+		src/imports/imports.pro \
+		tests/auto/quick/quick.pro \
+		tests/auto/quick/examples/examples.pro
+
+	qt5-build-r10000_src_prepare
+}