2 files changed, 78 insertions, 0 deletions
diff --git a/dev-libs/libdbusmenu-gtk2/Manifest b/dev-libs/libdbusmenu-gtk2/Manifest
new file mode 100644
index 00000000..3bd215e2
--- /dev/null
+++ b/dev-libs/libdbusmenu-gtk2/Manifest
@@ -0,0 +1 @@
+DIST libdbusmenu-12.10.2.tar.gz 735730 SHA256 9d6ad4a0b918b342ad2ee9230cce8a095eb601cb0cee6ddc1122d0481f9d04c9 SHA512 cf2e50dc3adbf35d0a4ccdd62a3efd9fae2d079b8d06e6522b70f077f89ac2cf72188e380f476e38d184b69549e90b801bf1e32174fa94bbe612dd52aec94496 WHIRLPOOL 3e75fd0bcbadcff8f4e4cd3a2be33a3aa7cf715413b1a67c5430b9420a965d64db2d988fa5c21fc42c6458ad4ed479c400b28b8a94074cb7223ab0a03ad985eb
diff --git a/dev-libs/libdbusmenu-gtk2/libdbusmenu-gtk2-12.10.2.ebuild b/dev-libs/libdbusmenu-gtk2/libdbusmenu-gtk2-12.10.2.ebuild
new file mode 100644
index 00000000..f28aa497
--- /dev/null
+++ b/dev-libs/libdbusmenu-gtk2/libdbusmenu-gtk2-12.10.2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+VALA_MIN_API_VERSION=0.16
+VALA_USE_DEPEND=vapigen
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit eutils flag-o-matic python-single-r1 vala
+
+MY_PN="libdbusmenu"
+DESCRIPTION="Library to pass menu structure across DBus"
+HOMEPAGE="http://launchpad.net/dbusmenu"
+SRC_URI="http://launchpad.net/${MY_PN/lib}/${PV%.*}/${PV}/+download/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="LGPL-2.1 LGPL-3"
+SLOT="3"
+KEYWORDS="~alpha amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc x86"
+IUSE="debug gtk +introspection"
+
+RDEPEND="
+	>=dev-libs/dbus-glib-0.100
+	>=dev-libs/json-glib-0.13.4
+	>=dev-libs/glib-2.32
+	dev-libs/libxml2
+	gtk? ( >=x11-libs/gtk+-2.18:2[introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-1 )
+	!<${CATEGORY}/${PN}-0.5.1-r200"
+DEPEND="${RDEPEND}
+	app-text/gnome-doc-utils
+	dev-util/intltool
+	virtual/pkgconfig
+	introspection? ( $(vala_depend) )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	if use introspection; then
+		vala_src_prepare
+		export VALA_API_GEN="${VAPIGEN}"
+	fi
+	python_fix_shebang tools
+}
+
+src_configure() {
+	append-flags -Wno-error #414323
+
+	# dumper extra tool is only for GTK+-2.x, tests use valgrind which is stupid
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--disable-static \
+		--disable-silent-rules \
+		--disable-scrollkeeper \
+		$(use_enable gtk) \
+		--disable-dumper \
+		$(use_enable introspection) \
+		$(use_enable introspection vala) \
+		$(use_enable debug massivedebugging) \
+		--with-html-dir=/usr/share/doc/${PF}/html \
+		--with-gtk=2
+}
+
+src_test() { :; } #440192
+
+src_install() {
+	MAKEOPTS+=" -j1"
+	default
+
+	local a b
+	for a in ${PN}-{glib,gtk}; do
+		b=/usr/share/doc/${PF}/html/${a}
+		[[ -d ${ED}/${b} ]] && dosym ${b} /usr/share/gtk-doc/html/${a}
+	done
+
+	prune_libtool_files
+}