Added lxpanel

1 files changed, 78 insertions, 0 deletions

diff --git a/lxde-base/lxpanel/lxpanel-0.7.0-r1.ebuild b/lxde-base/lxpanel/lxpanel-0.7.0-r1.ebuild
new file mode 100644
index 00000000..14eced4e
--- /dev/null
+++ b/lxde-base/lxpanel/lxpanel-0.7.0-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/lxpanel-0.7.0-r1.ebuild,v 1.3 2015/03/03 08:06:53 dlan Exp $
+
+EAPI="4"
+
+inherit autotools eutils readme.gentoo versionator
+
+MAJOR_VER="$(get_version_component_range 1-2)"
+
+DESCRIPTION="Lightweight X11 desktop panel for LXDE"
+HOMEPAGE="http://lxde.org/"
+SRC_URI="mirror://sourceforge/lxde/LXPanel%20%28desktop%20panel%29/LXPanel%20${MAJOR_VER}.x/${P}.tar.xz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~x86 ~x86-interix ~amd64-linux ~arm-linux ~x86-linux"
+SLOT="0"
+IUSE="+alsa wifi"
+RESTRICT="test"  # bug 249598
+
+RDEPEND="x11-libs/gtk+:2
+	>=x11-libs/libfm-1.2.0[gtk]
+	x11-libs/libwnck:1
+	x11-libs/libXmu
+	x11-libs/libXpm
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/libX11
+	lxde-base/lxmenu-data
+	lxde-base/menu-cache
+	alsa? ( media-libs/alsa-lib )
+	wifi? ( net-wireless/wireless-tools )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+DOC_CONTENTS="If you have problems with broken icons shown in the main panel,
+you will have to configure panel settings via its menu.
+This will not be an issue with first time installations."
+
+src_prepare() {
+	#bug #522404
+	epatch "${FILESDIR}"/${PN}-0.7.0-right-click-fix.patch
+	epatch "${FILESDIR}"/${PN}-0.5.9-sandbox.patch
+	#bug #415595
+	sed -i "s:-Werror::" configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local plugins="netstatus,volume,cpu,deskno,batt, \
+		kbled,xkb,thermal,cpufreq,monitors"
+
+	use wifi && plugins+=",netstat"
+	use alsa && plugins+=",volumealsa"
+	[[ ${CHOST} == *-interix* ]] && plugins=deskno,kbled,xkb
+
+	econf $(use_enable alsa) --with-x --with-plugins="${plugins}"
+	# the gtk+ dep already pulls in libX11, so we might as well hardcode with-x
+}
+
+src_install () {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README
+
+	# Get rid of the .la files.
+	find "${D}" -name '*.la' -delete
+
+	readme.gentoo_create_doc
+
+	# Sabayon, add our computer icon
+	insinto /usr/share/lxpanel/images
+	newins "${FILESDIR}"/start-here.png my-computer.png
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}