kde-plasma/kde-gtk-config : version bump

1 files changed, 53 insertions, 0 deletions

diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.16.1-r1337.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.16.1-r1337.ebuild
new file mode 100644
index 00000000..c367387d
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.16.1-r1337.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE Plasma systemsettings kcm to set GTK application look&feel"
+HOMEPAGE="https://cgit.kde.org/kde-gtk-config.git"
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtsvg)
+	$(add_qt_dep qtwidgets)
+	dev-libs/glib:2
+	x11-libs/gtk+:2
+	x11-libs/gtk+:3
+	x11-libs/libXcursor
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+"
+
+PATCHES=( "${FILESDIR}"/redhat-or-not-go-dconf-and-flatpak-yourself-or-try-again-with-a-option-to-disable.patch )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+	elog "If you notice missing icons in your GTK applications, you may have to install"
+	elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+	elog "for example."
+}