dev-qt : import 5.11.1 from gentoo tree, prepare for qt5 bump

52 files changed, 2055 insertions, 0 deletions

diff --git a/dev-qt/assistant/assistant-5.11.1.ebuild b/dev-qt/assistant/assistant-5.11.1.ebuild
new file mode 100644
index 00000000..0fe2bc14
--- /dev/null
+++ b/dev-qt/assistant/assistant-5.11.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit desktop gnome2-utils qt5-build
+
+DESCRIPTION="Tool for viewing on-line documentation in Qt help file format"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~x86"
+fi
+
+IUSE="webkit"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qthelp-${PV}
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qtprintsupport-${PV}
+	~dev-qt/qtsql-${PV}[sqlite]
+	~dev-qt/qtwidgets-${PV}
+	webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/assistant/assistant
+)
+
+src_prepare() {
+	qt_use_disable_mod webkit webkitwidgets \
+		src/assistant/assistant/assistant.pro
+
+	qt5-build_src_prepare
+}
+
+src_install() {
+	qt5-build_src_install
+
+	doicon -s 32 src/assistant/assistant/images/assistant.png
+	newicon -s 128 src/assistant/assistant/images/assistant-128.png assistant.png
+	make_desktop_entry "${QT5_BINDIR}"/assistant 'Qt 5 Assistant' assistant 'Qt;Development;Documentation'
+}
+
+pkg_postinst() {
+	qt5-build_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	qt5-build_pkg_postrm
+	gnome2_icon_cache_update
+}
diff --git a/dev-qt/designer/designer-5.11.1.ebuild b/dev-qt/designer/designer-5.11.1.ebuild
new file mode 100644
index 00000000..c561782d
--- /dev/null
+++ b/dev-qt/designer/designer-5.11.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit desktop gnome2-utils qt5-build
+
+DESCRIPTION="WYSIWYG tool for designing and building Qt-based GUIs"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="declarative webkit"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qtprintsupport-${PV}
+	~dev-qt/qtwidgets-${PV}
+	~dev-qt/qtxml-${PV}
+	declarative? ( ~dev-qt/qtdeclarative-${PV}[widgets] )
+	webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/designer
+)
+
+src_prepare() {
+	qt_use_disable_mod declarative quickwidgets \
+		src/designer/src/plugins/plugins.pro
+
+	qt_use_disable_mod webkit webkitwidgets \
+		src/designer/src/plugins/plugins.pro
+
+	qt5-build_src_prepare
+}
+
+src_install() {
+	qt5-build_src_install
+
+	doicon -s 128 src/designer/src/designer/images/designer.png
+	make_desktop_entry "${QT5_BINDIR}"/designer 'Qt 5 Designer' designer 'Qt;Development;GUIDesigner'
+}
+
+pkg_postinst() {
+	qt5-build_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	qt5-build_pkg_postrm
+	gnome2_icon_cache_update
+}
diff --git a/dev-qt/linguist-tools/linguist-tools-5.11.1.ebuild b/dev-qt/linguist-tools/linguist-tools-5.11.1.ebuild
new file mode 100644
index 00000000..72c04bdc
--- /dev/null
+++ b/dev-qt/linguist-tools/linguist-tools-5.11.1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit qt5-build
+
+DESCRIPTION="Tools for working with Qt translation data files"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="qml"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtxml-${PV}
+	qml? ( ~dev-qt/qtdeclarative-${PV} )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/linguist
+)
+
+src_prepare() {
+	sed -i -e '/SUBDIRS += linguist/d' \
+		src/linguist/linguist.pro || die
+
+	qt_use_disable_mod qml qmldevtools-private \
+		src/linguist/lupdate/lupdate.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/linguist/linguist-5.11.1.ebuild b/dev-qt/linguist/linguist-5.11.1.ebuild
new file mode 100644
index 00000000..38f06fe3
--- /dev/null
+++ b/dev-qt/linguist/linguist-5.11.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit desktop gnome2-utils qt5-build
+
+DESCRIPTION="Graphical tool for translating Qt applications"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/designer-${PV}
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtprintsupport-${PV}
+	~dev-qt/qtwidgets-${PV}
+	~dev-qt/qtxml-${PV}
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/linguist/linguist
+)
+
+src_install() {
+	qt5-build_src_install
+
+	local size
+	for size in 16 32 48 64 128; do
+		newicon -s ${size} src/linguist/linguist/images/icons/linguist-${size}-32.png linguist.png
+	done
+	make_desktop_entry "${QT5_BINDIR}"/linguist 'Qt 5 Linguist' linguist 'Qt;Development;Translation'
+}
+
+pkg_postinst() {
+	qt5-build_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	qt5-build_pkg_postrm
+	gnome2_icon_cache_update
+}
diff --git a/dev-qt/pixeltool/pixeltool-5.11.1.ebuild b/dev-qt/pixeltool/pixeltool-5.11.1.ebuild
new file mode 100644
index 00000000..7bcdc97e
--- /dev/null
+++ b/dev-qt/pixeltool/pixeltool-5.11.1.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit qt5-build
+
+DESCRIPTION="Qt screen magnifier"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtwidgets-${PV}
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/pixeltool
+)
diff --git a/dev-qt/qdbus/qdbus-5.11.1.ebuild b/dev-qt/qdbus/qdbus-5.11.1.ebuild
new file mode 100644
index 00000000..4736c7cd
--- /dev/null
+++ b/dev-qt/qdbus/qdbus-5.11.1.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit qt5-build
+
+DESCRIPTION="Interface to Qt applications communicating over D-Bus"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdbus-${PV}
+	~dev-qt/qtxml-${PV}
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/qdbus/qdbus
+)
diff --git a/dev-qt/qdbusviewer/qdbusviewer-5.11.1.ebuild b/dev-qt/qdbusviewer/qdbusviewer-5.11.1.ebuild
new file mode 100644
index 00000000..ceb1e6f9
--- /dev/null
+++ b/dev-qt/qdbusviewer/qdbusviewer-5.11.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit desktop gnome2-utils qt5-build
+
+DESCRIPTION="Graphical tool that lets you introspect D-Bus objects and messages"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdbus-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtwidgets-${PV}
+	~dev-qt/qtxml-${PV}
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/qdbus/qdbusviewer
+)
+
+src_install() {
+	qt5-build_src_install
+
+	doicon -s 32 src/qdbus/qdbusviewer/images/qdbusviewer.png
+	newicon -s 128 src/qdbus/qdbusviewer/images/qdbusviewer-128.png qdbusviewer.png
+	make_desktop_entry "${QT5_BINDIR}"/qdbusviewer 'Qt 5 QDBusViewer' qdbusviewer 'Qt;Development'
+}
+
+pkg_postinst() {
+	qt5-build_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	qt5-build_pkg_postrm
+	gnome2_icon_cache_update
+}
diff --git a/dev-qt/qdoc/qdoc-5.11.1.ebuild b/dev-qt/qdoc/qdoc-5.11.1.ebuild
new file mode 100644
index 00000000..4c656e1b
--- /dev/null
+++ b/dev-qt/qdoc/qdoc-5.11.1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit qt5-build
+
+DESCRIPTION="Qt documentation generator"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="qml"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	sys-devel/clang:=
+	qml? ( ~dev-qt/qtdeclarative-${PV} )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/qdoc
+)
+
+src_prepare() {
+	qt_use_disable_mod qml qmldevtools-private \
+		src/qdoc/qdoc.pro
+
+	export LLVM_INSTALL_DIR="$(llvm-config --prefix)"
+	# this is normally loaded in qttools.pro, so skipped by using
+	# QT_TARGET_SUBDIRS causing build to fail
+	sed -e '1iload(qt_find_clang)\' -i src/qdoc/qdoc.pro || die
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qt3d/qt3d-5.11.1.ebuild b/dev-qt/qt3d/qt3d-5.11.1.ebuild
new file mode 100644
index 00000000..e6563090
--- /dev/null
+++ b/dev-qt/qt3d/qt3d-5.11.1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="The 3D module for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+# TODO: gamepad, tools
+IUSE="gles2 qml"
+
+DEPEND="
+	~dev-qt/qtconcurrent-${PV}
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtnetwork-${PV}
+	>=media-libs/assimp-4.0.0
+	qml? ( ~dev-qt/qtdeclarative-${PV}[gles2=] )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	rm -r src/3rdparty/assimp/{code,contrib,include} || die
+
+	qt_use_disable_mod qml quick src/src.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtbluetooth/qtbluetooth-5.11.1.ebuild b/dev-qt/qtbluetooth/qtbluetooth-5.11.1.ebuild
new file mode 100644
index 00000000..7f4a8b1b
--- /dev/null
+++ b/dev-qt/qtbluetooth/qtbluetooth-5.11.1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtconnectivity"
+inherit qt5-build
+
+DESCRIPTION="Bluetooth support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+IUSE="qml"
+
+RDEPEND="
+	~dev-qt/qtconcurrent-${PV}
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdbus-${PV}
+	>=net-wireless/bluez-5:=
+	qml? ( ~dev-qt/qtdeclarative-${PV} )
+"
+DEPEND="${RDEPEND}
+	~dev-qt/qtnetwork-${PV}
+"
+
+src_prepare() {
+	sed -i -e 's/nfc//' src/src.pro || die
+
+	qt_use_disable_mod qml quick src/src.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtcharts/qtcharts-5.11.1.ebuild b/dev-qt/qtcharts/qtcharts-5.11.1.ebuild
new file mode 100644
index 00000000..ff3df69c
--- /dev/null
+++ b/dev-qt/qtcharts/qtcharts-5.11.1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Chart component library for the Qt5 framework"
+LICENSE="GPL-3"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="qml"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtwidgets-${PV}
+	qml? ( ~dev-qt/qtdeclarative-${PV} )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	qt_use_disable_mod qml quick \
+		src/src.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtconcurrent/qtconcurrent-5.11.1.ebuild b/dev-qt/qtconcurrent/qtconcurrent-5.11.1.ebuild
new file mode 100644
index 00000000..75e304af
--- /dev/null
+++ b/dev-qt/qtconcurrent/qtconcurrent-5.11.1.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Multi-threading concurrence support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/concurrent
+)
diff --git a/dev-qt/qtcore/qtcore-5.11.1.ebuild b/dev-qt/qtcore/qtcore-5.11.1.ebuild
new file mode 100644
index 00000000..48916104
--- /dev/null
+++ b/dev-qt/qtcore/qtcore-5.11.1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Cross-platform application development framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="icu systemd"
+
+DEPEND="
+	dev-libs/double-conversion:=
+	dev-libs/glib:2
+	dev-libs/libpcre2[pcre16,unicode]
+	sys-libs/zlib
+	icu? ( dev-libs/icu:= )
+	!icu? ( virtual/libiconv )
+	systemd? ( sys-apps/systemd:= )
+"
+RDEPEND="${DEPEND}
+	!<dev-qt/qtcore-4.8.7-r4:4
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/bootstrap
+	src/tools/moc
+	src/tools/rcc
+	src/tools/qfloat16-tables
+	src/corelib
+	src/tools/qlalr
+	doc
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	!:network
+	!:sql
+	!:testlib
+	!:xml
+)
+
+src_configure() {
+	local myconf=(
+		$(qt_use icu)
+		$(qt_use !icu iconv)
+		$(qt_use systemd journald)
+	)
+	qt5-build_src_configure
+}
+
+src_install() {
+	qt5-build_src_install
+
+	local flags=(
+		ALSA CUPS DBUS EGL EGLFS EGL_X11 EVDEV FONTCONFIG FREETYPE
+		HARFBUZZ IMAGEFORMAT_JPEG IMAGEFORMAT_PNG LIBPROXY MITSHM
+		OPENGL OPENSSL OPENVG PULSEAUDIO SHAPE SSL TSLIB WIDGETS
+		XCURSOR	XFIXES XKB XRANDR XRENDER XSYNC ZLIB
+	)
+
+	for flag in ${flags[@]}; do
+		cat >> "${D%/}"/${QT5_HEADERDIR}/QtCore/qconfig.h <<- _EOF_ || die
+
+			#if defined(QT_NO_${flag}) && defined(QT_${flag})
+			# undef QT_NO_${flag}
+			#elif !defined(QT_NO_${flag}) && !defined(QT_${flag})
+			# define QT_NO_${flag}
+			#endif
+		_EOF_
+	done
+}
diff --git a/dev-qt/qtdatavis3d/qtdatavis3d-5.11.1.ebuild b/dev-qt/qtdatavis3d/qtdatavis3d-5.11.1.ebuild
new file mode 100644
index 00000000..64777049
--- /dev/null
+++ b/dev-qt/qtdatavis3d/qtdatavis3d-5.11.1.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="3D data visualization library for the Qt5 framework"
+LICENSE="GPL-3"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="gles2 qml"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=]
+	qml? ( ~dev-qt/qtdeclarative-${PV}[gles2=] )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# eliminate bogus dependency on qtwidgets
+	sed -i -e '/requires.*widgets/d' qtdatavis3d.pro || die
+
+	qt_use_disable_mod qml quick \
+		src/src.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtdbus/qtdbus-5.11.1.ebuild b/dev-qt/qtdbus/qtdbus-5.11.1.ebuild
new file mode 100644
index 00000000..b31a0a2f
--- /dev/null
+++ b/dev-qt/qtdbus/qtdbus-5.11.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Qt5 module for inter-process communication over the D-Bus protocol"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	>=sys-apps/dbus-1.4.20
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/dbus
+	src/tools/qdbusxml2cpp
+	src/tools/qdbuscpp2xml
+)
+
+QT5_GENTOO_CONFIG=(
+	:dbus
+	:dbus-linked:
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:dbus
+	:dbus-linked
+)
+
+src_configure() {
+	local myconf=(
+		-dbus-linked
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.11.1.ebuild b/dev-qt/qtdeclarative/qtdeclarative-5.11.1.ebuild
new file mode 100644
index 00000000..3da293ee
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.11.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+inherit python-any-r1 qt5-build
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="gles2 +jit localstorage +widgets xml"
+
+# qtgui[gles2=] is needed because of bug 504322
+COMMON_DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=]
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qttest-${PV}
+	localstorage? ( ~dev-qt/qtsql-${PV} )
+	widgets? ( ~dev-qt/qtwidgets-${PV}[gles2=] )
+	xml? (
+		~dev-qt/qtnetwork-${PV}
+		~dev-qt/qtxmlpatterns-${PV}
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+"
+RDEPEND="${COMMON_DEPEND}
+	!<dev-qt/qtquickcontrols-5.7:5
+"
+
+src_prepare() {
+	use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
+
+	qt_use_disable_mod localstorage sql \
+		src/imports/imports.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/qmltest/qmltest.pro \
+		tests/auto/auto.pro \
+		tools/tools.pro \
+		tools/qmlscene/qmlscene.pro \
+		tools/qml/qml.pro
+
+	qt_use_disable_mod xml xmlpatterns \
+		src/imports/imports.pro \
+		tests/auto/quick/quick.pro \
+		tests/auto/quick/examples/examples.pro
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		-qml-debug
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtdiag/qtdiag-5.11.1.ebuild b/dev-qt/qtdiag/qtdiag-5.11.1.ebuild
new file mode 100644
index 00000000..85c0174e
--- /dev/null
+++ b/dev-qt/qtdiag/qtdiag-5.11.1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit qt5-build
+
+DESCRIPTION="Tool for reporting diagnostic information about Qt and its environment"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~x86"
+fi
+
+IUSE="+network +widgets"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	network? ( ~dev-qt/qtnetwork-${PV}[ssl] )
+	widgets? ( ~dev-qt/qtwidgets-${PV} )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/qtdiag
+)
+
+src_prepare() {
+	qt_use_disable_mod network network \
+		src/qtdiag/qtdiag.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/qtdiag/qtdiag.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtgraphicaleffects/qtgraphicaleffects-5.11.1.ebuild b/dev-qt/qtgraphicaleffects/qtgraphicaleffects-5.11.1.ebuild
new file mode 100644
index 00000000..51a225a5
--- /dev/null
+++ b/dev-qt/qtgraphicaleffects/qtgraphicaleffects-5.11.1.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VIRTUALX_REQUIRED="test"
+inherit qt5-build
+
+DESCRIPTION="Set of QML types for adding visual effects to user interfaces"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE=""
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}
+"
+DEPEND="${RDEPEND}"
diff --git a/dev-qt/qtgui/qtgui-5.11.1.ebuild b/dev-qt/qtgui/qtgui-5.11.1.ebuild
new file mode 100644
index 00000000..034e4220
--- /dev/null
+++ b/dev-qt/qtgui/qtgui-5.11.1.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="The GUI module and platform plugins for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+# TODO: linuxfb
+
+IUSE="accessibility dbus egl eglfs evdev +gif gles2 ibus
+	jpeg +libinput +png tslib tuio +udev vnc +xcb"
+REQUIRED_USE="
+	|| ( eglfs xcb )
+	accessibility? ( dbus xcb )
+	eglfs? ( egl )
+	ibus? ( dbus )
+	libinput? ( udev )
+	xcb? ( gles2? ( egl ) )
+"
+
+RDEPEND="
+	dev-libs/glib:2
+	~dev-qt/qtcore-${PV}
+	media-libs/fontconfig
+	>=media-libs/freetype-2.6.1:2
+	>=media-libs/harfbuzz-1.6.0:=
+	>=sys-libs/zlib-1.2.5
+	virtual/opengl
+	dbus? ( ~dev-qt/qtdbus-${PV} )
+	egl? ( media-libs/mesa[egl] )
+	eglfs? (
+		media-libs/mesa[gbm]
+		x11-libs/libdrm
+	)
+	evdev? ( sys-libs/mtdev )
+	gles2? ( media-libs/mesa[gles2] )
+	jpeg? ( virtual/jpeg:0 )
+	libinput? (
+		dev-libs/libinput:=
+		x11-libs/libxkbcommon
+	)
+	png? ( media-libs/libpng:0= )
+	tslib? ( x11-libs/tslib )
+	tuio? ( ~dev-qt/qtnetwork-${PV} )
+	udev? ( virtual/libudev:= )
+	vnc? ( ~dev-qt/qtnetwork-${PV} )
+	xcb? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		>=x11-libs/libXi-1.7.5
+		>=x11-libs/libxcb-1.10:=[xkb]
+		>=x11-libs/libxkbcommon-0.4.1[X]
+		x11-libs/xcb-util-image
+		x11-libs/xcb-util-keysyms
+		x11-libs/xcb-util-renderutil
+		x11-libs/xcb-util-wm
+	)
+"
+DEPEND="${RDEPEND}
+	evdev? ( sys-kernel/linux-headers )
+	udev? ( sys-kernel/linux-headers )
+"
+PDEPEND="
+	ibus? ( app-i18n/ibus )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/qvkgen
+	src/gui
+	src/openglextensions
+	src/platformheaders
+	src/platformsupport
+	src/plugins/generic
+	src/plugins/imageformats
+	src/plugins/platforms
+	src/plugins/platforminputcontexts
+)
+
+QT5_GENTOO_CONFIG=(
+	accessibility:accessibility-atspi-bridge
+	egl
+	eglfs
+	eglfs:eglfs_egldevice:
+	eglfs:eglfs_gbm:
+	evdev
+	evdev:mtdev:
+	:fontconfig
+	:system-freetype:FREETYPE
+	!:no-freetype:
+	!gif:no-gif:
+	gles2::OPENGL_ES
+	gles2:opengles2:OPENGL_ES_2
+	!:no-gui:
+	:system-harfbuzz:HARFBUZZ
+	!:no-harfbuzz:
+	jpeg:system-jpeg:IMAGEFORMAT_JPEG
+	!jpeg:no-jpeg:
+	libinput
+	libinput:xkbcommon-evdev:
+	:opengl
+	png:png:
+	png:system-png:IMAGEFORMAT_PNG
+	!png:no-png:
+	tslib
+	udev:libudev:
+	xcb:xcb:
+	xcb:xcb-glx:
+	xcb:xcb-plugin:
+	xcb:xcb-render:
+	xcb:xcb-sm:
+	xcb:xcb-xlib:
+	xcb:xinput2:
+	xcb::XKB
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:gui
+)
+
+src_prepare() {
+	# egl_x11 is activated when both egl and xcb are enabled
+	use egl && QT5_GENTOO_CONFIG+=(xcb:egl_x11) || QT5_GENTOO_CONFIG+=(egl:egl_x11)
+
+	qt_use_disable_config dbus dbus \
+		src/platformsupport/themes/genericunix/genericunix.pri
+
+	qt_use_disable_config tuio udpsocket src/plugins/generic/generic.pro
+
+	qt_use_disable_mod ibus dbus \
+		src/plugins/platforminputcontexts/platforminputcontexts.pro
+
+	use vnc || sed -i -e '/SUBDIRS += vnc/d' \
+		src/plugins/platforms/platforms.pro || die
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		$(usex dbus -dbus-linked '')
+		$(qt_use egl)
+		$(qt_use eglfs)
+		$(usex eglfs '-gbm -kms' '')
+		$(qt_use evdev)
+		$(qt_use evdev mtdev)
+		-fontconfig
+		-system-freetype
+		$(usex gif '' -no-gif)
+		-gui
+		-system-harfbuzz
+		$(qt_use jpeg libjpeg system)
+		$(qt_use libinput)
+		$(qt_use libinput xkbcommon-evdev)
+		-opengl $(usex gles2 es2 desktop)
+		$(qt_use png libpng system)
+		$(qt_use tslib)
+		$(qt_use udev libudev)
+		$(qt_use xcb xcb system)
+		$(qt_use xcb xkbcommon-x11 system)
+		$(usex xcb '-xcb-xlib -xinput2 -xkb' '')
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qthelp/qthelp-5.11.1.ebuild b/dev-qt/qthelp/qthelp-5.11.1.ebuild
new file mode 100644
index 00000000..1e0ee9ab
--- /dev/null
+++ b/dev-qt/qthelp/qthelp-5.11.1.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit qt5-build
+
+DESCRIPTION="Qt5 module for integrating online documentation into applications"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qtsql-${PV}[sqlite]
+	~dev-qt/qtwidgets-${PV}
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/assistant/help
+	src/assistant/qcollectiongenerator
+	src/assistant/qhelpconverter
+	src/assistant/qhelpgenerator
+)
diff --git a/dev-qt/qtimageformats/qtimageformats-5.11.1.ebuild b/dev-qt/qtimageformats/qtimageformats-5.11.1.ebuild
new file mode 100644
index 00000000..5b10805b
--- /dev/null
+++ b/dev-qt/qtimageformats/qtimageformats-5.11.1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Additional format plugins for the Qt image I/O system"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~x86"
+fi
+
+IUSE="jpeg2k mng"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	media-libs/libwebp:=
+	media-libs/tiff:0
+	jpeg2k? ( media-libs/jasper:= )
+	mng? ( media-libs/libmng:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	qt_use_compile_test jpeg2k jasper
+	qt_use_compile_test mng libmng
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtlocation/qtlocation-5.11.1.ebuild b/dev-qt/qtlocation/qtlocation-5.11.1.ebuild
new file mode 100644
index 00000000..f791b5b3
--- /dev/null
+++ b/dev-qt/qtlocation/qtlocation-5.11.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="The Location module for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+IUSE=""
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qtpositioning-${PV}
+	~dev-qt/qtsql-${PV}
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	~dev-qt/qtconcurrent-${PV}
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/3rdparty/clipper
+	src/3rdparty/poly2tri
+	src/3rdparty/clip2tri
+	src/3rdparty/mapbox-gl-native
+	src/location
+	src/imports/location
+	src/plugins/geoservices
+)
+
+src_configure() {
+	# src/plugins/geoservices requires files that are only generated when
+	# qmake is run in the root directory. Bug 633776.
+	mkdir -p "${QT5_BUILD_DIR}" || die
+	qt5_qmake "${QT_BUILD_DIR}"
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtmultimedia/qtmultimedia-5.11.1.ebuild b/dev-qt/qtmultimedia/qtmultimedia-5.11.1.ebuild
new file mode 100644
index 00000000..04cc34da
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-5.11.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="alsa gles2 gstreamer openal pulseaudio qml widgets"
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=]
+	~dev-qt/qtnetwork-${PV}
+	alsa? ( media-libs/alsa-lib )
+	gstreamer? (
+		dev-libs/glib:2
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	qml? (
+		~dev-qt/qtdeclarative-${PV}
+		gles2? ( ~dev-qt/qtgui-${PV}[egl] )
+		openal? ( media-libs/openal )
+	)
+	widgets? (
+		~dev-qt/qtopengl-${PV}
+		~dev-qt/qtwidgets-${PV}[gles2=]
+	)
+"
+DEPEND="${RDEPEND}
+	gstreamer? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	sed -i -e '/CONFIG\s*+=/ s/optimize_full//' \
+		src/multimedia/multimedia.pro || die
+
+	qt_use_disable_config openal openal \
+		src/imports/imports.pro
+
+	qt_use_disable_mod qml quick \
+		src/src.pro \
+		src/plugins/plugins.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/gsttools/gsttools.pro \
+		src/plugins/gstreamer/common.pri
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		$(qt_use alsa)
+		$(qt_use gstreamer)
+		$(qt_use pulseaudio)
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtnetwork/qtnetwork-5.11.1.ebuild b/dev-qt/qtnetwork/qtnetwork-5.11.1.ebuild
new file mode 100644
index 00000000..95290d66
--- /dev/null
+++ b/dev-qt/qtnetwork/qtnetwork-5.11.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Network abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="bindist connman libproxy networkmanager +ssl"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	>=sys-libs/zlib-1.2.5
+	connman? ( ~dev-qt/qtdbus-${PV} )
+	libproxy? ( net-libs/libproxy )
+	networkmanager? ( ~dev-qt/qtdbus-${PV} )
+	ssl? ( dev-libs/openssl:0=[bindist=] )
+"
+RDEPEND="${DEPEND}
+	connman? ( net-misc/connman )
+	networkmanager? ( net-misc/networkmanager )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/network
+	src/plugins/bearer/generic
+)
+
+QT5_GENTOO_CONFIG=(
+	libproxy
+	ssl::SSL
+	ssl::OPENSSL
+	ssl:openssl-linked:LINKED_OPENSSL
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:network
+)
+
+pkg_setup() {
+	use connman && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/connman)
+	use networkmanager && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/networkmanager)
+}
+
+src_configure() {
+	local myconf=(
+		$(use connman || use networkmanager && echo -dbus-linked)
+		$(qt_use libproxy)
+		$(usex ssl -openssl-linked '')
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtnetworkauth/qtnetworkauth-5.11.1.ebuild b/dev-qt/qtnetworkauth/qtnetworkauth-5.11.1.ebuild
new file mode 100644
index 00000000..a1e6dc62
--- /dev/null
+++ b/dev-qt/qtnetworkauth/qtnetworkauth-5.11.1.ebuild
@@ -0,0 +1,20 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Network authorization library for the Qt5 framework"
+LICENSE="GPL-3"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtnetwork-${PV}
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtopengl/qtopengl-5.11.1.ebuild b/dev-qt/qtopengl/qtopengl-5.11.1.ebuild
new file mode 100644
index 00000000..5dfd9694
--- /dev/null
+++ b/dev-qt/qtopengl/qtopengl-5.11.1.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+inherit qt5-build
+
+DESCRIPTION="OpenGL support library for the Qt5 framework (deprecated)"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="gles2"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=]
+	~dev-qt/qtwidgets-${PV}[gles2=]
+	virtual/opengl
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/opengl
+)
+
+src_configure() {
+	local myconf=(
+		-opengl $(usex gles2 es2 desktop)
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtpaths/qtpaths-5.11.1.ebuild b/dev-qt/qtpaths/qtpaths-5.11.1.ebuild
new file mode 100644
index 00000000..bc5bdee2
--- /dev/null
+++ b/dev-qt/qtpaths/qtpaths-5.11.1.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit qt5-build
+
+DESCRIPTION="Command line client to QStandardPaths"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/qtpaths
+)
diff --git a/dev-qt/qtplugininfo/qtplugininfo-5.11.1.ebuild b/dev-qt/qtplugininfo/qtplugininfo-5.11.1.ebuild
new file mode 100644
index 00000000..43ae95d1
--- /dev/null
+++ b/dev-qt/qtplugininfo/qtplugininfo-5.11.1.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit qt5-build
+
+DESCRIPTION="Qt5 plugin metadata dumper"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/qtplugininfo
+)
diff --git a/dev-qt/qtpositioning/qtpositioning-5.11.1.ebuild b/dev-qt/qtpositioning/qtpositioning-5.11.1.ebuild
new file mode 100644
index 00000000..37f71567
--- /dev/null
+++ b/dev-qt/qtpositioning/qtpositioning-5.11.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtlocation"
+inherit qt5-build
+
+DESCRIPTION="Physical position determination library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="geoclue qml"
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	geoclue? ( ~dev-qt/qtdbus-${PV} )
+	qml? ( ~dev-qt/qtdeclarative-${PV} )
+"
+DEPEND="${RDEPEND}"
+PDEPEND="
+	geoclue? ( app-misc/geoclue:0 )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/3rdparty/clipper
+	src/3rdparty/poly2tri
+	src/3rdparty/clip2tri
+	src/positioning
+	src/plugins/position/positionpoll
+)
+
+pkg_setup() {
+	use geoclue && QT5_TARGET_SUBDIRS+=(src/plugins/position/geoclue)
+	use qml && QT5_TARGET_SUBDIRS+=(
+		src/positioningquick
+		src/imports/positioning
+	)
+}
diff --git a/dev-qt/qtprintsupport/qtprintsupport-5.11.1.ebuild b/dev-qt/qtprintsupport/qtprintsupport-5.11.1.ebuild
new file mode 100644
index 00000000..b53ccddd
--- /dev/null
+++ b/dev-qt/qtprintsupport/qtprintsupport-5.11.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+inherit qt5-build
+
+DESCRIPTION="Printing support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="cups gles2"
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=]
+	~dev-qt/qtwidgets-${PV}[gles2=]
+	cups? ( >=net-print/cups-1.4 )
+"
+DEPEND="${RDEPEND}
+	test? ( ~dev-qt/qtnetwork-${PV} )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/printsupport
+	src/plugins/printsupport
+)
+
+QT5_GENTOO_CONFIG=(
+	cups
+)
+
+src_configure() {
+	local myconf=(
+		$(qt_use cups)
+		-opengl $(usex gles2 es2 desktop)
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtquickcontrols/qtquickcontrols-5.11.1.ebuild b/dev-qt/qtquickcontrols/qtquickcontrols-5.11.1.ebuild
new file mode 100644
index 00000000..e0dc9411
--- /dev/null
+++ b/dev-qt/qtquickcontrols/qtquickcontrols-5.11.1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Set of controls used in conjunction with Qt Quick to build complete interfaces"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="+widgets"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}
+	widgets? ( ~dev-qt/qtwidgets-${PV} )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/controls/Private/private.pri \
+		tests/auto/activeFocusOnTab/activeFocusOnTab.pro \
+		tests/auto/controls/controls.pro \
+		tests/auto/testplugin/testplugin.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtquickcontrols2/qtquickcontrols2-5.11.1.ebuild b/dev-qt/qtquickcontrols2/qtquickcontrols2-5.11.1.ebuild
new file mode 100644
index 00000000..aa6bccf5
--- /dev/null
+++ b/dev-qt/qtquickcontrols2/qtquickcontrols2-5.11.1.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Set of next generation Qt Quick controls for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+IUSE="widgets"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}
+	widgets? ( ~dev-qt/qtwidgets-${PV} )
+"
+RDEPEND="${DEPEND}
+	~dev-qt/qtgraphicaleffects-${PV}
+"
+
+src_prepare() {
+	qt_use_disable_mod widgets widgets \
+		src/imports/platform/platform.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtscript/qtscript-5.11.1.ebuild b/dev-qt/qtscript/qtscript-5.11.1.ebuild
new file mode 100644
index 00000000..2644fc6e
--- /dev/null
+++ b/dev-qt/qtscript/qtscript-5.11.1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Application scripting library for the Qt5 framework (deprecated)"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="+jit scripttools"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	scripttools? (
+		~dev-qt/qtgui-${PV}
+		~dev-qt/qtwidgets-${PV}
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	qt_use_disable_mod scripttools widgets \
+		src/src.pro
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		JAVASCRIPTCORE_JIT=$(usex jit 'yes' 'no')
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtscxml/qtscxml-5.11.1.ebuild b/dev-qt/qtscxml/qtscxml-5.11.1.ebuild
new file mode 100644
index 00000000..59b06ef2
--- /dev/null
+++ b/dev-qt/qtscxml/qtscxml-5.11.1.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="State Chart XML (SCXML) support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtsensors/qtsensors-5.11.1.ebuild b/dev-qt/qtsensors/qtsensors-5.11.1.ebuild
new file mode 100644
index 00000000..d0b0c5b6
--- /dev/null
+++ b/dev-qt/qtsensors/qtsensors-5.11.1.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Hardware sensor access library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+# TODO: simulator
+IUSE="qml"
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdbus-${PV}
+	qml? ( ~dev-qt/qtdeclarative-${PV} )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	qt_use_disable_mod qml quick \
+		src/src.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtserialbus/qtserialbus-5.11.1.ebuild b/dev-qt/qtserialbus/qtserialbus-5.11.1.ebuild
new file mode 100644
index 00000000..c6a1fac1
--- /dev/null
+++ b/dev-qt/qtserialbus/qtserialbus-5.11.1.ebuild
@@ -0,0 +1,20 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Support for CAN and other serial buses"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qtserialport-${PV}
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtserialport/qtserialport-5.11.1.ebuild b/dev-qt/qtserialport/qtserialport-5.11.1.ebuild
new file mode 100644
index 00000000..f29b276e
--- /dev/null
+++ b/dev-qt/qtserialport/qtserialport-5.11.1.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Serial port abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	virtual/libudev:=
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# make sure we link against libudev
+	sed -i -e 's/:qtConfig(libudev)//' \
+		src/serialport/serialport-lib.pri || die
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtspeech/qtspeech-5.11.1.ebuild b/dev-qt/qtspeech/qtspeech-5.11.1.ebuild
new file mode 100644
index 00000000..24627d2b
--- /dev/null
+++ b/dev-qt/qtspeech/qtspeech-5.11.1.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Text-to-speech library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+# TODO: flite plugin - needs 2.0.0 (not yet in tree)
+IUSE=""
+
+RDEPEND="
+	>=app-accessibility/speech-dispatcher-0.8.7
+	~dev-qt/qtcore-${PV}
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-5.9.4-nogui.patch" )
diff --git a/dev-qt/qtsql/qtsql-5.11.1.ebuild b/dev-qt/qtsql/qtsql-5.11.1.ebuild
new file mode 100644
index 00000000..db29e42d
--- /dev/null
+++ b/dev-qt/qtsql/qtsql-5.11.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="SQL abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="freetds mysql oci8 odbc postgres +sqlite"
+
+REQUIRED_USE="
+	|| ( freetds mysql oci8 odbc postgres sqlite )
+"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	freetds? ( dev-db/freetds )
+	mysql? ( virtual/libmysqlclient:= )
+	oci8? ( dev-db/oracle-instantclient-basic )
+	odbc? ( || ( dev-db/unixODBC dev-db/libiodbc ) )
+	postgres? ( dev-db/postgresql:* )
+	sqlite? ( >=dev-db/sqlite-3.8.10.2:3 )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/sql
+	src/plugins/sqldrivers
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:sql
+)
+
+src_configure() {
+	local myconf=(
+		$(qt_use freetds  sql-tds    plugin)
+		$(qt_use mysql    sql-mysql  plugin)
+		$(qt_use oci8     sql-oci    plugin)
+		$(qt_use odbc     sql-odbc   plugin)
+		$(qt_use postgres sql-psql   plugin)
+		$(qt_use sqlite   sql-sqlite plugin)
+		$(usex sqlite -system-sqlite '')
+	)
+
+	use mysql && myconf+=("-I${EPREFIX}/usr/include/mysql" "-L${EPREFIX}/usr/$(get_libdir)/mysql")
+	use oci8 && myconf+=("-I${ORACLE_HOME}/include" "-L${ORACLE_HOME}/$(get_libdir)")
+	use odbc && myconf+=("-I${EPREFIX}/usr/include/iodbc")
+	use postgres && myconf+=("-I${EPREFIX}/usr/include/postgresql/pgsql")
+
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtsvg/qtsvg-5.11.1.ebuild b/dev-qt/qtsvg/qtsvg-5.11.1.ebuild
new file mode 100644
index 00000000..8afd46f0
--- /dev/null
+++ b/dev-qt/qtsvg/qtsvg-5.11.1.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="SVG rendering library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtwidgets-${PV}
+	>=sys-libs/zlib-1.2.5
+"
+DEPEND="${RDEPEND}
+	test? ( ~dev-qt/qtxml-${PV} )
+"
diff --git a/dev-qt/qttest/qttest-5.11.1.ebuild b/dev-qt/qttest/qttest-5.11.1.ebuild
new file mode 100644
index 00000000..a136469c
--- /dev/null
+++ b/dev-qt/qttest/qttest-5.11.1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+inherit qt5-build
+
+DESCRIPTION="Unit testing library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+"
+DEPEND="${RDEPEND}
+	test? (
+		~dev-qt/qtgui-${PV}
+		~dev-qt/qtxml-${PV}
+	)
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/testlib
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:testlib
+)
diff --git a/dev-qt/qttranslations/qttranslations-5.11.1.ebuild b/dev-qt/qttranslations/qttranslations-5.11.1.ebuild
new file mode 100644
index 00000000..02291152
--- /dev/null
+++ b/dev-qt/qttranslations/qttranslations-5.11.1.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Translation files for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/linguist-tools-${PV}
+	~dev-qt/qtcore-${PV}
+"
+RDEPEND=""
diff --git a/dev-qt/qtvirtualkeyboard/qtvirtualkeyboard-5.11.1.ebuild b/dev-qt/qtvirtualkeyboard/qtvirtualkeyboard-5.11.1.ebuild
new file mode 100644
index 00000000..21fd992d
--- /dev/null
+++ b/dev-qt/qtvirtualkeyboard/qtvirtualkeyboard-5.11.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Virtual keyboard plugin for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-fbsd"
+fi
+
+# TODO: unbudle libraries for more layouts
+IUSE="handwriting +spell +xcb"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtsvg-${PV}
+	spell? ( app-text/hunspell:= )
+	xcb? ( x11-libs/libxcb:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local myqmakeargs=(
+		$(usex handwriting CONFIG+=lipi-toolkit "")
+		$(usex spell "" CONFIG+=disable-hunspell)
+		$(usex xcb "" CONFIG+=disable-desktop)
+		CONFIG+="lang-ar_AR lang-da_DK lang-de_DE lang-en_GB \
+                        lang-es_ES lang-fa_FA lang-fi_FI lang-fr_FR \
+                        lang-hi_IN lang-it_IT lang-nb_NO lang-pl_PL \
+                        lang-pt_PT lang-ro_RO lang-ru_RU lang-sv_SE"
+	)
+
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtwayland/qtwayland-5.11.1.ebuild b/dev-qt/qtwayland/qtwayland-5.11.1.ebuild
new file mode 100644
index 00000000..4c355304
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-5.11.1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="+libinput xcomposite"
+
+DEPEND="
+	>=dev-libs/wayland-1.6.0
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}[egl,libinput?]
+	media-libs/mesa[egl]
+	>=x11-libs/libxkbcommon-0.2.0
+	xcomposite? (
+		x11-libs/libX11
+		x11-libs/libXcomposite
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	qt_use_disable_config libinput xkbcommon-evdev \
+		src/client/client.pro \
+		src/compositor/wayland_wrapper/wayland_wrapper.pri \
+		src/plugins/shellintegration/ivi-shell/ivi-shell.pro \
+		tests/auto/compositor/compositor/compositor.pro
+
+	use xcomposite || rm -r config.tests/xcomposite || die
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtwebchannel/qtwebchannel-5.11.1.ebuild b/dev-qt/qtwebchannel/qtwebchannel-5.11.1.ebuild
new file mode 100644
index 00000000..7f4acf24
--- /dev/null
+++ b/dev-qt/qtwebchannel/qtwebchannel-5.11.1.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Qt5 module for integrating C++ and QML applications with HTML/JavaScript clients"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="qml"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	qml? ( ~dev-qt/qtdeclarative-${PV} )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	qt_use_disable_mod qml quick src/src.pro
+	qt_use_disable_mod qml qml src/webchannel/webchannel.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtwebengine/qtwebengine-5.11.1.ebuild b/dev-qt/qtwebengine/qtwebengine-5.11.1.ebuild
new file mode 100644
index 00000000..495c4d06
--- /dev/null
+++ b/dev-qt/qtwebengine/qtwebengine-5.11.1.ebuild
@@ -0,0 +1,138 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit multiprocessing pax-utils python-any-r1 qt5-build
+
+DESCRIPTION="Library for rendering dynamic web content in Qt5 C++ and QML applications"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+IUSE="alsa bindist designer geolocation pax_kernel pulseaudio +system-ffmpeg +system-icu widgets"
+REQUIRED_USE="designer? ( widgets )"
+
+RDEPEND="
+	app-arch/snappy:=
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qtprintsupport-${PV}
+	~dev-qt/qtwebchannel-${PV}[qml]
+	dev-libs/expat
+	dev-libs/libevent:=
+	dev-libs/libxml2[icu]
+	dev-libs/libxslt
+	dev-libs/protobuf:=
+	dev-libs/re2:=
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz:=
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:0=
+	>=media-libs/libvpx-1.5:=[svc]
+	media-libs/libwebp:=
+	media-libs/mesa[egl]
+	media-libs/opus
+	net-libs/libsrtp:0=
+	sys-apps/dbus
+	sys-apps/pciutils
+	sys-libs/libcap
+	sys-libs/zlib[minizip]
+	virtual/libudev
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libXtst
+	alsa? ( media-libs/alsa-lib )
+	designer? ( ~dev-qt/designer-${PV} )
+	geolocation? ( ~dev-qt/qtpositioning-${PV} )
+	pulseaudio? ( media-sound/pulseaudio:= )
+	system-ffmpeg? ( media-video/ffmpeg:0= )
+	system-icu? ( dev-libs/icu:= )
+	widgets? (
+		~dev-qt/qtdeclarative-${PV}[widgets]
+		~dev-qt/qtwidgets-${PV}
+	)
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	>=app-arch/gzip-1.7
+	dev-util/gperf
+	dev-util/ninja
+	dev-util/re2c
+	sys-devel/bison
+	pax_kernel? ( sys-apps/elfix )
+"
+
+PATCHES+=(
+	"${FILESDIR}/${PN}-5.9.6-gcc8.patch" # bug 657124
+	"${FILESDIR}/${P}-libxml2-disable-catalogs.patch" # bug 653078
+	"${FILESDIR}/${P}-ffmpeg4.patch"
+	"${FILESDIR}/${P}-eglGetProcAddress-fallback-lookup.patch" # 5.11 branch
+	"${FILESDIR}/${P}-nouveau-disable-gpu.patch" # bug 609752
+)
+
+src_prepare() {
+	use pax_kernel && PATCHES+=( "${FILESDIR}/${PN}-5.9.3-paxmark-mksnapshot.patch" )
+
+	# bug 620444 - ensure local headers are used
+	find "${S}" -type f -name "*.pr[fio]" | xargs sed -i -e 's|INCLUDEPATH += |&$$QTWEBENGINE_ROOT/include |' || die
+
+	qt_use_disable_config alsa webengine-alsa src/core/config/linux.pri
+	qt_use_disable_config pulseaudio webengine-pulseaudio src/core/config/linux.pri
+
+	qt_use_disable_mod designer webenginewidgets src/plugins/plugins.pro
+
+	qt_use_disable_mod geolocation positioning \
+		mkspecs/features/configure.prf \
+		src/core/core_chromium.pri \
+		src/core/core_common.pri
+
+	qt_use_disable_mod widgets widgets src/src.pro
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	export NINJA_PATH=/usr/bin/ninja
+	export NINJAFLAGS="${NINJAFLAGS:--j$(makeopts_jobs) -l$(makeopts_loadavg "${MAKEOPTS}" 0) -v}"
+
+	local myqmakeargs=(
+		--
+		-opus
+		-printing-and-pdf
+		-webp
+		$(usex alsa '-alsa' '')
+		$(usex bindist '' '-proprietary-codecs')
+		$(usex pulseaudio '-pulseaudio' '')
+		$(usex system-ffmpeg '-ffmpeg' '')
+		$(usex system-icu '-webengine-icu' '')
+	)
+	qt5-build_src_configure
+}
+
+src_install() {
+	qt5-build_src_install
+
+	# bug 601472
+	if [[ ! -f ${D%/}${QT5_LIBDIR}/libQt5WebEngine.so ]]; then
+		die "${CATEGORY}/${PF} failed to build anything. Please report to https://bugs.gentoo.org/"
+	fi
+
+	pax-mark m "${D%/}${QT5_LIBEXECDIR}"/QtWebEngineProcess
+}
diff --git a/dev-qt/qtwebsockets/qtwebsockets-5.11.1.ebuild b/dev-qt/qtwebsockets/qtwebsockets-5.11.1.ebuild
new file mode 100644
index 00000000..362a0a81
--- /dev/null
+++ b/dev-qt/qtwebsockets/qtwebsockets-5.11.1.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Implementation of the WebSocket protocol for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="qml +ssl"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtnetwork-${PV}[ssl=]
+	qml? ( ~dev-qt/qtdeclarative-${PV} )
+
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	qt_use_disable_mod qml quick src/src.pro
+
+	qt5-build_src_prepare
+}
diff --git a/dev-qt/qtwebview/qtwebview-5.11.1.ebuild b/dev-qt/qtwebview/qtwebview-5.11.1.ebuild
new file mode 100644
index 00000000..43288fc1
--- /dev/null
+++ b/dev-qt/qtwebview/qtwebview-5.11.1.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Module for displaying web content in a QML application using the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtwebengine-${PV}
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtwidgets/qtwidgets-5.11.1.ebuild b/dev-qt/qtwidgets/qtwidgets-5.11.1.ebuild
new file mode 100644
index 00000000..caf1f79a
--- /dev/null
+++ b/dev-qt/qtwidgets/qtwidgets-5.11.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Set of components for creating classic desktop-style UIs for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+# keep IUSE defaults in sync with qtgui
+IUSE="gles2 gtk +png +xcb"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=,png=,xcb?]
+	gtk? (
+		~dev-qt/qtgui-${PV}[dbus]
+		x11-libs/gtk+:3
+		x11-libs/libX11
+		x11-libs/pango
+	)
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/uic
+	src/widgets
+	src/plugins/platformthemes
+)
+
+QT5_GENTOO_CONFIG=(
+	gtk:gtk3:
+	::widgets
+	!:no-widgets:
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:widgets
+)
+
+src_configure() {
+	local myconf=(
+		-opengl $(usex gles2 es2 desktop)
+		$(qt_use gtk)
+		-gui
+		$(qt_use png libpng system)
+		-widgets
+		$(qt_use xcb xcb system)
+		$(qt_use xcb xkbcommon system)
+		$(usex xcb '-xcb-xlib -xinput2 -xkb' '')
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtx11extras/qtx11extras-5.11.1.ebuild b/dev-qt/qtx11extras/qtx11extras-5.11.1.ebuild
new file mode 100644
index 00000000..b029cc42
--- /dev/null
+++ b/dev-qt/qtx11extras/qtx11extras-5.11.1.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="Linux/X11-specific support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[xcb]
+"
+DEPEND="${RDEPEND}
+	test? ( ~dev-qt/qtwidgets-${PV} )
+"
diff --git a/dev-qt/qtxml/qtxml-5.11.1.ebuild b/dev-qt/qtxml/qtxml-5.11.1.ebuild
new file mode 100644
index 00000000..b8568f5e
--- /dev/null
+++ b/dev-qt/qtxml/qtxml-5.11.1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Implementation of SAX and DOM for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+"
+DEPEND="${RDEPEND}
+	test? ( ~dev-qt/qtnetwork-${PV} )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/xml
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:xml
+)
diff --git a/dev-qt/qtxmlpatterns/qtxmlpatterns-5.11.1.ebuild b/dev-qt/qtxmlpatterns/qtxmlpatterns-5.11.1.ebuild
new file mode 100644
index 00000000..8e0054f7
--- /dev/null
+++ b/dev-qt/qtxmlpatterns/qtxmlpatterns-5.11.1.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build
+
+DESCRIPTION="XPath, XQuery, XSLT, and XML Schema validation library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE=""
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtnetwork-${PV}
+"
+RDEPEND="${DEPEND}"