make little cleanup

2 files changed, 0 insertions, 122 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
deleted file mode 100644
index 5bcb4930..00000000
--- a/kde-apps/k3b/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST 8102d390e763abc1e4db2954798930e5f04d6370.zip 10616002 SHA256 40888aef2f13f7b4978d0b7f7bfa400d75f0cf2907068189810bf26ef42cdae7 SHA512 22baf5572e84214286426f322ea69afb16ec9468f8a51a355349988382a0e17ddc4dd32ffa1b0142a25bf0e0fda687ff3b6de3092b74df99c0bf8d544e97034c WHIRLPOOL 290c6b5f437b49c92cca457a5c5f9b03d8b428a15fac52dd6845a84f81588a2e7a578aae94aa48545d4028f0a24506b00d0aecf10fa63d80d9cceec784d03e47
diff --git a/kde-apps/k3b/k3b-2.10.0.ebuild b/kde-apps/k3b/k3b-2.10.0.ebuild
deleted file mode 100644
index bd902325..00000000
--- a/kde-apps/k3b/k3b-2.10.0.ebuild
+++ /dev/null
@@ -1,121 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-KDE_HANDBOOK="forceoptional"
-KDE_TEST="optional"
-inherit kde5
-
-DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
-HOMEPAGE="http://www.k3b.org/"
-
-_COMMIT="8102d390e763abc1e4db2954798930e5f04d6370"
-SRC_URI="https://github.com/KDE/k3b/archive/${_COMMIT}.zip"
-
-LICENSE="GPL-2 FDL-1.2"
-KEYWORDS="~amd64 ~x86"
-IUSE="dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis"
-
-S=${WORKDIR}/${PN}-${_COMMIT}
-
-DEPEND="
-	$(add_frameworks_dep karchive)
-	$(add_frameworks_dep kbookmarks)
-	$(add_frameworks_dep kcmutils)
-	$(add_frameworks_dep kcompletion)
-	$(add_frameworks_dep kconfig)
-	$(add_frameworks_dep kconfigwidgets)
-	$(add_frameworks_dep kcoreaddons)
-	$(add_frameworks_dep kfilemetadata)
-	$(add_frameworks_dep ki18n)
-	$(add_frameworks_dep kiconthemes)
-	$(add_frameworks_dep kio)
-	$(add_frameworks_dep kjobwidgets)
-	$(add_frameworks_dep knewstuff)
-	$(add_frameworks_dep knotifications)
-	$(add_frameworks_dep knotifyconfig)
-	$(add_frameworks_dep kservice)
-	$(add_frameworks_dep kwidgetsaddons)
-	$(add_frameworks_dep kxmlgui)
-	$(add_frameworks_dep solid)
-	$(add_kdeapps_dep libkcddb)
-	$(add_qt_dep qtdbus)
-	$(add_qt_dep qtgui)
-	$(add_qt_dep qtnetwork)
-	$(add_qt_dep qtwebkit)
-	$(add_qt_dep qtwidgets)
-	$(add_qt_dep qtxml)
-	media-libs/libsamplerate
-	dvd? ( media-libs/libdvdread )
-	ffmpeg? (
-		libav? ( media-video/libav:= )
-		!libav? ( media-video/ffmpeg:0= )
-	)
-	flac? ( >=media-libs/flac-1.2[cxx] )
-	mp3? ( media-sound/lame )
-	mad? ( media-libs/libmad )
-	musepack? ( >=media-sound/musepack-tools-444 )
-	sndfile? ( media-libs/libsndfile )
-	taglib? ( >=media-libs/taglib-1.5 )
-	vorbis? ( media-libs/libvorbis )
-"
-RDEPEND="${DEPEND}
-	app-cdr/cdrdao
-	media-sound/cdparanoia
-	virtual/cdrtools
-	dvd? (
-		>=app-cdr/dvd+rw-tools-7
-		encode? ( media-video/transcode[dvd] )
-	)
-	emovix? ( media-video/emovix )
-	sox? ( media-sound/sox )
-	vcd? ( media-video/vcdimager )
-	!app-cdr/k3b:4
-"
-
-REQUIRED_USE="
-	mp3? ( encode )
-	sox? ( encode )
-"
-
-DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
-
-src_configure() {
-	local mycmakeargs=(
-		-DK3B_BUILD_API_DOCS=OFF
-		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
-		-DK3B_ENABLE_HAL_SUPPORT=OFF
-		-DK3B_ENABLE_MUSICBRAINZ=OFF
-		-DK3B_DEBUG=$(usex debug)
-		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
-		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
-		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
-		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
-		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
-		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
-		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
-		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
-		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
-		-DK3B_ENABLE_TAGLIB=$(usex taglib)
-		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
-		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
-	)
-
-	kde5_src_configure
-}
-
-pkg_postinst() {
-	kde5_pkg_postinst
-
-	echo
-	elog "If you get warnings on start-up, uncheck the \"Check system"
-	elog "configuration\" option in the \"Misc\" settings window."
-	echo
-
-	local group=cdrom
-	use kernel_linux || group=operator
-	elog "Make sure you have proper read/write permissions on optical device(s)."
-	elog "Usually, it is sufficient to be in the ${group} group."
-	echo
-}